!Erwärmung eines Werkstücks bei Stromfluss
fini
/clear

strom=5000       !Stromstärke in A
zeit=1e-3           !Dauer des Stromflusses in Sekunden
zeitschritte=10 !Anzahl der Zeitschritte
!Aussenumrisse des Körpers
untere_ecke_x=-5e-3
untere_ecke_y=-9e-3
breite=10e-3
hoehe=18e-3
tiefe=4e-3
!Negativkörper links
untere_ecke_x_l=untere_ecke_x
untere_ecke_y_l=-5e-3
breite_l=2.5e-3
hoehe_l=10e-3

!Negativkörper rechts
untere_ecke_x_r=2.5e-3
untere_ecke_y_r=-5e-3
breite_r=breite_l
hoehe_r=hoehe_l

!Verrundungsradius für die Kanten
eckenradius=0.5e-3

/prep7

!et,1,solid97       !andere Vernetzungsmethode wählen
!et,1,solid98
et,1,solid227,111   !structural-thermoelectric
!et,1,solid237,1
!et,1,solid69
!Werkstoffeigenschaften für irgendeinen Stahltyp
!***********************************************
mp,ALPX,1,1.2e-5    !Wärmeausdehnung
mp,ex,1,210000e6    !E-Modul
mp,rsvx,1,1/10e6    !el. Leitwert
mp,kxx,1,52         !Wärmeleitwert
mp,c,1,420          !spez. Wärmekapazität
mp,dens,1,7860      !Dichte
mp,murx,1,2000
mp,perx,1,8.859e-12
mp,nuxy,1,0.3


!Geometrieerzeugung Variante 1
!***********************************************
!Extrudieren aus einer 2-D-Figur
!Flächen erzeugen
RECTNG,untere_ecke_x,untere_ecke_x+breite,untere_ecke_y,untere_ecke_y+hoehe
RECTNG,untere_ecke_x_l,untere_ecke_x_l+breite_l,untere_ecke_y_l,untere_ecke_y_l+hoehe_l
RECTNG,untere_ecke_x_r,untere_ecke_x_r+breite_r,untere_ecke_y_r,untere_ecke_y_r+hoehe_r
!Seitentaschen subtrahieren
asba,1,2
asba,4,3
!Innenfläche löschen
adele,1
!lplot
!Kanten abrunden
lfillt,6,5,eckenradius   !L2
lfillt,6,7,eckenradius   !L10
lfillt,9,12,eckenradius  !L15
lfillt,11,12,eckenradius !L16
!Innenfläche wiederherstellen
al,all
!Volumenkörper aus der Fläche extrudieren
VEXT,1,,,,,tiefe


!Geometrieerzeugung Variante 2
!***********************************************
!Erzeugen von 3D-Körpern
!blc4,untere_ecke_x,untere_ecke_y,breite,hoehe,tiefe  !Aussenumrisse des Körpers
!blc4,untere_ecke_x_l,untere_ecke_y_l,breite_l,hoehe_l,tiefe                   !Negativkörper der linken Seite
!blc4,untere_ecke_x_r,untere_ecke_y_r,breite_r,hoehe_r,tiefe                   !Negativkörper der rechten Seite
!CYL4,untere_ecke_x_l+(breite_l-0.05e-3),untere_ecke_y_l+0.1e-3,eckenradius,190,,440,tiefe

!vsbv,1,2
!vsbv,4,3

!Eckenverrundung
!afillt,9,12,eckenradius
!afillt,10,11,eckenradius
!afillt,15,17,eckenradius
!afillt,14,16,eckenradius

!Vernetzung der Geometrie
!***********************************************
!wenn solid98 vernetzt wird
esize,8e-3/8
vmesh,all
!Wenn solid226 vernetzt wird
!MSHKEY,0      ! Use  free meshin
!MSHAPE,1,3d  ! Use hexahedra 3-D

!esize,10e-3/8
!vmesh,all

!elektrische Anfangswerte festsetzen
!***********************************
nsel,s,loc,y,-9e-3
cp,1,volt,all      !Kopplung des Potentials "unten"
*get,node1,node,,num,min
f,node1,amps,strom   !Festlegung des Stromeingangs
nsel,s,loc,y,9e-3
d,all,volt,0         !Festlegung der gegenüberliegeneden Seite auf Bezugspotential

!thermische Randbedingungen festlegen
!************************************
! Flächen für freie Konvektion und Strahlung definieren
asel,s,,,1,20,1
nsla,s,1
sf,all,conv,50,20
tunif,20       !Umgebungstemperatur von 20°C
alls

!Lösung
!****************************************
/solu

!'''''''''''''''''''''''''''''''''''''''
antype,trans
kbc,0
time,zeit
deltim,zeit/zeitschritte
outres,all,all  !alle Lösungsschritte
solve




!Auswertung
/post1
plnsol,temp