!
!************************ Thermische Modellierung der Alugussproben ************************
!
!******** Variablendefinition************
!
! Angaben in SI-Einheiten
mm=1e-3
!
!einstellbare Parameter
!
f = 0.3					!Modulationsfrequenz der Laserstrahlung in Hz
anz = 6					!Anzahl der Lastschritte
!
dalo = 1.75*mm			!Dicke Aluguss unten (variabel)
dalu = 1.75*mm			!Dicke Aluguss oben (variabel)
!
!feste Parameter
!
dpl = 0.15*mm			!Dicke Polyimidschicht je oben und unten
dpzt = 0.2*mm			!Dicke PZT-Platte
!
lal = 20*mm				!Länge Aluguss je links und rechts (Ausschnitt aus Probe) 
lpl = 4.75*mm			!Länge Polyimideinbettung je links und rechts der PZT-Platte 
lpzt = 30*mm			!Länge PZT-Platte
!
!y = Dicke
y1 = dalu
y2 = dalu+dpl
y3 = dalu+dpl+dpzt
y4 = dalu+2*dpl+dpzt
y5 = dalu+dalo+2*dpl+dpzt
!
!x = Länge
x1 = lal
x2 = lal+lpl
x3 = lal+lpl+lpzt
x4 = lal+2*lpl+lpzt
x5 = 2*lal+2*lpl+lpzt
!
!******** Modellerstellung (Preprocessor) **********
!
/PREP7
!
!******** Elementtyp festlegen
!
ET,1,PLANE55			!2-D Temperatur-Element

!******** Materialien definieren
!
!* 1: Aluminiumdruckguss
!
MP,DENS,1,2790			!Dichte in kg/m^3
!
MP,KXX,1,140			!Wärmeleitfähigkeit in W/mK
!
MP,C,1,840				!spez. Wärmekapazität in J/kgK
!
!* 2: Polyimid (Kapton)
!
MP,DENS,2,1432
!
MP,KXX,2,0.166
!
MP,C,2,890
!
!* 3: PZT (PIC 255)
!
MP,DENS,3,7800
!
MP,KXX,3,1.1
!
MP,C,3,350
!
!********* Geometrie
!
!Aluminiumdruckguss
RECT,0,x5,0,y1
RECT,0,x5,y4,y5
RECT,0,x1,y1,y4
RECT,x4,x5,y1,y4
!
!Polyimid
RECT,x1,x4,y1,y2
RECT,x1,x4,y3,y4
RECT,x1,x2,y2,y3
RECT,x3,x4,y2,y3
!
!PZT
RECT,x2,x3,y2,y3
!
ASEL,ALL
AGLUE,ALL
!
!******** Vernetzung
!
!*Elementattribute zuweisen (Material)
!
!Aluminiumdruckguss
asel,s,loc,y,0,y1
asel,a,loc,y,y4,y5
aatt,1
!
asel,s,loc,x,0,x1
asel,a,loc,x,x4,x5
aatt,1
!
!Polyimid
asel,s,loc,x,x1,x4
asel,r,loc,y,y1,y2
aatt,2
!
asel,s,loc,x,x1,x4
asel,r,loc,y,y3,y4
aatt,2
!
asel,s,loc,x,x1,x2
asel,r,loc,y,y2,y3
aatt,2
!
asel,s,loc,x,x3,x4
asel,r,loc,y,y2,y3
aatt,2
!
!PZT
asel,s,loc,x,x2,x3
asel,r,loc,y,y2,y3
aatt,3
!
asel,all
!
!*Steuerparameter
!
!Elementform: viereckig
mshape,0,2D				!Befehl hat keine Auswirkung?
!
!strukturiertes Netz (mit vierseitigen Flächenelementen)
!mshkey,1				!geht nur bei Flächen mit 4 Linien
!
!Anzahl der Elemente auf den Linien
!x-Richtung
lsel,s,length,,lpzt		!PZT
lesize,all,,,10
!
lsel,s,length,,lpl		!Polyimid
lesize,all,,,2
!
lsel,s,length,,x1		!Alu
lesize,all,,,10
!
lsel,s,length,,lpzt+2*lpl	!PZT+Polyimid
lesize,all,,,14
!
lsel,s,length,,x5		!Länge des gesamten Modells
lesize,all,,,34

!y-Richtung
lsel,s,length,,dpzt		!PZT und Polyimid
lsel,a,length,,dpl
lesize,all,,,1
!
lsel,s,length,,y1		!Alu
lesize,all,,,1
!
lsel,s,length,,dpzt+2*dpl
lesize,all,,,1
!
alls
amesh,all
!
!***************Lösung (Solution)****************
/SOLU
!
!transiente thermische Analyse
antype,trans
!
!Ausgangstemperatur auf 20°C
tunif,20
!
!Ergebnisausgabe für jeden Zwischenschritt
outres,all,all
!
!Durchführung der Analyse
!
t = 1/(2*f)					!Dauer eines Lastschrittes (halbe Periodendauer)
w = 1						!Wechsel zwischen Laser an/aus
!Do-Schleife zur Abarbeitung der Lastschritte 
*DO,i,1,anz					!von i = 1 bis anz durchlaufen	
	*if,w,eq,1,then
		nsel,s,loc,y,y5			!Wärmestromdichte auf Oberseite des Modells = 780 W/m2*K
		nsel,r,loc,x,x1,x4		!nur im Bereich des Piezowandlers (PZT-Platte + Polyimid)
		sf,all,hflux,780
		alls
		w = 0
		!
	*else
		nsel,s,loc,y,y5			!Wärmestromdichte auf Oberseite des Modells = 0
		nsel,r,loc,x,x1,x4		!nur im Bereich des Piezowandlers (PZT-Platte + Polyimid)
		sf,all,hflux,0
		alls
		w = 1
		!
	*endif
	nsel,s,loc,y				!Temperatur an der Unterseite des Modells auf 20°C
	d,all,temp,20
	alls
	!Zeiteinstellungen
	tges = i/(2*f)
	time,tges					!Zeit am Ende des Lastschrittes
	autots,on					!automatische Zeitschrittweite ein
	deltime,(t/100),(t/100),(t/10),on	!Startschrittweite, min. Schrittweite, max. Schrittweite, on
	kbc,1						!sprungförmige Änderung
	solve						!LS berechnen
*ENDDO
!