FINISH                       			! closes procedures   
/CLEAR,Start                 			! clear database


!---local parameters---------------------------------------------------------
	*SET,Pi,4*ATAN(1)							  ! Pi
	*SET,g,9806.6                   ! g in [mm*s^-2]
	
	*SET,a_jib,0                    ! Jib angle in [deg]
	
	*SET,SWL,1                      ! Unit load
	*SET,JIBLEN,10000								! beam length [mm]
	*SET,CYLLEN,2000								! distance from fixed point to floating bearing 
	
  *SET,HPIVOT,1500								! section height 1 
	*SET,WPIVOT,500									! section width 1
  *SET,HCYL,1500									 ! section height 2
	*SET,WCYL,500										! section width 2
	*SET,HHEAD,1500									! section height 3
	*SET,WHEAD,500									! section width 3
  
  *SET,TWEB,15   									! thickness, web plates [mm]
	*SET,TTOP,15	 	   		  			 	! thickness, top flange [mm]
	*SET,TBTM,15			     					! thickness, bottom flange [mm]	
!---Preprocessing---------------------------------------------------------


/PREP7
  
ET,1,BEAM189
  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,210000 
MPDATA,PRXY,1,,0.3

   
! section 1
SECTYPE,1,BEAM,HREC,,0   
SECOFFSET,CENT 
SECDATA,WCYL,HCYL,TWEB,TWEB,TTOP,TBTM,0,0,0,0
! section 2
SECTYPE,2,BEAM,HREC,,0   
SECOFFSET,USER,WHEAD/2,HCYL/2 
SECDATA,WHEAD,HHEAD,TWEB,TWEB,TTOP,TBTM,0,0,0,0 
! section 3 
SECTYPE,3,BEAM,HREC,,0   
SECOFFSET,USER,WPIVOT/2,-((HCYL/2)-HPIVOT) 
SECDATA,WPIVOT,HPIVOT,TWEB,TWEB,TTOP,TBTM,0,0,0,0 
SECTYPE,4,TAPER, ,  
SECDATA,1,0,0,0, 
SECDATA,2,JIBLEN-CYLLEN,0,0, 
SECTYPE,5,TAPER, ,  
SECDATA,1,0,0,0, 
SECDATA,3,-CYLLEN,0,0, 
                 
K,1,0,0,0,  
K,2,JIBLEN-CYLLEN,0,0,
K,3,-CYLLEN,0,0 

!---Meshing
  
LSTR,1,2  
LSTR,1,3  
TYPE,1   
MAT,1
REAL,  
ESYS,0   
SECNUM,4 

!LESIZE,1,,,5
LESIZE,1,1000
LMESH,1  

TYPE,1   
MAT,1
REAL,   
ESYS,0   
SECNUM,5 

!LESIZE,2,,,3
LESIZE,2,1000  
LMESH,2  


/ESHAPE,1.0 
/EFACET,1   
/VIEW,1,,1
/REPLOT 
  
!---Loads and Constraints

DK,1,UY,,,0,UZ,ROTX,ROTZ              ! Constraint on Keypoint 1, 
DK,3,UX,,,0,UY,UZ,ROTX,ROTZ		        ! Constraint on Keypoint 3, 
FK,2,FZ,SWL*g*cos(a_jib*pi/180)       ! Force on Keypoint 2 [N], bending
FK,2,FX,-SWL*g*sin(a_jib*pi/180)      ! Force on Keypoint 2 [N], compression

FINISH                   		       		! leave pre-processor																																																    																																						
                              				
!---start analysis            				
/SOLU										 			       	! Solution-Processor
ANTYPE,static           				      ! set analysis type                   																																												
SOLVE										 				      ! solve
FINISH									 				      ! leave solution processor																																		
                         																																																
!---General Postproc     																												
/POST1                   																																																   																																												


/WIND,ALL,OFF   
/WIND,1,TOP 
/WIND,2,BOT 

/GCMD,1,PLNSOL,UZ
/GCMD,2,PLNSOL,UX
GPLOT