/clear

/prep7

! ------------ PARAMETERS ----------------------------------------

K=1E9 !elastiche Anfangssteifigkeit

!------------ ELEMENT TYPES -------------------------------------

ET,1,SOLSH190 ! 3D 8-node solid-shell element
ET,2,SOLSH190 ! 3D 8-node solid-shell element
ET,5,SOLSH190 ! 3D 8-node solid-shell element
ET,3,TARGE170 ! 2D 4-Knoten target element
ET,4,CONTA173 ! 2D 4-Knoten contact element
KEYOPT,4,12,5 ! bonded always contact Option

!------------ MATERIAL DEFINITION -------------------------------

MP,EX,1,3.6E4
MP,EY,1,1E4
MP,EZ,1,1E4
MP,GXY,1,4E3
MP,GYZ,1,4E3
MP,GXZ,1,4E3
MP,PRXY,1,0.3
MP,PRXZ,1,0.3
MP,PRYZ,1,0.38

! cohesive zone Materialmodell:
TB,CZM,2,1,1,CBDE
TBDATA,1,40,1,40,1,1E-8

!------Geometrie--------

k,1,0,0,0
k,2,60,0,0
k,3,60,60,0
k,4,0,60,0
k,5,0,0,-0.5
k,6,60,0,-0.5
k,7,60,60,-0.5
k,8,0,60,-0.5
V,1,2,3,4,5,6,7,8

k,9,0,0,-0.5
k,10,60,0,-0.5
k,11,60,60,-0.5
k,12,0,60,-0.5
k,13,0,0,-2.5
k,14,60,0,-2.5
k,15,60,60,-2.5
k,16,0,60,-2.5
V,9,10,11,12,13,14,15,16

k,17,0,0,-2.5
k,18,60,0,-2.5
k,19,60,60,-2.5
k,20,0,60,-2.5
k,21,0,0,-3
k,22,60,0,-3
k,23,60,60,-3
k,24,0,60,-3
V,17,18,19,20,21,22,23,24

!------------ MESHING -------------------------------------------

ESIZE,,4
MSHKEY,1

LSEL,S,LENGTH,,60
LESIZE,ALL,,,10,,1
TYPE,1
VEORIENT,1,THIN
VMESH,1

TYPE,2
LOCAL,11,0,0,0,0,90
ESYS,11
VEORIENT,2,THIN
VMESH,2

TYPE,5
ESYS,0
VEORIENT,3,THIN
VMESH,3

CSYS,0

! Target Elemente:

ESEL,S,TYPE,,1
NSLE,S
NSEL,R,LOC,Z,-0.5
Type,3
MAT,2
REAL,3
ESURF

ESEL,S,TYPE,,2
NSLE,S
NSEL,R,LOC,Z,-2.5
Type,3
MAT,2
REAL,4
ESURF

! Contact Elemente

ESEL,S,TYPE,,2
NSLE,S
NSEL,R,LOC,Z,-0.5
Type,4
MAT,2
REAL,3
RMODIF,3,3,-K 		!elastische Anfangssteifigkeit
RMODIF,3,12,-K
ESURF

ESEL,S,TYPE,,5
NSLE,S
NSEL,R,LOC,Z,-2.5
Type,4
MAT,2
REAL,4
RMODIF,3,3,-K 		!elastische Anfangssteifigkeit
RMODIF,3,12,-K
ESURF


!------------ BOUNDARY CONDITIONS --------------------------------

!kreisförmige Lagerung um den Fallturm nachzubilden

LOCAL,12,CYLIN,30,30,0
cSYS,12
NSEL,S,LOC,X,20,60
NSEL,R,LOC,Y,0,360
D,ALL,ALL,0
CSYS,0

!------------------- SOLUTION --------------------------

/SOLU
SOLCONTROL,ON,ON
NLGEOM,ON
TIME,1
OUTRES,ALL,ALL

!zentraleKraft:

NSEL,S,LOC,X,30
NSEL,R,LOC,Y,30
NSEL,R,LOC,Z,0
F,ALL,FZ,-2000

ALLSEL,ALL
SOLVE
FINISH

!------------Postprocessing----------------

/POST1

PLNSOL,U,SUM !total displacement
PLNSOL,S,EQV

/DEVICE,VECTOR,1 	!wireframe Modus an
PLNSOL,CONT,GAP,0,1 	!contour plot des contact gaps
PLNSOL,CONT,SLIDE,0,1	!contour plot der Verschiebung
PLNSOL,CONT,SFRIC,0,1 	!contour plot der Scherkräfte

NSEL,S,LOC,Z,-0.5	!obere Schichtwechsel
NSEL,S,LOC,Z,-2.5 	!unterer Schichtwechsel

PLNSOL,CONT,STAT,0,1 	!contact status(3=nicht getrennt/0=komplett offen)