finish
/clear,start

!Zylinder über Platte
!planare Anordnung

/UNIT,MKS
			
zrad=2.5e-3  				! Zylinderradius
sw=5e-4   				! Schlagweite
psd=2e-4				! Papierschichtdicke
b=0.0075				! Breite

pot0=0					! Erdpotential 
pot1=1					! Potential 1V

eps=8.85418781762e-12			! Dielektrische Eigenschaften
		
eps_oil = eps*2.2			! Öl			
rs_oil  = 1e+10
eps_poil= eps*6.0			! Öl-Papier
rs_poil = 1e+11


/prep7


!et,1,plane121,,,0,,2,1		! Definition des Schalenelement für 2D-planare Berechnung
!et,2,plane121,,,0,,2,1		! Definition des Schalenelement für 2D-planare Berechnung

et,1,plane230,,,0
et,2,plane230,,,0

mp,perx,1,eps_poil 	                ! Öl-Papier
mp,pery,1,eps_poil
mp,rsvx,1,rs_poil                   
mp,rsvy,1,rs_poil

mp,perx,2,eps_oil			! Öl
mp,pery,2,eps_oil
mp,rsvx,2,rs_oil                   
mp,rsvy,2,rs_oil

!--------------Geometrie------------------------------------------

!n,1,krad*sin(swi),sw+krad-cos(swi)
!e,1

CYL4,0,0,b				! Umgebung Halbkreis 
CYL4,0,sw+zrad+psd,zrad			! Querschnitt Zylinder

RECTNG,-b-0.01,b+0.01,-b-0.01, 0	! Umgebung 
RECTNG,-b-0.01,b+0.01,0,psd		! Papierschicht

AOVLAP,all

ADELE,2
ADELE,5
ADELE,7,9

!---Vernetzung----------------------------------------------------

mshape,1,2d				! Dreiecke
mshkey,0				! freie Vernetzung
type,1  $mat,1

esize,psd/5				! Elementgröße

amesh,6					! Vernetzung Papierschicht


type,2  $mat,2

esize,zrad/10

LESIZE, 7,zrad/50,,,0.2
LESIZE, 8,zrad/50,,,5

amesh,10				! Ölbereich

!---Randbedingungen-----------------------------------------------

!Potentialelektrode

nsel,s,ext
nsel,r,loc,y,sw+psd,sw+psd+2*zrad
nsel,u,loc,y,b
nsel,u,loc,x,-b,-zrad-0.001
nsel,u,loc,x,zrad+0.001,b
d,all,volt,pot1

!Potential Platte/Erde

nsel,s,ext
nsel,r,loc,y,0,0
d,all,volt,pot0

allsel

fini

!---Lösung--------------------------------------------------------

/solu

antype,0			!Specifies the analysis type and restart status
				! 0 - STATIC, 3 - Harmonic, 4 - Transient

solve

fini

/post1

PLNSOL,ef,sum
!plnsol,volt
!PLVECT,ef