{ Unconnected Elements 
https://ww3.cad.de/foren/ubb/Forum15/HTML/001835.shtml#000002
von Kotom-Eng  }

{ Im diesem Macro werden Hinweislinien LEADER_LINE erstellt. 
Da wir das häufig verwenden gibt es in unserer Benutzeroberfläche einen Befehlsbutton zum Löschen.
Befehl:  DELETE GLOBAL INFOS 'leader_kann_weg' END }

{ Warum steht das ausserhalb des Macrotextes ?
  LET KE_uce_tab_name 'uce'   
In das Macro versetzt und umbenannt. }

DEFINE KE_uce_search
  LOCAL Ctr
  LOCAL Nb_elt
  LOCAL Zael_green
  LOCAL Pnt_start
  LOCAL Pnt_ziel
  LOCAL Akt_geo_color
  LOCAL Akt_geo_linetyp
  LOCAL Akt_pfeiltyp
  
  LET KE_uce_tab_name_gv 'uce' { Globale Variable }
  
  INQ_ENV 3     
  LET Akt_geo_color (INQ 201)
  LET Akt_geo_linetyp  (INQ 301)
  INQ_ENV 7
  LET Pnt_start ((INQ 103) -15,-15)
  INQ_ENV 12
  LET Akt_pfeiltyp (INQ 604)
  LET Zael_green 0
  
  INQ_SELECTED_ELEM SELECT LINES ALL OR ARCS ALL OR FILLETS ALL CONFIRM
  LET Nb_elt ( INQ 14 )
  CREATE_LTAB Nb_elt 2 KE_uce_tab_name_gv
  LET Ctr 1
  WHILE (Ctr <= Nb_elt)
    WRITE_LTAB KE_uce_tab_name_gv Ctr 1 ( INQ 332 )
    IF (( INQ 403 ) = LINE )
      WRITE_LTAB KE_uce_tab_name_gv Ctr 2 ( STR ( INQ 101 ))
    ELSE
      WRITE_LTAB KE_uce_tab_name_gv Ctr 2 ( STR ( INQ 103 ))
    END_IF
    WRITE_LTAB KE_uce_tab_name_gv (Nb_elt + Ctr) 1 ( INQ 332 )
    WRITE_LTAB KE_uce_tab_name_gv (Nb_elt + Ctr) 2 ( STR ( INQ 102 ))
    INQ_NEXT_ELEM
    LET Ctr (Ctr+1)
  END_WHILE

  LET Nb_elt ( LTAB_ROWS KE_uce_tab_name_gv )
  LET Ctr 1
  WHILE (Ctr <= Nb_elt)
    SELECT_FROM_LTAB KE_uce_tab_name_gv COLUMN 2 = ( READ_LTAB KE_uce_tab_name_gv Ctr 2 ) END
	LET Pnt_ziel ( READ_LTAB KE_uce_tab_name_gv Ctr 2 )
    IF (( LTAB_ROWS 'sys_select') < 2 )
   {  SHOW SELECT POINTER ( READ_LTAB KE_uce_tab_name_gv Ctr 1 ) CONFIRM RED }
      ADD_CURRENT_INFO 'leader_kann_weg' END
      LEADER_LINE SOLID RED LEADER_ARROW NONE Pnt_start ((VAL Pnt_ziel) -0.2,-0.2 ) END Pnt_start ((VAL Pnt_ziel) -0.2,-0.2 ) END END
      { Zwei Leader_line aufeinander, damit sie keine grünen Punkte haben ;-)  }
      CHANGE_CURRENT_INFO 'leader_kann_weg' '' 
      RGB_COLOR Akt_geo_color LINEPATTERN Akt_geo_linetyp LEADER_ARROW Akt_pfeiltyp END
      LET Zael_green (Zael_green +1)     
    END_IF
    LET Ctr (Ctr+1)
  END_WHILE
  WINDOW FIT
  Fk_show_only_green_vertex     { Eigenständiges Macro siehe Fk_show_only_green_vertex.m }
  IF (Zael_green > 0)
    BEEP DISPLAY  ('Achtung '+(STR Zael_green)+' unzulässige grüne Punkte gefunden, Bitte in Ordnung bringen.') 
  ELSE
    DISPLAY_NO_WAIT 'Prima ! Keine Fehler gefunden. Weiter so ;-)' 
    WAIT 2	
  END_IF	
END_DEFINE