!----------Abkühlen_Block_3-D----------
!-----TEIL1-----Geometrie-Konstanten-Variablen-Vorgabe des Wärmeeintrages-----
keyw,pr_sgui,1		!Schlüsselwort, genannt pr_sgui, ist 1 (true) (0 wäre false)
fini			!(finish) Verlässt den aktuellen Prozessor
/cle			!(/clear) reinigt Datenbank und liest für Neustart start81.ans
/FILNAME,D:/Ansys/Projekte_Fuchs/Abkühlen_Block1,0	!Speicherort und Name

!-----Konstanten und Variablen-----

!-----Maße des Blocks
BB=30e-3		!x Blockbreite
BH=20e-3		!y Werte in m eingegeben Blockhöhe
BT=20e-3		!z Blocktiefe


!-----Temperaturen
Blocktemp=500		!Ausgangstemperatur des Blocks
alpha=10		!Wärmeübergangskoeffizient


/prep7			! Start Preprozessor

!-----Elementtypen
et,1,solid70      	       	!Quader Temperatur



!---------Materialeigenschaften-------------
!-----Material 1 = Block (Aluminium)-----

!mp,murx,1,3000
!mp,rsvx,1,3.77			!elektrische Leitfähigkeit Aluminium
mp,kxx,1,235			!Wärmeleitwert Aluminium
mp,c,1,897			!Wärmekapazität Aluminium
mp,dens,1,2700			!Dichte von Aluminium


!-----Aufbau der Geometrie-----
/prep7
/view,,1,2,3			!Blickwinkel für die Darstellung

!-----Bau des Alublocks-----

block,-BB/2,BB/2,-BH/2,BH/2,-BT/2,BT/2			!Quaderform (Geometrie wird um Ursprungspunkt angelegt)

save				!Zwischenspeichern

!-----Vermaschung der Geometrie
!-----Vermaschung des Blocks

esize,0.01 		!Größe der Elemente
mshape,1,3D
type,1  $mat,1		!wähle mat 1 (Aluminium)
vmesh,1			!automatische Vermaschung des Volumens 1 (Tetraeder)

save			!Zwischenspeichern



/solu
ANTYPE,TRANS
AUTOTS,ON
OUTRES,ALL,ALL
TIME,2700		!z.B. Betrachtung bei 10800 also 3h
KBC,1
DELTIM,5,1,100

nsel,all
ic,all,temp,500

asel,s,area,,1,6
sf,all,conv,alpha,20
allsel
/pnum,node
/pbc,temp,1
/psf,conv,,1
nplot

solve




!-------------------------------
/POST1 
/type,,5			!Darstellung als Schnitt
/cplane,1			!mit Schnittebene „Workingplane“
esel,s,mat,,1			!Auswahl aller Elemente
/contour,,all,20,30,300		!Schrittweite der Anzeige der Temperatur von 20 bis  °C
plnsol,temp			!Temperaturverteilung
/contour,,all,0,30,400
plns,tf,sum			!Wärmestromdichte

!----------------------------
/post26
n1=node(BB/2,BH/2,BT/2)
n2=node(0,0,0,)
nsol,2,n1,temp,,Rand
nsol,3,n2,temp,,Mitte
plvar,2,3