!------------------------------------
! 24L
! Streckziehen mit Kontakt, 2D, Bsp.
! Einheiten: mm, s, t, N
!------------------------------------

! Leeren der DB
	finish
	/clear, start
	/filename, Coilband_Shell_2D_1-2
	/titel, Coilwickeln

! Starten des Preprocessors
	/prep7
	
!------------------------------------

! Geometrie
	c_Hoehe = 20.0
	c_Radius = 1015.0
	c_Dicke = 5.0
	Epy = 0.001

! Material
	Emodul = 210000
	Nu = 0.3
	Mu = 0.15
	
! Netz
	Elgr = 5
	
! Verschiebung
	NLS = 90	!Zahl der gesamten Schritte (entspricht Gradzahl der Verschiebungsrichtung, sollte fuer volle Aufwicklung 90 betragen
	SNLS = 7	!Zahl der letzten Schritte von NLS die langsamer ablaufen sollen (Kontaktinitialisierung)
	CNI = 5		!Faktor um den die letzten Schritte langsamer laufen sollen. Bsp: Faktor 10 erzeugt bei SNLS = 6 insgesamt 60 weitere Schritte
	
! Solver Options
	Fas = 1
	Uto = 0.01
	Toa = 0.5

!------------------------------------

	/prep7
	
! Geometrie
	k, 1, 0, 0, 0						!Keypoint Kreismitte
	k, 2, 0, -c_Radius, 0					!Keypont Kreisanfang
	circle, 1, c_Radius, , 2, 180, 90		!Halbkreis ziehen
	
	Laenge = c_Radius*3.142				!Laenge des umwickelnden Bandendes bestimmen
	rectng, 0, Laenge, c_Radius+EPY, c_Radius+EPY+c_Hoehe	!Bandende ueber Coil erzeugen 
	r, 1, c_Dicke		!Real-Konstante c_Dicke an Rechteck uebergeben
	
! Elemente
	et, 1, plane42		!2D-Shell-Element
	keyopt, 1, 3, 3		!
	et, 2, targe169		!Target-Element
	et, 3, conta171		!Contact-Element
	keyopt, 3, 9, 2
	
! Material
	mp, ex, 1, Emodul	!Materialeigenschaften fuer Coilende uebergeben
	mp, prxy, Nu
	mp, mu, 1, Mu
	tb, MISO, 1, 1, 33
	tbpt, ,0.001, 210
	tbpt, , 0.002, 420
	tbpt, , 0.0068, 668.253
	tbpt, , 0.0116, 671.4451
	tbpt, , 0.0148, 675.0682
	tbpt, , 0.0173, 677.3458
	tbpt, , 0.0216, 680.0621
	tbpt, , 0.0263, 691.1598
	tbpt, , 0.03, 700.5659
	tbpt, , 0.0333, 708.0798
	tbpt, , 0.0367, 715.4066
	tbpt, , 0.0401, 722.3006
	tbpt, , 0.0435, 728.8314
	tbpt, , 0.0469, 734.9436
	tbpt, , 0.0497, 739.8863
	tbpt, , 0.0532, 745.4231
	tbpt, , 0.0567, 750.43
	tbpt, , 0.0601, 755.3938
	tbpt, , 0.0636, 759.9267
	tbpt, , 0.0671, 764.3084
	tbpt, , 0.0706, 768.3974
	tbpt, , 0.0742, 772.2248
	tbpt, , 0.0777, 775.829
	tbpt, , 0.1777, 849.468
	tbpt, , 0.2777, 891.5382
	tbpt, , 0.3777, 921.6856
	tbpt, , 0.4777, 945.3718
	tbpt, , 0.5777, 964.9699
	tbpt, , 0.6777, 981.7353
	tbpt, , 0.7777, 996.4155
	tbpt, , 0.8777, 1009.4932
	tbpt, , 0.9777, 1021.2988
	tbpt, , 1.0777, 1032.0689

! Netz Blech
	type, 1		
	mat, 1
	real, 1
	esize, Elgr
	amesh, all
	
! Benennen der Randknoten
	nsel, s, loc, x, Laenge
	*get, AO, node, 0, count							!Zahl der Knoten an der rechten, vertikalen Kante des Coilendes bestimmen
	alls
	*do, i, 1, AO, 1									!Schleife zum Durchlaufen aller Knoten an der Kante des Coilendes
	hw1=c_Radius+Epy										!Unteres Ende des Coilende-Rechtecks
	N%i% = node(Laenge, hw1+(i-1)*c_Hoehe/(AO-1), , )		!Knoten an der rechten Kante einzeln von N1..Ni benennen
	*enddo
	
! Netz Target Stempel
	type, 2
	real, 4
	csys,1
	lsel, s, loc, x, c_radius
	lmesh, all
	csys,0
	alls
	
! Netz Contact Blech
	type, 3
	real, 4
	lsel, s, loc, y, c_Radius+ Epy
	nsll, s, 1
	esurf
	alls
	
!------------------------------------

	finish
	/solu

! Option für den Solver
	antype, static, new
	nlgeom, on
	*if, FAS, eq,1,then
		nrop, full, , on
		cnvtol, u, UTO, TOA, 0
	*endif
	
! Lösen
	*do, i, 0, NLS-SNLS+SNLS*CNI
		time = 1
		nsel, s, node, , N1			!untersten Knoten rechte Kante auswaehlen
		
		*if, i, GT, NLS-SNLS, then
			d, all, uy, -2*c_Radius*sin(3.14159265359/180*(NLS-SNLS+(i-NLS+SNLS)/CNI))
			d, all, ux, -Laenge*(1-cos(3.14159265359/180*(NLS-SNLS+(i-NLS+SNLS)/CNI)))
		*else
			d, all, uy, -2*c_Radius*sin(3.14159265359/180*i)
			d, all, ux, -Laenge*(1-cos(3.14159265359/180*i))			
		*endif
		
		alls
		esel, s, type, , 1
		nsle, s
		nsel, r, loc, x, 0
		d, all, ux, 0
		d, all, uy, 0
		alls
		solve
	*enddo
	finish