!Flaechenmodell der Peppe

fini
/clear
/filna,Peppe_flae

!Modellgenerierung

/prep7

!Parameter
!Eingabe:
!*********************************************
!*********************************************
!*********************************************
a=8.6
b=12.4
c=14
d=3.2
e=1.2
f=0.4
g=0.15
h=1.4
i=0.15
j=0.4
k=0.4
l=1
!*********************************************
!*********************************************
!*********************************************

!Berechnung der Kordinaten

y1=d $x1=a/2
y2=d $x2=b/2
x3=b/2
y4=l $x4=c/2
y5=l $x5=c/2+7
y6=0 $x6=c/2+7
y7=0 $x7=c/2-k
x8=c/2-k
y9=e+f $x9=a/2+g+h+i
y10=e+f $x10=a/2+g+h
y11=e $x11=a/2+g+h
y12=e $x12=a/2+g
y13=e+f $x13=a/2+g
y14=e+f $x14=a/2

m=-j*j+y4*y4-2*y4*y9+y9*y9
n=(x4-x9)*(x4-x9)
o=(j*j-(x4-x9)*(x4-x9))
y3=(-(j*sqrt(m+n)*(x4-x3)-j*j*y4+(y4*(x3-x9)-y9*(x3-x4))*(x4-x9)))/o
*if,y3,lt,y9,then
y3=((j*sqrt(m+n)*(x4-x3)+j*j*y4-(y4*(x3-x9)-y9*(x3-x4))*(x4-x9)))/o
*endif

p=-j*j+y3*y3-2*y3*y9+y9*y9
q=(x3-x9)*(x3-x9)
r=(j*j-(x3-x9)*(x3-x9))
y8=(-(j*sqrt(p+q)*(x8-x9)-j*j*y9+(y3*(x8-x9)+y9*(x3-x8))*(x3-x9)))/r
*if,y8,lt,y7,then
y8=((j*sqrt(p+q)*(x8-x9)+j*j*y9-(y3*(x8-x9)+y9*(x3-x8))*(x3-x9)))/r
*endif


!Knotenpunkte fuer Ursprungsgeometrie

k,1,x1,y1 $k,2,x2,y2 $k,3,x3,y3 $k,4,x4,y4 $k,5,x5,y5 $k,6,x6,y6 $k,7,x7,y7 $k,8,x8,y8 $k,9,x9,y9 $k,10,x10,y10 $k,11,x11,y11 $k,12,x12,y12 $k,13,x13,y13 $k,14,x14,y14

!Knotenpunkte - Zusaetzlich, wegen Aufteilung der Flaeche fuer die Vernetzung

k,15,x10,y1 $k,16,x4+2,y4 $k,17,x4+2,y7 $k,18,x4,y7 $k,19,x14,y3 $k,20,x10,y3 $k,21,x13,y3 $k,22,x13,y1


!Flaechen

a,11,12,13,10 $a,13,21,20,10 $a,21,22,15,20 $a,13,14,19,21 $a,21,19,1,22 $a,15,2,3,20 $a,3,20,10,9 $a,3,9,8,4 $a,8,7,18,4 $a,4,18,17,16 $a,17,16,5,6

!Linien fuer die Vernetzung vorbereiten

lesize,1,,,8 $lesize,2,,,3 $lesize,3,,,8 $lesize,4,,,3 $lesize,5,,,2 $lesize,6,,,8 $lesize,7,,,2 $lesize,8,,,7 $lesize,9,,,8 $lesize,10,,,7
lesize,11,,,1 $lesize,12,,,2 $lesize,13,,,1 $lesize,14,,,7 $lesize,15,,,1 $lesize,16,,,3 $lesize,17,,,7 $lesize,18,,,3 $lesize,19,,,3 $lesize,20,,,2
lesize,21,,,10 $lesize,22,,,2 $lesize,23,,,10 $lesize,24,,,5 $lesize,25,,,2 $lesize,26,,,5 $lesize,27,,,10 $lesize,28,,,5 $lesize,29,,,10 $lesize,30,,,8
lesize,31,,,5 $lesize,32,,,8


!Materialdaten und Vernetzung

et,1,42,,,1 $mp,ex,1,24 $mp,nuxy,1,0.499 $mshape,0 $amesh,all


!Randbedingungen

Kraft=1 $Flaeche=(4*x2*x2-4*x1*x1)*3.1416/4 $druck=Kraft/Flaeche
nsel,s,loc,y,0 $d,all,all $allsel $nsel,s,loc,y,y1 $*get,master,node,,num,min $cp,1,uy,all $allsel $nsel,s,loc,y,y1 $sf,all,pres,druck $allsel



!Berechnung

/solu
antype,static	!(,Welcher)Bestimmung des Analysetypes
pstres,on	!Vorspannungseffekte werden kalkuliert-wird bei Beulanalyse immer gebraucht
solve
fini

/solu
antype,buckle	!(,was)	Beulanalyse
bucopt,lanb,2	!(,,Zahl) die Anzahl der zu bestimmenden Beulformen wird bestimmt
mxpand,all	!(,Zahl) hiermit wird die Anzahl der Lösungen bestimmt, die geschrieben werden solllen-ohne den Befehl halt alle
solve
!fini

/post1
set,first	!die erste berechnete Lösung wird geladen

*get,last,active,,set,freq	!Speichert das Rechenergebniss in einer Variablen (last)

/solu
antype,static,new	!Neue statische Berechnung

last2=1.1*last	!Kritsche Last wird mit Erhoehung versehen
nsel,s,loc,y,y1 $sf,all,pres,last2 $allsel

nlgeom,on	!große Verformungen an
autots,off	!Automatische Schrittvorgabe aus, um nach der Newton-Raphson Methode (bevorzugt für statische Instabilitaet) zu berechnen
nsubsts,1000,10000,10	!zwischenschritte für einen Lastschritt werden spezifiziert
outres,all,all	!Alle Loesungen werden mitgeschrieben
arclen,on,25,0.001	!Methode fuer Newton-Raphson, autots muss aus sein
solve