FINISH  $/CLEAR
*ABBR,trafo,/INPUT,spule.INP

!=================================================================================
!	Originalwicklung: 
!=================================================================================
!	Leiterquerschnitt: 	22mm x 1.5mm=	33mm^2 
!	Windungen: 			27
!	Gesamtleiterlänge:	27*1.1875m=	32.064m
!	Ohmscher Widerstand (1/56 Ohm*mm^2/m):	17.35 mOhm
!	bei 1V Spannung sollten ca. 58A zu erwarten sein

!=================================================================================
!								Daten: 
!=================================================================================
U_p=1	!	[V]
frq=50			!	[Hz]

!	Primärleiter (Querschnitt)
x_p=0.048
z_p=0.022

!	Wicklungsform (innen- und  außenmaße)
x_li=0.069
x_la=0.165

y_la=0.410

!	Rundungen (innen-,  außen-, mittlerer Radius)
r_li=0.0345
r_la=0.0825
r_lm=(r_la-r_li)/2+r_li

!	Luftraumradius
R_a=0.5

!=================================================================================
/PREP7

ET,1,SOLID97,0
ET,3,SOLID97,3	 							!	AX, AY, AZ, CURR DEGREES OF FREEDOM: VOLTAGE-FED STRANDED COIL
ET,5,INFIN111,1

!=================================================================================
!								Solid97,3-Spulenelemente: Primärwicklung
!=================================================================================
PI=4*atan(1)
TURNprim=27									
CSYM=1										
FILLprim=0.844		!	Wickelkörper zu 84.4% mit Kupfer ausgefüllt				

!	Radialstücke
VOLU30=1/2*PI*(r_la*r_la-r_li*r_li)*z_p								!	Volumen Spulenkörper
CARE30=x_p*z_p																	!	Querschnittsfläche durch die der Strom fließt
R,30,CARE30,TURNprim,VOLU30,0,+1,0,CSYM,FILLprim			!	Achtung in Zylinderkoordinaten! in +theta richtung

!	Vertikalstücken
VOLU31=x_p*y_la*z_p		
R,31,CARE30,TURNprim,VOLU31,0,+1,0,CSYM,FILLprim
R,32,CARE30,TURNprim,VOLU31,0,-1,0,CSYM,FILLprim

!=================================================================================
!							 KOPPELELEMENT - 3-D MASSIVE CONDUCTOR VOLT,CURR DOF
!=================================================================================	
ET,7,CIRCU124,5,0		
R,7,1							

!=================================================================================
!							Independent Voltage Source
!=================================================================================	
!ET,12,CIRCU124,4,4							
!R,12,	0.0,U_P,	 1,U_p

ET,12,CIRCU124,4,1 						!	Independent Voltage Source, Sinusoidal load
	!R1	 voltage offset
	!R2	voltage amplitude
	!R3	frequency
	!R4	delay time
	!R5	phase delay
	!R6	exp. decay factor
R,12,0,U_p,frq

!=================================================================================
!								Materialeigenschaften
!=================================================================================
!	Luft:
MP,MURX,1,1 
MP,RSVX,1,0 
!	Kupferleiter: 
MP,MURX,2,1     
MP,RSVX,2,1/56e6

local,11,0,	0,		+y_la/2,	 0	,0,0,0
wpcsys,,11
cylind,	r_li,r_la,	-z_p/2,+z_p/2,		0,180
wpcsys,,0
local,12,0,	0,		-y_la/2,	 0	,0,0,0
wpcsys,,12
cylind,	r_li,r_la,	-z_p/2,+z_p/2,		180,360
wpcsys,,0
Block,	-x_la/2,-x_li/2,		-y_la/2,+y_la/2,		-z_p/2+mp1,+z_p/2
Block,	+x_li/2,+x_la/2,	-y_la/2,+y_la/2,		-z_p/2+mp1,+z_p/2

SPHERE,R_a
VOVLAP,ALL	
numcp,volu
!_________________________________________________________________________________
!	Leiter Rundelemente
TYPE,3  $MAT,2 	$REAL,30
!ESIZE,1*z_p
MSHAPE,0,3D	

