finish
/clear
/UNITS, SI
/Title, "Rahmen mit Kontakt"
/prep7

MP,EX,1,21E10
MP,DENS,1,7800
MP,PRXY,1,0.3

K,1,0,0,0
K,2,0,0,2.5
K,3,0,5.0,2.5
K,4,0,5.0,0
K,5,3,0,0
K,6,3,0,2
K,7,3,5.0,2
K,8,3,5.0,0

!Fläche
K,30,0,0,2.51
K,31,0,5.0,2.51
K,32,3,5.0,2.01
K,33,3,0.0,2.01

/triad,off
!Steher
L,1,2
L,4,3
L,8,7
L,5,6
L,6,7 !Längsträger vorne
L,2,3 !Längsträger hinten
!Querträger
L,2,6
L,3,7

A,30,31,32,33 !Fläche

ET,1,BEAM189
KEYOPT,1,1,1
KEYOPT,1,2,1
keyopt,1,4,2 ! output both torsional and flexural shear stress
keyopt,1,6,3 ! extrapolate section forces, etc. to nodes
keyopt,1,7,2 ! maximize output data ...
keyopt,1,9,3 ! maximize output data ...
SECTYPE,1,BEAM,ASEC,60x60
SECDATA,0.0013481,5.45E-7,0,5.45E-7,0.9E-12,1.09E-6,0.03,0.03,0.03,0.03,0.06,0.06

!Auswahl Linien Profil 60x60
LSEL,S,LOC,Z,0,2.5
LATT, 1,,1,,,,1 !Profilzuweisung
LESIZE, ALL,,,10
LMESH,ALL

ET,2,SHELL281
keyopt,2,1,2
SECTYPE,3,SHELL
SECDATA,0.01,1 !Platte mit 0.01m Dicke

LSEL,S,LOC,Z,0,2.8
ASEL,ALL
AATT,1,,2,,3
LESIZE,ALL,,,10
AMESH, ALL

!cncheck
!Lasten
SFA,ALL,,PRES,100

!Randbedingungen
nsel,s,loc,z,0
d,all,uz,0
d,all,uy,0
d,all,ux,0
d,all,rotz,0
d,all,roty,0
d,all,rotx,0

!Kontakte
et,3,TARGE170
et,4,CONTA177
keyopt,4,4,0
keyopt,4,5,3 !close gap, reduce penetration
keyopt,4,9,1
keyopt,4,11,1 !include thickness
keyopt,4,12,5 !always bonded

lsel,none
ASEL,ALL
esla,s
nsle,s
type,3
esurf
LSEL,S,LOC,Z,2.0,2.5
nsll,s
esll,s
type,4
esurf

ALLSEL
finish

/SOLU
time,1.0
nsubst,1,100,1
outres,all,last
outpr,all,last
ANTYPE,static
NLGEOM,OFF
NROPT,FULL
solve
finish