finish
/CLEAR,START
/NOPR
/FILENAME,Balken
/TITLE,Balken
/PREP7						 
*afun,deg                                        !Winkelangaben in Deg
/UNITS,SI					 !SI-Einheiten
/VIEW,1,1,1,1
csys,0

!*************************************************
!Materialkennwerte
mp,ex,1,2.1e5					 !E-Modul [N/mm^2]
mp,nuxy,1,0.3					 !Querkontraktionszahl
mp,alpx,1,1.2e-5                                 !alpha T
mptemp,1,20

!*************************************************
!Parameter:
B1=75       !halbe  1 [mm]
B2=75						 !halbe  2 [mm]
B3=75						 !Abstand A [mm]
B4=75						 ! 1 [mm]
B5=75						 ! 2 [mm]
B6=75						 ! 3 [mm]
B7=75						 ! 4 [mm]
B8=75					 ! 1 [mm]
B9=75						 ! 2 [mm]
B10=65      	 ! 3 [mm]

H1=0						 !Höhe 1 [mm]
H2=11.5						 !Höhe 2 [mm]
H3=12.9						 !Höhe 3 [mm]
H4=28.5						 !Höhe 4 [mm]
H5=62.5						 !Höhe 5 [mm]
H6=92.25					 !Höhe 6 [mm]
H7=121						 !Höhe 7 [mm]
H8=134.5					 !Höhe 8 [mm]
H9=164.5					 !Höhe 9 [mm]
H10=170						 !Höhe 10 [mm]

L1=135                                           !Abstand Mittelpunkt zum Loch [mm]
X1=85                                            !Abstand UK zum Loch [mm]
D1=13                                            !Lochdurchmesser [mm]

L=600                                            !Läng [mm]
F=220000                                         ! [N]
FT=1823000                                       !max [N]
A=7686                                           !Fläche [mm^2]
LF=0                                             !Abstand zu Krafteinleitungspunkt

ET,41,SURF154                                    !zum Aufbringen der Flächenlast
KEYOPT,41,11,2

!*************************************************
!Erzeugen der Keypoints:
K, 1, B1, H1, 0,
K, 2, B2, H2, 0,
K, 3, B3, H3, 0,
K, 4, B4, H4, 0,
K, 5, B5, H5, 0,
K, 6, B6, H6, 0,
K, 7, B7, H7, 0,
K, 8, B8, H8, 0,
K, 9, B9, H9, 0,
K, 10, B10, H10, 0,
K, 11, 0, H10, 0,
K, 12, 0, 0, 0

!*************************************************
!Geometrie:
L, 1, 2						 !Linie 1 von Keypoint 1 zu Keypoint 2
L, 2, 3						 !Linie 2
L, 3, 4						 !Linie 3
L, 4, 5						 !Linie 4
L, 5, 6						 !Linie 5
L, 6, 7						 !Linie 6
L, 7, 8						 !Linie 7
L, 8, 9						 !Linie 8
L, 9, 10					 !Linie 9
L, 10, 11					 !Linie 10
L, 12, 1					 !Linie 11

LFILLT,9,10,13,0			!Ausrundung L21 zwischen Linie 9 und Linie 10

LSYMM, X, ALL,,,0,1,0				 !Spiegeln der bereits erzeugten Linien      LSYMM, Ncomp, NL1, NL2, NINC, KINC, NOELEM, IMOVE

ALLS
LSEL,S,LOC,Y,0
LSEL,R,LOC,Z,0
LGLUE,ALL                                        !untere Linien verbinden

ALLS
LSEL,S,LOC,Y,H10
LSEL,R,LOC,Z,0
LGLUE,ALL                                        !obere Linien verbinden

ALLS
AL, ALL						 !Erzeugen der Flaeche

VEXT,ALL,,,0,0,L/2,,		        	 !Erzeugen des Volumens durch Extrudieren in Z-Richtung

WPOFFS,0,0,L/2
ALLS
ASEL,S,LOC,Z,L/2
VEXT,ALL,,,0,0,L/2,,                             !zweites Stück
WPOFFS,0,0,L/2
ALLS
ASEL,S,LOC,Z,L
VEXT,ALL,,,0,0,L/2,,                             !drittes Stück
ALLS
VADD, ALL

!*************************************************
!Spiegeln
ALLS
!VGEN,2,ALL,,,0,0,L/2,,0,1                       !alles in den Ursprung verschieben
VSYMM,Z,ALL,,,,0,0,0                             !VSYMM, Ncomp, NV1, NV2, NINC, KINC, NOELEM, IMOVE
VADD,ALL