!	Rundelemente
VMESH,1,2						
!_________________________________________________________________________________
!		Leiter vorn
TYPE,3  $MAT,2 	$REAL,31
VMESH,3
!_________________________________________________________________________________
!		Leiter hinten
TYPE,3  $MAT,2 	$REAL,32
VMESH,4


!=================================================================================
!								Vernetzung-Luft
!=================================================================================
ESIZE,0.25
TYPE,1  $MAT,1
MSHAPE,1,3D 			 
VMESH,5

!=================================================================================
!								RANDBEDINGUNG
!=================================================================================
ALLSEL
CSYS,2			
TYPE,5
ESIZE,R_a
ASEL,S,EXT
VEXT,ALL,,,1										
SF,ALL,INF										
CSYS,0

!=================================================================================
!								Freiheitsgraddefinition für Solid97,3-Spulenelemente
!	degrees of freedom CURR (current) and EMF (electromotive force drop, or potential drop)
!=================================================================================
ESEL,S,TYPE,,3
NSLE,s,all
CP,1,CURR,ALL
CP,2,EMF,ALL
ALLSEL

!=================================================================================
!								Zylinderkoordinatensystem der Elemente, Rundstücke
!=================================================================================
local,21,1,	0,		-y_la/2,	 0	,0,0,0
csys,21
VSEL,S,,,2
ESLV
emodif,all,esys,21							
csys,0

local,22,1,	0,		+y_la/2,	 0	,0,0,0
csys,22
VSEL,S,,,1
ESLV
emodif,all,esys,22
csys,0

ALLSEL
!=================================================================================
!								Knoten für Kopplung auf Spule wählen
!=================================================================================
VSEL,S,,,3
NSLV,S,1
*GET,N_P1,NODE,0,NUM,MAX	
												
!=================================================================================
!								Anschluß der elektrischen Bauelemente
!=================================================================================
!		Zusätzliche Knoten erzeugen:
ALLSEL
NUMCMP,NODE										! COMPRESSES THE NUMBERING OF DEFINED ITEMS
*GET,N_max,NODE,,NUM,MAX					! GRÖSSTE KNOTENNUMMER GEWÄHLT

!	N:	Defines a node

N,N_max+1,		+0.0,		+2*R_a+0.1,		+0.3
N,N_max+2,		-0.2,		+2*R_a+0.1,		+0.0			!	für spannungsquelle, stromknoten i_K

N,N_max+3,		+0.2,		+2*R_a+0.1,		+0.3
N,N_max+4,		+0.2,		+2*R_a+0.1,		+0.1
nplot
!________________________________________________________________________________________
!										SCHALTUNG mit Knoten:
!																
!		GRND---( N_max+1 )---[ U-Quelle ]---( N_max+3 )---( N_p1 )---( N_max+4 )---GRND
!													|										|
!											( N_max+2 )							Spule

!=================================================================================
!								Verschaltung:
!=================================================================================
!	SPEISUNG DURCH
TYPE,12	$REAL,12	  					$E,	N_max+1,N_max+3,N_max+2						
		
!	Koppelelement zu wicklung:
TYPE,7	$REAL,7							$E,	N_max+4,N_max+3,	N_p1
EPLOT
!=================================================================================
!								BEZUGSPOTENTIAL, Erdung:
!=================================================================================
!	primärseite
NSEL,S,NODE,,N_max+1
NSEL,A,NODE,,N_max+4
D,ALL,VOLT,0
ALLSEL
EPLOT

!=================================================================================
!								Nichtlineare Transiente Analyse
!=================================================================================
ALLSEL
/SOLU
ANTYPE,TRANS
KBC,0
outres,all,all
!CNVTOL,CSG  ,,,,1e-9	!	magnetic current segments
time,1e-12	
solve
TIME,0.02
NSUBST,20,200,20
SOLVE

!	Spannungsquelle:
/post26			
allsel
nsol,4,N_max+3,volt,,U_netz
plvar,4

!	Stromfluß:
/post26			
allsel
nsol,2,N_p1,curr,,I_prim
plvar,2

!	Stromdichteorientierung:
/post1
esel,s,type,,3
plve,jt

ALLSEL
/POST1
set,,,,,0.5e-6
etable,energie,sene
ssum