FINISH
/CLEAR,START
/PREP7
! No polynomial elements
/PMETH,OFF,1
 
! Set electric preferences
KEYW,PR_ELMAG,1
KEYW,MAGELC,1
 
! Select element
ET,1,SOLID123
 
! Material properties
MP,PERX,1,1e10  ! Metal
MP,RSVX,1,0.0   !
MP,PERX,2,1.0   ! Gas
MP,PERX,3,4.0   ! Permittivity of FR4

! Construct the structure
dist1 = 0.0005 ! thickness of copper plates
dist2 = 0.005   ! thickness of FR4
dist3 = 0.03    ! thivkness of gas between 2 GEMs
dist4 = 0.01625

xstripe = 0.008
ystripe = 0.034
holeradius1 = 0.00375
holeradius2 = 0.00325
holeradius3 = 0.00275
xholepos = 0.
yholepos = 0.
xcelldimention = 0.014
ycelldimention = 0.02425

dist4 = 3*dist3+3*dist2+6*dist1
depth = dist2+dist1


x1 = xcelldimention/2-xstripe/2
x2 = xcelldimention/2+xstripe/2
y1 = ycelldimention/2-ystripe/2
y2 = ycelldimention/2+ystripe/2
CON4, xholepos, yholepos, holeradius1, holeradius2, dist2/2               ! 1
CON4, xholepos, yholepos, holeradius3, holeradius1, dist2                 ! 2
CYL4, xholepos, yholepos, holeradius1, 0.0, holeradius1, 360.0, dist1     ! 3
VGEN, 1, 3, 3, , 0, 0, -dist1,0,0,1                                       ! 3
VGEN, 2, 3, 3, , 0, 0, dist2+dist1,0,0,0                                  ! 4
VGEN, 2, 1, 4, , xcelldimention, 0, 0, 0, 0, 0                            ! 5-8
VGEN, 2, 1, 8, , 0, ycelldimention, 0, 0, 0, 0                            ! 9-16
VGEN, 2, 1, 4, , xcelldimention/2, ycelldimention/2, 0, 0, 0, 0 !Holes    ! 17-20
BLOCK,   0,  xcelldimention,     0, ycelldimention,   depth,  depth+dist1 ! 21: Hole Help Plain
VADD, all                                                                 ! 22: plain + Holes
BLOCK,   0,  xcelldimention,     0, ycelldimention,  0, dist2             ! 1: FR4
BLOCK,   0,  xcelldimention,     0, ycelldimention,       0, -dist1       ! 2: strip1 GEM
BLOCK,   0,  xcelldimention,     0, ycelldimention,  dist2,  depth        ! 3: strip2 GEM
VSBV,  1, 22, , , KEEP                                                    ! 1 -> 4
VSBV,  2, 22, , , KEEP                                                    ! 2 -> 1
VSBV,  3, 22, , ,                                                         ! 3 -> 2
VGEN,    3,   all, , , 0, 0, dist3+2*dist1+dist2, 0, 0, 0  ! :4+6+9 FR4, 1+3+7 stripe1, 2+5+8 stripe2
BLOCK,   0,  xcelldimention,     0, ycelldimention, -dist3-dist1, -dist3-2*dist1 ! 10: strip3
BLOCK,   0,  xcelldimention,     0, ycelldimention,  dist4-dist1,  dist4  ! 11: strip4
!BLOCK,   x1, x2,     0, ycelldimention, -dist3+11*dist1, -dist3+12*dist1  ! 11: xstripe
!BLOCK,   x1, x2,     0, ycelldimention,    -dist3+dist1, -dist3+11*dist1  ! 12: FR4 xstripe
!BLOCK,   0,  xcelldimention, y1,    y2,    -dist3+dist1,          -dist3  ! 13: ystripe
BLOCK,   0,  xcelldimention,     0, ycelldimention,       -dist3-2*dist1,  dist4  ! 12: Gas

VSBV, 12,     1, , , KEEP ! 12 -> 13
VSBV, 13,     2, , , KEEP ! 13 -> 12
VSBV, 12,     3, , , KEEP ! 12 -> 13
VSBV, 13,     4, , , KEEP ! 13 -> 12
VSBV, 12,     5, , , KEEP ! 12 -> 13
VSBV, 13,     6, , , KEEP ! 13 -> 12
VSBV, 12,     7, , , KEEP ! 12 -> 13
VSBV, 13,     8, , , KEEP ! 13 -> 12
VSBV, 12,     9, , , KEEP ! 12 -> 13
VSBV, 13,    10, , , KEEP ! 13 -> 12
VSBV, 12,    11, , , KEEP ! 12 -> 13

! Glue everything together: 1 stripe2, 2 stripe3, 3 stripe4, 5 stripe5,  7 stripe6, 8 stripe7, 10 stripe1, 11 stripe8, 13 gas bigining at the end 4 FR4, 6 FR4, 9 FR4
VGLUE, all



! Assign material attributes
VSEL, S, VOLU, ,  1,  3 ! Metal strips1
VATT, 1, ,1
VSEL, S, VOLU, ,  5     ! Metal strips1
VATT, 1, ,1
VSEL, S, VOLU, ,  7,  8 ! Metal strips1
VATT, 1, ,1
VSEL, S, VOLU, , 10, 11 ! Metal strips1
VATT, 1, ,1
VSEL, S, VOLU, , 13     ! Gas volume
VATT, 2, ,1
VSEL, S, VOLU, ,  4     ! Substrate
VATT, 3, ,1
VSEL, S, VOLU, ,  6     ! Substrate
VATT, 3, ,1
VSEL, S, VOLU, ,  9     ! Substrate
VATT, 3, ,1

! Voltage boundary conditions on the metal
VSEL, S, VOLU, , 11  ! stripe 1
ASLV, S
DA, ALL, VOLT, 5000
VSEL, S, VOLU, ,  8  ! stripe 2
ASLV, S
DA, ALL, VOLT, 4500
VSEL, S, VOLU, ,  7  ! stripe 3
ASLV, S
DA, ALL, VOLT, 3500
VSEL, S, VOLU, ,  5  ! stripe 4
ASLV, S
DA, ALL, VOLT, 3000
VSEL, S, VOLU, ,  3  ! stripe 5
ASLV, S
DA, ALL, VOLT, 2000
VSEL, S, VOLU, ,  2  ! stripe 6
ASLV, S
DA, ALL, VOLT, 1500
VSEL, S, VOLU, ,  1  ! stripe 7
ASLV, S
DA, ALL, VOLT, 500
VSEL, S, VOLU, , 10  ! xstripe
ASLV, S
DA, ALL, VOLT, 0

VSEL, U, VOLU, , 10  
ASEL, S, AREA, ,133
ASEL, A, AREA, ,139,141
DA, ALL, SYMM


! Meshing options
VSEL, S, VOLU, , 13  ! Only mesh the gas
ASLV, S
MSHKEY,0
SMRTSIZE, 4
VMESH, 13, 13

! Solve the field
/SOLU
SOLVE

! Write the solution
/POST1
/OUTPUT, field, lis
PRNSOL
/OUTPUT

! Write the mesh to files
/OUTPUT, NLIST, lis
NLIST,,,,COORD
/OUTPUT
 
/OUTPUT, ELIST, lis
ELIST
/OUTPUT
 
/OUTPUT, MPLIST, lis
MPLIST
/OUTPUT
 
! Show the solution
/EFACET,1
PLNSOL, VOLT,, 0