/prep7

mp,ex,,2.1e+5
mp,nuxy,,0.33
mp,dens,,7800e-12

bestif=1e5
bedamp=500

! Change element type to 272 axisymm

esel,s,ename,,200
et,1,272,,3
SECT,1,AXIS
SECDATA,1,0,0,0,1,0,0

emodif,all,type,1			
emodif,all,sect,1
emodif,all,mat,1

NAXIS
ALLSEL,ALL

/COM, create springs and fix ends
et,100,combi214,,1
r,100,bestif,bestif,,,bedamp,bedamp				
type,100
real,100

*get,nmax,node,0,count						!SPRING1
cmsel,s,spring1
n0=ndnext(0)
n,nmax+1,nx(n0),ny(n0)
e,n0,nmax+1
!d,n0,all
d,nmax+1,all
alls

*get,nmax,node,0,count						!SPRING2
cmsel,s,spring2
n0=ndnext(0)
n,nmax+1,nx(n0),ny(n0)
e,n0,nmax+1
d,nmax+1,all
!d,n0,all
alls

/COM, PERFORMING CAMPBELL ANALYSIS USING QRDAMP EIGEN SOLVER
/SOLU
ANTYPE,MODAL
MODOPT,QRDAMP,12,1.0,,ON		! COMPUTE COMPLEX EIGEN MODES USING DAMP SOLVER
MXPAND,12,,,YES				! EXPAND ALL THE MODES WITH STRESS CALCULATION ON
CORIOLIS,ON,,,ON			! CORIOLIS ON IN A STATIONARY REFERENCE FRAME

pival = acos(-1)
spinRpm = 50000				! Rotational velocity in rpm

*do,i,0,spinRpm,5000
omega,i*pival/30
solve
*enddo

FINI

/POST1
/sho,png
PRCAMP,ON,1.0,RPM
/rgb,index,100,100,100,0
/rgb,index,0,0,0,15				! PRINT CAMPBELL VALUES FOR SLOPE = 1.0 IN RPM
PLCAMP,,1.,RPM
*GET,CRIC11,CAMP,1,VCRI,,,
*GET,CRIC21,CAMP,2,VCRI,,,
*GET,CRIC31,CAMP,3,VCRI,,,