FINISH
/CLEAR

!parameter
breite = 0.025			!width of column [m]
hoehe = 0.003			!height of column [m]

length = 0.5 			!length of column [m]
eMaterial = 210e9

mass = 1.7898			!mass on top of the column [kg]

anz=10					!number of elements

duration=2
timestep=0.01			!anzahl lastschritte
omega=25.13				!excitation frequency
p=8.4679

!preprozessor
/PREP7
!geometry

K,1,0,0
K,2,0,length

!lines
L,1,2

!number of elements
LSEL,s,length,,length
LESIZE,all,,,anz

ALLSEL
!element type
ET,1,BEAM188
MP,EX,1,eMaterial
MP,PRXY,1,0.3

!cross-section
SECTYPE,1,BEAM,RECT
SECDATA,hoehe,breite

!generate fe net
type,1
mat,1
LMESH,all

!mass element
ET,2,Mass21
Keyopt,2,1,0
KEYOPT,2,2,0
Keyopt,2,3,4

R,2,mass

!put on the mass
type,2
real,2
nsel,s,loc,y,length
*get,nodenr,node,0,num,max
E,nodenr

!Solution
/SOLU

ANTYPE,4
TRNOPT,FULL
kbc,0
autots,off
outres,all,all
nsub,1
TIMINT,on,all
TINTP,0

!constraints of DOF
ALLSEL
D,all,UZ,0,,,,ROTX,ROTY			!system just in x and y
ALLSEL
NSEL,s,loc,x,0
NSEL,r,loc,y,0
D,all,UY,0,,,,UX,ROTZ
ALLSEL
NSEL,s,loc,y,length
D,all,UY,0,,,,ROTX,ROTY
ALLSEL

!movement of the footing
*do,time,timestep,duration,timestep
time,time
F,2,FX,p*sin(omega*time)
solve
FDELE,2,ALL
*enddo

FINISH

!Post processor
/POST26
NSOL,2,2,U,X,UX
STORE,MERGE

PRVAR,2
PLVAR,2