finish
/clear

*abbr,elektrostatik_3D,/input,elektrostatik_3D,txt

breiteg=5e-4		!Breite Gesamt
breite1=8e-5		!Breite eines Absorbers
laenge=1e-3		!Länge
tiefe=4.5e-4		!Waferdicke
fuge=1e-4-breite1
pot=500			!angelegtes Potenzial

/prep7
et,1,solid122		!3D 20-node electrostatic solid
et,2,mesh200,7		!Vernetzungshife
mp,perx,1,12.9		!Permittivität für GaAs
!mp,perx,1,11.7		!Permittivität für Si

!----Geometrie-----
rectng,0,breiteg,0,laenge				!gesamte Fläche
rectng,0,0.5*fuge,0,laenge				!1. Fuge
rectng,0.5*fuge+breite1,1.5*fuge+breite1,0,laenge	!2. Fuge
rectng,1.5*fuge+2*breite1,2.5*fuge+2*breite1,0,laenge	!3. Fuge
rectng,2.5*fuge+3*breite1,3.5*fuge+3*breite1,0,laenge	!4. Fuge
rectng,3.5*fuge+4*breite1,4.5*fuge+4*breite1,0,laenge	!5. Fuge
rectng,4.5*fuge+5*breite1,5*fuge+5*breite1,0,laenge	!6. Fuge
aovlap,all
!/pnum,area,1 
!A9,A3,A4,A5,A6,A8:Fugen

!----Vernetzung der Flächen-----
type,2
esize,fuge/5
amesh,9		!Vernetzen der linken halben Fuge
amesh,3,6,1	!Vernetzen der mitteleren vier Fugen
amesh,8		!Vernetzen der rechten halben Fuge
esize,fuge/4
amesh,10,14,1	!Vernetzen der Elektroden

!----Flächen extrudieren-------
type,1		!Zuweisung Elementtyp 1
mat,1		!Zuweisung Material 1
esize,,4
vext,all,,,,,-tiefe
aclear,all

!----Elektroden---------------
!ohmscher Kontakt: Bottomelektrode
nsel,s,loc,z,-tiefe
d,all,volt,0
!Schottkykontakte: Topelektroden
asel,s,,,10
nsla,s,1
d,all,volt,pot
asel,s,,,11
nsla,s,1
d,all,volt,pot
asel,s,,,12
nsla,s,1
d,all,volt,pot
asel,s,,,13
nsla,s,1
d,all,volt,pot
asel,s,,,14
nsla,s,1
d,all,volt,pot

allsel
!--------Lösung------
/solu
solve
!------Auswertung------
/post1
!/view,,-0.5,-0.7,0.4
!plns,volt
!/wait,1
plns,ef,sum
!/wait,2
!/ctype,1
!plns,volt