finish
/clear
/prep7



!!!Element-Typen!!!

ET,1,SOLID95

et,2,mpc184
keyopt,2,1,1

et,3,mesh200	!Als Platzhalter, siehe unten
keyopt,3,1,7	!Quadrilateral mit 8 Knoten



!!! Material-Parameter!!!

mp,ex,1,2.1e11
mp,prxy,1,0.3
mp,dens,1,7850



!!!Modellierung!!!

!Erzeugen eines Rechteckquerschnitts
BLC4, , ,0.2,0.005	

!Vermeshen mit mesh200 Elementen
type,3
esize,0.002
amesh,all

!Extrudieren um die Rotationsaxe unter Verwendung von SOLID95-Elementen
!Hab ich mit der GUI gemacht und hier reinkopiert

TYPE,   1   
EXTOPT,ESIZE,5,0,   
EXTOPT,ACLEAR,0 
!*  
EXTOPT,ATTR,0,0,0   
MAT,1   
REAL,_Z4
ESYS,0  
!*  
FLST,2,1,5,ORDE,1   
FITEM,2,1   
FLST,8,2,3  
FITEM,8,1   
FITEM,8,2   
VROTAT,P51X, , , , , ,P51X, ,360, , 




!!!Modellierung der Lager!!!

!Erzeugen der beiden Lagerknoten
*get,nmax,node,0,num,max
N1=nmax+1
N2=nmax+2
n,N1,0,0,0		!Festlager
n,N2,0.2,0,0		!Loslager


!Modellierung des Festlagers!

!selektiere alle Knoten auf der Stirnseite der Welle
nsel,none
nsel,all
NSEL,S,LOC,X,0,0

!Auswahl der Knoten auf der äußeren Kante
!dazu werden alle Knoten aus der Auswahl entfernt, die einen Radialabstand von kleiner als 4,5mm haben

narb=0	!Zählvariable
*get,nanz,node,,count !Anzahl der Knoten
*do,i,1,nanz-1 !Schleife bis nanz durchlaufen
narb=ndnext(narb)
distanz=distnd(N1,narb)
*if,distanz,lt,0.0045,then	!Knoten mit weniger als 4,5mm Radialabstand werden entfernt
nsel,u,node,,narb
*endif
*enddo

CM,fest,NODE	!Abspeichern der Kanten-Knoten


!Verknüpfen der Kanten-Knoten mit dem Lagerknoten per MPC184

nsel,none
nsel,all

cmsel,s,fest,nodes
nsel,a,node,,n1
*get,nanz,node,,count !Anzahl der Ringknoten
mat,1
type,2 !Aktivieren des MPC-Elementtyps
narb=0
*do,i,1,nanz-1 !Schleife mit nanz durchlaufen
narb=ndnext(narb)
e,N1,narb !MPC184 zwischen Lagermittelpunkt und Ringknoten legen
*enddo




!Modellierung des Loslagers!
!genau wie beim Festlager

nsel,none
nsel,all
NSEL,S,LOC,X,0.2,0.2	!komischer Weise werden hier auch die Knoten erfasst mit einem x-Wert von 0.195 statt 0.2

narb=0
*get,nanz,node,,count !Anzahl der Knoten

*do,i,1,nanz-1 !Schleife mit nanz durchlaufen
narb=ndnext(narb)
distanz=distnd(N2,narb)
*if,distanz,lt,0.0045,then
nsel,u,node,,narb
*endif
*get,x_koord,node,narb,loc,x	
*if,x_koord,ne,0.2,then	!rausschmeissen der Knoten mit einem x-Wert ungleich 0.2
nsel,u,node,,narb
*endif
*enddo

CM,los,NODE

nsel,none
nsel,all

cmsel,s,los,nodes
nsel,a,node,,n2
*get,nanz,node,,count !Anzahl der Ringknoten
mat,1
type,2 !Aktivieren des MPC-Elementtyps
narb=0
*do,i,1,nanz-1 !Schleife mit nanz durchlaufen
narb=ndnext(narb)
e,N2,narb !MPC zwischen Lagermittelpunkt und Ringknoten legen
*enddo



!!!Randbedingungen setzen!!!

nsel,none
nsel,all

!Festlager
d,N1,ux
d,N1,uy
d,N1,uz
d,N1,rotx

!Loslager
d,N2,uy
d,N2,uz


!!!Modalanalyse!!!
!wieder nur aus der GUI rauskopiert

FINISH  
/SOL
!*  
ANTYPE,2
!*  
!*  
MODOPT,LANB,10  
EQSLV,SPAR  
MXPAND,0, , ,0  
LUMPM,0 
PSTRES,0
!*  
MODOPT,LANB,10,0,10000, ,OFF

!!!Lösen!!!
SOLVE   

!!!Ergebnisse anzeigen!!!!
FINISH  
/POST1  
SET,LIST


!Analytische Lösung wäre: f1=508, f2=2031, f3=4570, f4=...