!#############################################
!---------Ring mit Torus----------------------
!#############################################

!------Parameter------------------
leira=11.75e-3		!Radius Alustab
leila=50e-3		!Länge Alubstab
rad=50e-3		!Radius umgebende Luft
torad1=2.013e-3		!Radius Torus Stahl
toradmaj=15e-3		!Hauptradius Torus
strom=sqrt(2)*800	!Strom (Scheitelwert)
freq=50			!Frequenz

/prep7
et,1,solid117		!Element Luft
et,2,solid117,6		!Element Alustab
et,3,solid117,1		!Element Ring
mp,murx,1,1		!mu_relativ Luft
mp,murx,2,1		!mu_relativ Alustab
mp,murx,3,100		!mu_relativ Ring
mp,rsvx,2,1/28.64e6	!spezifischer el. Widerstand Alustab
mp,rsvx,3,1/5e6		!spezifischer el. Widerstand Ring

!--------Geometrie-----------------
cylind,,leira,-leila/2,leila/2,0,90		!Nachbildung Alustab 
cylind,,leira,-leila/2,leila/2,90,180		!Viertelzylinder, damit  
cylind,,leira,-leila/2,leila/2,180,270		!Vernetzung mit Quadern 
cylind,,leira,-leila/2,leila/2,270,360
vglue,all					!Verkleben der Teilzylinder
numcmp,volu
				
torus,,torad1,toradmaj,-90,234			!Ring

cylind,,rad,-leila/2,leila/2			!Luft

vovlap,all					!Überlappen der Volumen
numcmp,volu					!Komprimierung der Nummerierung

!V1-4:Leiter V5:Stahlring V6:Luft

!-------Vernetzung-Alustab------------------
lsel,s,loc,z,0				!grobe Vernetzung in Längsrichtung
lsel,r,loc,x,-leira,leira
lesize,all,,,2
type,2
mat,2
esize,,4					
mshape,0,3d				!Vernetzung mit Quadern
mshkey,1				!Mapped mashing
vmesh,1,4,1

!-------Vernetzung-Stahlring------------
type,3
mat,3
esize
mshape,1,3d
mshkey,0
smrtsize,5
vmesh,5

!-------Vernetzung-Luft------------------
type,1				
mat,1
esize,leila/4				!Elementgröße
mshape,1,3d				!Vernetzung mit Tetraedern
mshkey,0				!Free mashing
vmesh,6

!------Randbedingungen----------------
csys,1					!Koordinatensystem
asel,s,loc,x,rad			!Ränder der Luft 
da,all,az,0				!mit Potential 0 belegen
asel,s,loc,z,-leila/2
asel,a,loc,z,leila/2
da,all,az,0

!-----Last-----------------------------
esel,s,mat,,2				!Last auf Alustab aufbringen
nsle
nsel,r,loc,z,-leila/2
cp,1,volt,all
*get,n1,node,,num,min
f,n1,amps,strom				!Strom einspeisen

esel,s,mat,,2
nsle
nsel,r,loc,z,leila/2
d,all,volt,0				!Potential Null

/solu					!Lösung
allsel
antype,harm				!harmonisch
harfrq,freq				!Frequenzvorgabe			
solve

/post1
set,1,1
esel,s,mat,,2
powerh					!Leistung Alustab

esel,s,mat,,3				!Leistung Ring
powerh