FINISH 
/CLEAR 
/FILNAM,Conta176 und Conta177 Kontakt mit initial penetration
/prep7

et,1,188			!Elementtyp festlegen

MP,EX,1,210e3			!Standardwerte von Stahl - E-Modul
MP, NUXY, 1, 0.3		!Querkontraktionszahl
MP, DENS, 1, 7.8e-9		!Dichte
MP, Damp, 1, 1e-4		!Daempfung


et,2,181
SECTYPE,2,Shell
SECDATA,4,2			!Dicke der Platte an allen vier Knoten ist 4
MP,EX,2,850			!E-Modul (Kunststoff)


!-------------------------------Beginn Geometrieerstellung des Balkenkreuzes

K,1,-50,0,18			!Startkeypoint erstellen
K,2,470,0,18
L,1,2

SECTYPE,1,BEAM,CTUBE		!Vernetzung des Horizontalbalkens
SECDATA,8,9
SECOFFSET,CENT,,,   
Secplot,1
SECN,1
Lsel,s,line,,1
lesize,all,40		
lmesh,all

K,3,210,-270,0			!Vertikalbalken
K,4,210,270,0
L,3,4
Lsel,s,line,,2
lesize,all,40
lmesh,all

allsel

!-------------------------------Ende der Geometrieerstellung des Balkenkreuzes
!-------------------------------Geometrie der Schale


k,6,0,210,16			
k,8,420,210,16

				!Zyl Koord Syst

k,11,210,-198,4			!Mittelpunkt
k,12,210,-198,8			!positive X-Achse
k,13,210,-205,4			!xy-ebene
cskp,11,1,11,12,13		!tyl. Koord. Syst. definiert

k,14,12,0,-210
k,15,12,90,-210
k,16,12,0,210
k,17,12,90,210
a,15,14,16,17

CSYS,0

k,9,0,-210,-210
K,10,420,-210,-210

A,15,17,10,9			!Bodenebene

a,6,8,16,14			!Seitenebene

!-------------------------------Vernetzung Schale
				
type,2
real,2
SECNUM,2
esize,40			
amesh,all
allsel
/eshape,1
eplot,all

!-------------------------------Ende der Vernetzung
		
!-------------------------------Beginn Kontaktelemente Balkenkreuz

et,3,170
et,4,176		!3D-Line-to-Line

keyopt,4,3,1		!Crossing Beams
KEYOPT,4,12,6		!Bonded Initial Contact
R,4,9,9,,,,		!Radien korresponideren mit den geometrischen Abstaenden
RMODIF,4,6,-200	!Pinball region (Abstand der Mittellinien der Balken)
lsel,S,Line,,1
esll,s
type,3
real,4
esurf
lsel,S,Line,,2
esll,s
type,4
esurf

allsel

!-------------------------------Ende Kontaktelemente Balkenkreuz

!-------------------------------Beginn Kontaktelemente Shell-to-Beam

!-------------------------------Kontakt der Vertikalstange zum Behälter

et,5,170
et,7,177		!3D-Line-to-Surface
r,7

keyopt,7,9,2		!Effect of initial penetration or gap: Include both initial geometrical penetration or gap and offset, but with ramped effects
RMODIF,7,6,-100  	!ab -16.1 Kontakt erkannt, ab -27 Penetration erkannt, ab -27.1 wird angezeigt und geclosed! Pinball Region eingestellt (Abstand der Mittellinien plus Offset plus Shell thickness)
			!geometr. Abstand = 16; Radius Balken = 9; halbe Dicke = 2
RMODIF,7,10,9		!Offset einstellen (Radius des Balken)
KEYOPT,7,12,6 		!Bonded Contact (lineare Rechnung; nach erstem LS geschlossen)
keyopt,7,11,1		!Include Shell thickness
		
real,7
	
! Generate the target surface   

ASEL,S,,,3 		!Wird weiter unten durch CNCHECK,Trim verkleinert
TYPE,5
ESLA,S
ESURF 

! Reverse target normals 

ESURF,,REVERSE  
eplot
ALLSEL

! Generate the contact surface  

lsel,s,line,,2
TYPE,7  
ESLL,S,1

ESURF   
EPLOT
allsel

!-------------------------------Ende Kontakt der Vertikalstange zum Behälter

et,5,170
et,6,177
r,6


keyopt,6,9,2		!Effect of initial penetration or gap: Include both initial geometrical penetration or gap and offset, but with ramped effects
RMODIF,6,10,9		!Offset einstellen
RMODIF,6,6,-27.1	!ab -2.1 Kontakt erkannt, ab -9 Penetration erkannt und Kontakt als closed erkannt; Pinball Region eingestellt
			!geometr. Abstand = 2; Dicke = 2; Radius  = 9
KEYOPT,6,12,3 		!Bonded Contact (lineare Rechnung)
keyopt,6,11,1		!Include Shell thickness


real,6


!Generate the target surface   

ASEL,S,,,3 
TYPE,5
ESLA,S
ESURF 

! Reverse target normals 

ESURF,,REVERSE  
eplot

! Generate the contact surface  

lsel,s,line,,1

TYPE,6  
ESLL,S,1
!esel,u,elem,,5,6
ESURF,,Line   
EPLOT
allsel

!-------------------------------Ende Kontakt der Horizontalstange zum Behälter

!-------------------------------Ende Kontaktelemente Shell-to-Beam

CNCHECK,TRIM			!Minimierung der Kontaktelemente

!-------------------------------Erster Lastschritt (Kontakt aufbauen)

!-------------------------------Lösungseinstellungen

/solu
nlgeom,on
!-------------------------------Randbedingungen

allsel

ksel,s,kp,,1
ksel,a,kp,,2
ksel,a,kp,,3
ksel,a,kp,,4
dk,all,all			!Endpunkte des Balkenkreuzes festhalten
allsel

asel,s,area,,2			!Teil der Bodenebene festhalten
nsla,s,1
nsel,r,loc,z,-210
d,all,all

/PBC,ALL,,1
esel,s,elem,,all
eplot,all

!-------------------------------Horizontale Kontakte deaktivieren

esel,s,real,,6
ekill,all


nsub,5,10,1
allsel



solve

/solu

!-------------------------------Zweiter Lastschritt (Last aufbringen)

!-------------------------------Lastprofil aufbringen

SFGRAD,Pres,0,Y,110,-0.00005	
asel,s,area,,all					 
esla,s
SFe,all,2,Pres,	
alls

/PSF,Pres,Norm,2,1,1
/replot

!-------------------------------Kontakt der Horizontalstange zum Behälter aktivieren

!esel,s,real,,6
alls
ealive,all

allsel


nsub,100,100,10
KBC,0


allsel
solve
/eof
/eshape,1
eplot,all
/post1

/EOF