! ---Koaxialkabel neue Anlage---
! ---Ausführung 2---

fini
/clea

/prep7

kappacu  = 57e6     ! Leitfähigkeit Kupfer
esizecu  = 0.2e-3   ! Elementgroesse im Isolator/Leiter (fuer gute Abbildung Stromverdraengung 1/2 der Eindringtiefenkonstante)
esizeluft= 5e-3     ! Elementgroesse Luft

et,1,plane13        ! Luft
et,2,plane13        ! Isolator
et,3,plane13,6      ! Kupferleiter
et,4,infin110       ! Randelemente

mp,murx,1,1         ! Luft Dielektrizitätskonstante (ideal)
mp,murx,2,1         ! Isolator Dielektrizitätskonstante (ideal)
mp,murx,3,1         ! Kupferleiter+ Dielektrizitätskonstante
mp,rsvx,3,1/kappacu ! Kupferleiter+ spez. Widerstand
mp,murx,4,1         ! Kupferleiter- Dielektrizitätskonstante
mp,rsvx,4,1/kappacu ! Kupferleiter- spez. Widerstand

! Einheit m
b=80e-3
h=10e-3
eckr=2.5e-3
d=0.5e-3
t=2e-3
da=0.5e-3
lo=40e-3


! ---Geometrie---

! -
rect,0,b/2,-d/2-h,-d/2
cyl4,b/2-eckr,-d/2-h+eckr,eckr,270,0,360
cyl4,b/2-eckr,-d/2-eckr,eckr,0,0,90
aovlap,all
adele,4 $adele,5
aadd,all
numcmp,all

! +
rect,0,b/2,d/2,d/2+h
cyl4,b/2-eckr,d/2+h-eckr,eckr,0,0,90
cyl4,b/2-eckr,d/2+eckr,eckr,270,0,360
aovlap,all
adele,5 $adele,6
aadd,3,4,7
numcmp,all

! Isolation
rect,0,b/2+da,-d/2-h-da,d/2+h
cyl4,b/2+da-eckr,-d/2-h-da+eckr,eckr,270,0,360
cyl4,b/2+da-eckr,d/2+h-eckr,eckr,0,0,90
!aovlap,all
aovlap,3,4,5
adele,6,7
aadd,8,4,5
numcmp,all

rect,0,b/2+da-eckr,-d/2-h-da-t,-d/2-h-da
cyl4,b/2+da-eckr,-d/2-h-da+eckr,eckr+t,270,eckr,360
rect,b/2+da,b/2+da+t,-d/2-h-da+eckr,d/2+h-eckr
cyl4,b/2+da-eckr,d/2+h-eckr,eckr+t,0,eckr,90
rect,lo/2,b/2+da-eckr,d/2+h,d/2+h+t
aadd,4,5,6,7,8
numcmp,all

! Luft
cyl4,,,80e-3,90,,-90
cyl4,,,85e-3,90,80e-3,-90
aovlap,all
numcmp,all

!asel,s,area,,5$aplot
/pnum,area,1
aplot


! ---Vernetzung---
! A1:Leiter+ A2:Rand A3:Leiter- A4:Luft A5:Außenhülle Leiter- A6:Isolator Luft
! Vernetzung Leiter
esize,esizecu
type,3
mat,3
amesh,1
mat,4
amesh,3
amesh,5

! Vernetzung Isolation
esize,esizecu
type,2
mat,2
amesh,6

! Vernetzung Luft
csys,1
esize,esizeluft
lesize,42,,,18,10
lesize,43,,,18,10

lesize,34,,,50
lesize,35,,,50
lesize,36,,,1
lesize,37,,,1

type,1
mat,1
amesh,4

! Vernetzung Randelemente
type,4
mat,1
amesh,2
nsel,s,loc,x,85e-3
sf,all,inf
alls
csys,0

! ---Kopplung---
esel,s,mat,,3             ! Leiterelemente +
nsle,                     ! alle Knoten
cp,next,volt,all          ! Kopplung des Potentials (Spannung)
*get,nplus,node,,num,min  ! niedrigste Knotennummer
alls
esel,s,mat,,4             ! Leiterelemente -
nsle,                     ! alle Knoten
cp,next,volt,all          ! Kopplung des Potentials (Spannung)
*get,nminus,node,,num,min ! niedrigste Knotennummer
alls

save,,,,model

! ---Lösung---
/solu
antype,trans              ! transiente Rechnung
outres,all,all            ! alle Zwischenschritte
stromamp = 630000         ! Stromamplitude (A)
tend = 1/12100            ! Zeit Ende (rund 1/4 Periode mit X kHz)
steps= 60                 ! Schritte
pi   = 4*atan(1)

*do,i,0,17                !*do,i,0,steps
  time,i*tend/steps+1e-12
  arg=sin(2*pi*i/steps)
  f,nplus,amps,1/2*stromamp*arg
  f,nminus,amps,-1/2*stromamp*arg
  solve
*enddo

/eof