! Definition von Piezomaterial in der Workbench 
!
! Die Komponenten Piezo, Elektrode_G, Elektrode_P und hier auch Aussen muessen vorher definiert sein.
! Weiterhin finden Knotendeinifionen fuer das Postprocessing statt.
!
! Autor: Wiebold Wurpts

	
NPIEZO = 1		! Anzahl der Piezokeramiken
PI     = acos(-1)

/prep7

! Elementtyp definieren
et,100,226,1001                      ! 3-D COUPLED-FIELD SOLID, PIEZO OPTION 

! PIC 181 in z-Richtung polarisiert					
TB,	ANEL,	100	,	1	,	0
TBDATA,	1,	1.5232E+11	,	8.9107E+10	,	8.5482E+10
TBDATA,	7,	1.5232E+11	,	8.5482E+10		
TBDATA,	12,	1.3141E+11				
TBDATA,	16,	3.1606E+10				
TBDATA,	19,	2.8305E+10				
TBDATA,	21,	2.8305E+10				
										
TB,	PIEZ,	100				
TBDATA,	3,	-4.4468				
TBDATA,	6,	-4.4468				
TBDATA,	9,	14.7815				
TBDATA,	14,	11.0105				
TBDATA,	16,	11.0105				
										
EMUNIT,	EPZRO,	8.85E-12				
MP,	PERX,	100	,	740		
MP,	PERY,	100	,	740		
MP,	PERZ,	100	,	604					
MP,	DENS,	100	,	7850	

MP,	PRXY, 100	, 	0.35
MP,	PRYZ, 100	, 	0.35
MP,	PRXZ, 100	, 	0.35


! Elemente und Material in Komponente Piezo umstellen
cmsel,s,Piezo
emodif,all,type,100
emodif,all,mat,100

! Ground Elektrode koppeln
cmsel,s,Elektrode_G
cp,1,volt,all
*get,MASTER_G,node,,num,min

! Potential Elektrode koppeln
cmsel,s,Elektrode_P
cp,2,volt,all
*get,MASTER_P,node,,num,min
allsel

! Aussenknoten definieren
cmsel,s,Aussen
Aussen = node(0,0,0)
allsel

! Spannungsvorgabe
! Vorzeichen: Das E-Feld ist in z-richtung positiv (Ez=-dU/dz)
d,MASTER_G,volt,0
d,MASTER_P,volt,NPIEZO*100		! Bei NPIEZO Kermiken entsprache das 100V 
					! Auskommentieren fuer Sensormodellierung

! Hier werden die Piezokeramiken vereinfacht als Ganzes modelliert. Um das gleiche E-Feld, und damit
! die gleiche Wirkung zu erzeugen muss bei z.B. 4 Keramiken hier eine 4-fach hoehere Spannung angelegt werden!


/SOL

! Speichern aller Ergebnisse fuer alle Frequenzschritte
outres,all,all