/FILNAME,Halbkugel
/PREP7

*AFUN,DEG
/UNITS,SI

!PARAMETERS
!----------

*SET,R,20
*SET,D,0.1
*SET,RHO,2500
*SET,EX,30e+09
*SET,PRXY,0.15
*SET,INDRUCK,2e+06

!GEOMETRIE
!---------

K,1,R,0,0
K,2,0,0,R
K,3,0,0,0
LARC,2,1,3,R
AROTAT,1,,,,,,2,3,-90,36

!ELEMENTEN DEFINIERUNG
!---------------------

ET,1,SHELL93
ET,2,SHELL63
ET,3,SHELL281

KEYOPT,2,1,0   !BEND+MEM=0 ;;; Membrane only=1
KEYOPT,3,1,0   !BEND+MEM=0 ;;; Membrane only=1

R,1,D          
R,2,D          
R,3,D

MP,EX,1,EX
MP,PRXY,1,PRXY
MP,DENS,1,RHO

!VERNETZUNG
!----------

MAT,1
REAL,3
TYPE,3
CSYS,0
ESIZE,D*10
AMESH,ALL

!SOLUTION
!--------

!RESTRAINTS
!**********

/SOLU
/PSYM,NDIR,1
/PBC,U,,
CSYS,0

NSEL,S,LOC,Z
D,ALL,UZ
ALLS

NSEL,S,LOC,X
DSYM,SYMM,X
ALLS

NSEL,S,LOC,Y
DSYM,SYMM,Y
ALLS

!LOADING
!*******

SFA,ALL,1,PRES,-(INDRUCK)       !INNENZUG
                                !ODER
!ACEL,,,9.81                    !GRAVITÄT_EIGGEWICHT


ALLS
NPLOT

SOLVE

!POSTPROCESSING
!--------------

/POST1
RSYS,2
SHELL,MID
/GRA,FULL
/EDGE,1
PLNS,S,Z
PLNS,S,Y