/title, Langevin-Bolt-Transducer
/Prep7

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!
!!	Create Geometrie of 2D-Axissymetric Transducer
!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!!	Frontmass

k,1,0,0,0
k,2,0,60e-3,0
k,3,3e-3,60e-3,0
k,4,3e-3,35e-3,0
k,5,10e-3,35e-3,0
k,6,10e-3,25e-3,0
k,7,5e-3,25e-3,0
k,8,5e-3,0,0

kplot

a,1,2,3,4,5,6,7,8

aplot

!!	Backmass

k,9,0,65e-3,0
k,10,0,84e-3,0
k,11,10e-3,84e-3,0
k,12,10e-3,50e-3,0
k,13,3e-3,50e-3,0
k,14,3e-3,65e-3,0

kplot

a,9,10,11,12,13,14

aplot

!!	Piezo-elements and ceramics

k,15,3e-3,47e-3,0
k,16,10e-3,47e-3,0
k,17,3e-3,44e-3,0
k,18,10e-3,44e-3,0
k,19,3e-3,41e-3,0
k,20,10e-3,41e-3,0
k,21,3e-3,38e-3,0
k,22,10e-3,38e-3,0

kplot

a,4,21,22,5	!!ceramic
a,21,19,20,22	!!piezo	(actuate)
a,19,17,18,20	!!piezo	(actuate)
a,17,15,16,18	!!ceramic
a,15,13,12,16	!!piezo (measure)

aplot

!!	glue the piezo-stack-elements

asel,s,,,3,7
aglue,all
allsel

!!	glue the front- to the back-mass

asel,s,,,1
asel,a,,,2
aglue,all
allsel

!!	define element-types

et,1,PLANE223,1001,,1	!!piezo-type VORSICHT: hier stimmt was mit der Piezo-Keyoption nicht!!!
et,2,PLANE82,,,1	!!isotropic material


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!
!!	define material properties
!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!!	upper piezo (actuate)
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

/com	Sonox P8	Y-polarized				
					
/com	Stiffness					
TB,	ANEL,	1	,	1	,	0
TBDATA,	1,	1.5712E+11	,	8.0664E+10	,	9.4680E+10
TBDATA,	7,	1.2468E+11	,	8.0664E+10		
TBDATA,	12,	1.5712E+11				
TBDATA,	16,	2.7593E+10				
TBDATA,	19,	2.7593E+10				
TBDATA,	21,	3.1218E+10				
						
/com	Piezo matrix					
TB,	PIEZ,	1				
TBDATA,	2,	-4.5612				
TBDATA,	5,	14.5958				
TBDATA,	8,	-4.5612				
TBDATA,	10,	10.4852				
TBDATA,	15,	10.4852				
						
/com	Permittivity					
EMUNIT,	EPZRO,	8,85E-12				
MP,	PERX,	1	,	7550		
MP,	PERY,	1	,	46		
MP,	PERZ,	1	,	7550		
/com	Density					
MP,	DENS,	1	,	7700		




!!	lower piezo (actuate)
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

/com	Sonox P8	Y-polarized				
						
/com	Stiffness					
TB,	ANEL,	2	,	1	,	0
TBDATA,	1,	1.5712E+11	,	8.0664E+10	,	9.4680E+10
TBDATA,	7,	1.2468E+11	,	8.0664E+10		
TBDATA,	12,	1.5712E+11				
TBDATA,	16,	2.7593E+10				
TBDATA,	19,	2.7593E+10				
TBDATA,	21,	3.1218E+10				
						
/com	Piezo matrix					
TB,	PIEZ,	2				
TBDATA,	2,	4.5612				
TBDATA,	5,	-14.5958				
TBDATA,	8,	4.5612				
TBDATA,	10,	-10.4852				
TBDATA,	15,	-10.4852				
						
/com	Permittivity					
EMUNIT,	EPZRO,	8.85E-12				
MP,	PERX,	2	,	7550		
MP,	PERY,	2	,	46		
MP,	PERZ,	2	,	7550		
/com	Density					
MP,	DENS,	2	,	7700		




!!	piezo (measure)
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

/com	Sonox P5	Y-polarized				
						
/com	Stiffness					
TB,	ANEL,	3	,	1	,	0
TBDATA,	1,	1.2268E+11	,	7.6535E+10	,	8.0869E+10
TBDATA,	7,	1.1019E+11	,	7.6535E+10		
TBDATA,	12,	1.2268E+11				
TBDATA,	16,	2.8071E+10				
TBDATA,	19,	2.8071E+10				
TBDATA,	21,	2.0907E+10				
						
/com	Piezo matrix					
TB,	PIEZ,	3				
TBDATA,	2,	-2.1987				
TBDATA,	5,	22.0308				
TBDATA,	8,	-2.1987				
TBDATA,	10,	15.4391				
TBDATA,	15,	15.4391				
						
/com	Permittivity					
EMUNIT,	EPZRO,	8.85E-12				
MP,	PERX,	3	,	261		
MP,	PERY,	3	,	-344		
MP,	PERZ,	3	,	261		
/com	Density					
MP,	DENS,	3	,	7650		




!!	ceramics
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

mp,dens,4,3595
mp,ex,4,4.25E+11
mp,nuxy,4,0.33

!!	titanium Ti6V4Al
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

mp,dens,5,4.43E+003
mp,ex,5,1.14E+011
mp,nuxy,5,0.342

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!
!!	assign materials
!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!!	front-mass

asel,s,,,8
aatt,5,,2

!!	back-mass

asel,s,,,9
aatt,5,,2

!!	ceramics

asel,s,,,4
aatt,4,,2

asel,s,,,7
aatt,4,,2

!!	sensor piezo

asel,s,,,3
aatt,3,,1

!!	lower piezo

asel,s,,,5
aatt,2,,1

!!	upper piezo

asel,s,,,6
aatt,1,,1

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!
!!	MESHING
!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!


allsel
aplot
esize,1.5e-3
amesh,all


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!
!!	Loading
!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!!	ground-electrodes

nsel,s,loc,y,41e-3
nsel,a,loc,y,47e-3
nsel,r,loc,x,3e-3,10e-3
cp,1,volt,all
*get,n_ground,node,0,num,min
allsel

!!	supply-electrode

nsel,s,loc,y,44e-3
nsel,r,loc,x,3e-3,10e-3
cp,3,volt,all
*get,n_supply,node,0,num,min
allsel

d,n_ground,volt,0
d,n_supply,volt,10

allsel,all

!!	axis-symmetry

nsel,s,loc,x,0
dsym,symm
allsel

!!	Mounting


!nsel,s,loc,y,25e-3
!nsel,r,loc,x,10e-3
!d,all,uy
eplot


fini


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!
!!	STATIC SOLUTION
!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

/solu

v_prstr=-1e5
antype,0
PSTRES,ON
lsel,s,loc,y,50e-3
sfl,all,press,v_prstr
allsel
lsel,s,loc,y,35e-3
sfl,all,press,v_prstr
allsel
SOLVE
SFLLI, ALL
FLST,2,2,4,ORDE,2
FITEM,2,12
FITEM,2,4
SFLDELE,P51X,PRES
fini