!Erwärmung eines Werkstücks bei Stromfluss
fini
/clear

strom=5000       !Stromstärke in A
zeit=1e-3           !Dauer des Stromflusses in Sekunden
zeitschritte=10 !Anzahl der Zeitschritte
!Aussenumrisse des Körpers
untere_ecke_x=-5e-3
untere_ecke_y=-9e-3
breite=10e-3
hoehe=18e-3
tiefe=4e-3
!Negativkörper links
untere_ecke_x_l=untere_ecke_x
untere_ecke_y_l=-5e-3
breite_l=2.5e-3
hoehe_l=10e-3

!Negativkörper rechts
untere_ecke_x_r=2.5e-3
untere_ecke_y_r=-5e-3
breite_r=breite_l
hoehe_r=hoehe_l

/prep7


et,1,solid98

!Werkstoffeigenschaften für irgendeinen Stahltyp
!***********************************************
mp,ALPX,1.2e-5    !thermische Dehnung
mp,ex,1,210000   !E-Modul
mp,rsvx,1,1/10e6 !el. Leitwert
mp,kxx,1,52       !Wärmeleitwert
mp,c,1,420        !spez. Wärmekapazität
mp,dens,1,7860    !Dichte

!es fehlen weitere Eigenschaften in Bezug auf das Magnetfeld-Verhalten



!Geometrieerzeugung
!***********************************************
blc4,untere_ecke_x,untere_ecke_y,breite,hoehe,tiefe  !Aussenumrisse des Körpers
blc4,untere_ecke_x_l,untere_ecke_y_l,breite_l,hoehe_l,tiefe                   !Negativkörper der linken Seite
blc4,untere_ecke_x_r,untere_ecke_y_r,breite_r,hoehe_r,tiefe                   !Negativkörper der rechten Seite

vsbv,1,2
vsbv,4,3



!Vernetzung der Geometrie
!***********************************************
esize,10e-3/8
vmesh,all


!elektrische Anfangswerte festsetzen
!***********************************
nsel,s,loc,y,-9e-3
cp,1,volt,all      !Kopplung des Potentials "unten"
*get,node1,node,,num,min
f,node1,amps,strom   !Festlegung des Stromeingangs
nsel,s,loc,y,9e-3
d,all,volt,0         !Festlegung der gegenüberliegeneden Seite auf Bezugspotential

!thermische Randbedingungen festlegen
!************************************
! Flächen für freie Konvektion und Strahlung definieren
asel,s,,,1,20,1
nsla,s,1
!nsel,s,loc,y,-9e-3
!nsel,s,loc,y,9e-3
!nsel,s,loc,x,-5e-3
!nsel,s,loc,x,5e-3
sf,all,conv,50,20
tunif,20       !Umgebungstemperatur von 20°C
alls

!Lösung
!****************************************
/solu

!'''''''''''''''''''''''''''''''''''''''
antype,trans
kbc,1
time,zeit
deltim,zeit/zeitschritte
outres,all,all  !alle Lösungsschritte
solve

!Auswertung
/post1
plnsol,temp