fini
/clear
!--------------------------------------------------------------------------------
/prep7
et,1,226,110 

!---Materialdaten
mp,kxx,1,0.1 
mp,kxx,2,54
mp,kxx,3,429		!Wärmeleitfähigkeit W/m*K Ag

mp,c,1,793 
mp,c,2,520 
mp,c,3,232		!Wärmemapazität J/kg*K Ag

mp,dens,1,5.85e3 
mp,dens,2,5.5e3 
mp,dens,3,10.49e3	!Dichte kg/m³ Ag

mp,rsvx,1,0.001
mp,rsvx,2,24.5 
mp,rsvx,3,1.6e-8	!spez. Widersatnd Ohm*m Ag


!--- Geometrie
l1=20e-3
l2=5e-3
ag=1e-3
rand=1e-3

!gestückelte Volumen mit extra Randvolumen

block,0,l1,rand,l1-rand,rand,l1-rand
block,0,l1,0,rand,0,rand
block,0,l1,0,rand,rand,l1-rand
block,0,l1,rand,l1-rand,0,rand
block,0,l1,l1-rand,l1,0,rand
block,0,l1,l1-rand,l1,rand,l1-rand
block,0,l1,l1-rand,l1,l1-rand,l1
block,0,l1,rand,l1-rand,l1-rand,l1
block,0,l1,0,rand,l1-rand,l1

block,0,-ag,rand,l1-rand,rand,l1-rand

block,-ag,-ag-l2,rand,l1-rand,rand,l1-rand
block,-ag,-ag-l2,0,rand,0,rand
block,-ag,-ag-l2,0,rand,rand,l1-rand
block,-ag,-ag-l2,rand,l1-rand,0,rand
block,-ag,-ag-l2,l1-rand,l1,0,rand
block,-ag,-ag-l2,l1-rand,l1,rand,l1-rand
block,-ag,-ag-l2,l1-rand,l1,l1-rand,l1
block,-ag,-ag-l2,rand,l1-rand,l1-rand,l1
block,-ag,-ag-l2,0,rand,l1-rand,l1

block,l1,l1+ag,rand,l1-rand,rand,l1-rand

block,l1+ag,l1+l2+ag,rand,l1-rand,rand,l1-rand
block,l1+ag,l1+l2+ag,0,rand,0,rand
block,l1+ag,l1+l2+ag,0,rand,rand,l1-rand
block,l1+ag,l1+l2+ag,rand,l1-rand,0,rand
block,l1+ag,l1+l2+ag,l1-rand,l1,0,rand
block,l1+ag,l1+l2+ag,l1-rand,l1,rand,l1-rand
block,l1+ag,l1+l2+ag,l1-rand,l1,l1-rand,l1
block,l1+ag,l1+l2+ag,rand,l1-rand,l1-rand,l1
block,l1+ag,l1+l2+ag,0,rand,l1-rand,l1

vglue,all 

!---Vernetzen
meshsize=l2/2

vsel,s,loc,x,-ag-l2/2 
esize,meshsize 
type,1 
mat,2 
mshkey,1 
vmesh,all

vsel,s,loc,x,-ag/2 
esize,meshsize 
type,1 
mat,3 
mshkey,1 
vmesh,all

vsel,s,loc,x,l1/2 
esize,meshsize 
type,1 
mat,1 
mshkey,1 
vmesh,all

vsel,s,loc,x,l1+ag/2 
esize,meshsize 
type,1 
mat,3 
mshkey,1 
vmesh,all

vsel,s,loc,x,l1+ag+l2/2 
esize,meshsize 
type,1 
mat,2 
mshkey,1 
vmesh,all

!---elektrische Parameter
eplot
nsel,s,loc,x,l1+l2+ag 
cp,1,volt,all 
*get,n_ein,node,,num,min
nsel,s,loc,x,-l2-ag 
d,all,volt,0

u1=440 
r1=1e-4
abst=1e-3
et,3,circu124,0 
r,3,r1
nsel,all
*get,node_max,node,,num,max
n,node_max+1,l1+l2+ag+abst,l1,0
type,3 
real,3 
e,node_max+1,n_ein 
d,node_max+1,volt,u1
*get,element_max,elem,,num,max


!----Lösung
allsel 
/solu 

zeitende=2 

antype,trans 
outres,all,all 
autots,on 
nsubst,100,200,10
kbc,1 
time,zeitende

solve

/post1
plns,temp
antime,100,0,,1,1,0,0