!*************************************************
!Ellipse für Krafteinleitung erzeugen
WPOFFS,0,H10,LF                                    !Ort der Krafteinleitung einstellen
WPROTA,0,-90,0
CYL4,0,0,15                                        !Kreis erzeugen
ASEL,S,LOC,Y,H10
ASEL,R,LOC,X,0
!ARSCALE,ALL,,,0.75,,,,0,1                        !Kreis zu Ellipse
WPROTA,0,90,0
WPOFFS,0,-H10,-LF
ALLS

!*************************************************
!Vernetzen
et,1,solid185					 !Brick-Elemente ohne Zwischenknoten
MSHAPE, 1, 3D					 !3D-Elemente (Tet)
SMRTSIZE,8
MSHKEY,0
VMESH,ALL
EPLOT

ALLS
ASEL,S,LOC,Y,H10
ASEL,R,LOC,X,0
AMESH,ALL

ALLS
LSEL,s,RADIUS,,15,,,0
LREFINE,ALL,,,2,1,,OFF

!*************************************************
!Lager
ALLS
LSEL,S,LOC,Z,-L/2
LSEL,R,LOC,Y,0
NSLL,S,1
D,ALL,UY                                         !Lager 1 erzeugen

ALLS
LSEL,S,LOC,Z,L/2
LSEL,R,LOC,Y,0
NSLL,S,1
D,ALL,UY                                         !Lager 2 erzeugen

ALLS
LSEL,S,LOC,Z,-1.5*L
LSEL,R,LOC,Y,0
NSLL,S,1
D,ALL,UY                                         !Lager 3 erzeugen

ALLS
LSEL,S,LOC,Z,1.5*L
LSEL,R,LOC,Y,0
NSLL,S,1
D,ALL,UY                                         !Lager 4 erzeugen

ALLS
KSEL,S,LOC,Z,L/2
KSEL,R,LOC,Y,0
KSEL,R,LOC,X,0
NSLK,S,1
D,ALL,UZ                                         !Festhaltung in Längsrichtung
D,ALL,UX                                         !Festhaltung 1 in Querrichtung

ALLS
KSEL,S,LOC,Z,-L/2
KSEL,R,LOC,Y,0
KSEL,R,LOC,X,0
NSLK,S,1
D,ALL,UX                                         !Festhaltung 2 in Querrichtung

ALLS
KSEL,S,LOC,Z,-1.5*L
KSEL,R,LOC,Y,0
KSEL,R,LOC,X,0
NSLK,S,1
D,ALL,UX                                         !Festhaltung 3 in Querrichtung

ALLS
KSEL,S,LOC,Z,1.5*L
KSEL,R,LOC,Y,0
KSEL,R,LOC,X,0
NSLK,S,1
D,ALL,UX                                         !Festhaltung 4 in Querrichtung
/REP,FAST

!*************************************************
!Kraft in Knoten einleiten
ALLS
ASEL,S,LOC,Y,H10
ASEL,R,LOC,X,0
NSLA,S,1                                         !Nodes in Ellipse wählen
CP,n,ALL,ALL                                        !Koppeln der Nodes in allen Dimensionen

!TYPE,41
!ESURF
!SFA,ALL,1,PRES,,F,0,-1,0

!clocal,100,1,0,H10,0                            !lokales kreisförmiges Koordinatensystem 100 erstellen
!csys,100
!nsel,s,loc,x,7.5                                   !Knoten wählen
!nsel,r,loc,z,0

ALLS
NSEL,S,LOC,X,LF
NSEL,R,LOC,Y,H10
NSEL,R,LOC,Z,0
F,ALL,FY,-F                                     !Aufbringen der Einzellast F in vert. Richtung
F,ALL,FX,-F/2                                   !Last in horizontaler Richtung

ALLS
ASEL,S,LOC,Z,1.5*L
ASEL,A,LOC,Z,-1.5*L
DA,ALL,SYMM,ALL                                  !Einspannung

ALLS
TREF,20                                          !Referenztemperatur von 20°C
BFE,ALL,TEMP,,-40                                !Abkühlung aller Elemente auf -40°C
/REPLOT

!*************************************************
!Solution
/SOL
SOLVE
FINISH

!*************************************************
!Postprocessing
/POST1
/EFACET,1
PLNSOL, S,EQV, 0,1.0