!!! Welcher Querschnitt soll untersucht werden? 
       d    =    4.0           ! Drahtdurchmesser                               [mm]
       l    =   80.0           ! Laenge des zu untersuchenden Balkens           [mm]
       a    =    d/2           ! spaeter wichtig: fuer Untersuchung von
       b    =    d/2           ! ellyptischen Querschnitten

  !!! Werkstoffdaten/ Konstanten 
       E     =   205800        ! E-Modul des Werkstoffs                         [N/mm²]
       G     =    79380        ! Schubmodul                                     [N/mm²]
       rho   =        7.9E-6   ! Dichte des Werkstoffs                          [kg/mm²]
       my    =   E/(2*G)-1     ! Querkontraktion (my = ~0.295)                  [1]
       damp  =        0.03     ! innere Daempfung des Werkstoffs                [1]
	   Pi    =        3.14159  !                                                [1]

       M     =    1            ! Moment (Einheit beachten!)                     [Nmm]

! # ///////////////////////////////////////////////////////////////////////////////////// #
! # ////////////////////////////////// PRAEPROZESSOR //////////////////////////////////// #

/PREP7                         ! Starten des Praeprozessors

MPTEMP,,,,,,,,
MPTEMP,1,0  
MPDATA,EX,1,,E                 ! E-Modul          (oben definiert) 
MPDATA,DENS,1,,rho             ! Dichte           (oben definiert) 
MPDATA,PRXY,1,,my              ! Querkontraktion  (oben definiert) 
MPDATA,DAMP,1,,0.03            ! innere Daempfung (oben definiert)

!==== Geometrie ===========================================================================
K, 1  ,0    ,0   ,0            ! Keypoint Nr.1 immer im KO-Ursprung/ Schwerpunkt  
K, 2  ,-a   ,0   ,0            ! Keypoint Nr.2 rechter, aeusserer Rand
K, 3  ,0    ,b   ,0            ! Keypoint Nr.3 oberer Rand

L,2,1                          ! Linie, von KP2 zu KP1 (immer in Richtung 0-Punkt - Netz!)
L,3,1                          ! Linie, von KP3 zu KP1 (immer in Richtung 0-Punkt - Netz!)
LARC,2,3,1,a                   ! Linie, von KP2 zu KP3, Center = KP1, Radius = a)

AL,1,2,3                       ! generiert eine Flaeche ueber Linien 1,2,3
LSEL,S,LINE,,1,2,1             ! Auswaehlen der Linien L1 und L2
LESIZE,ALL,,,4,2,,,1           ! Unterteilung aller ausgewaehlten Linien in:
                               ! Segmente: "f", Skalierungsfaktor: 2
LSEL,S,LINE,,3                 ! Auswaehlen der Linie L3 (das Bogenstueck)
LESIZE,ALL,,,6                 ! Unterteilen der Bogenstuecke in Segmente der Laenge 6
LSEL,ALL                       ! wieder alle Linien anwaehlen

!==== Volumenkörper bilden und mit Elementen (SOLID186) "fuellen" ========================
ET,1,SOLID186                  ! Elementtyp (1) --> "SOLID186" Quader mit 20 Knoten
TYPE,1                         ! ab jetzt haben alle neuen Elemente den Typ (1)

VEXT,1,,,,,-l                  ! Flaeche Nr.1 extrudieren um "l" --> neg. Z-Achse

VSEL,ALL                       ! Volumen anwaehlen (noch gibt es nur das eine)
ESIZE,,l/2                     ! Laenge der nun kreierten Elemente: 6
VSWEEP,ALL,1,                  ! Volumen mit Elementen füllen, Laenge der einzelnen
                               ! Elemente richtet sich nach "ESIZE"

!==== Spiegeln ===========================================================================
VSYMM,X,ALL,,,,0,0             ! alle Volumen um die X-Achse spiegeln (--> obere Haelfte)
VSYMM,Y,ALL,,,,0,0             ! alle Volumen um die Y-Achse spiegeln (--> Draht komplett)

NUMMRG,ALL,10E-6,,LOW          ! alle doppelten Objekte loeschen
NUMCMP,NODE                    ! Knoten neu durchnummerieren

/VIEW,1,1,1,1                  ! isometrische Ansicht
/ANG,1
/REP,FAST                      ! Grafik neu aufbauen

!===== (1) Flaeche, die gehalten wird ====================================================
NSEL,S,LOC,Z,0                 ! selektiere alle Knoten der Flaeche A1
D,ALL,,,,,,ALL                 ! Alle Freiheitsgrade beschraenken...

!===== (2) Flaeche zum erzeugen des (Torsions-)Moments mit "MPC184" (steif!) =============
NSEL,ALL                       ! wieder alle Knoten selektieren
*GET,n_nall,NODE,0,NUM,MAX     ! Anzahl aller Knoten ermitteln
master = n_nall+1              ! der Masterknoten hat immer die hoechte Knoten-Nummer
N,master,0,0,-(l+5)            ! Master-Knoten fuer MPC184 setzen

NSEL,S,LOC,Z,-l                ! selektiere alle Knoten der Flaeche A2 ( Z = 0)
*GET,n_nqf,NODE,0,NUM,MAX      ! Anzahl der Knoten der Flaeche A2 ermitteln
NSEL,A,NODE,,master
EPLOT

ET,2,MASS21 
R,1,0,0,0,0,0,0,
Type,2
Real,1
e,master

seltol,1e-3
nsel,,loc,z,-80
cm,stfl,node
nsel,a,,,master

CERIG,master,ALL,all, , , ,  

!ET,2,184,1                     ! Elementtyp 3 ist "MPC184"
!TYPE,2                         ! Ab jetzt entstehen Elemente des Typs 3

!*DO,KNOTEN,1,n_nqf,1           ! Beginn der Schleife zum Erstellen des "MPC184"
!  E,master,KNOTEN              ! Var. "KNOTEN" von 1 bis n_nqf, Schrittweite: 1
!*ENDDO                         ! Element bilden von M.-Knoten zu "KNOTEN"

!===== Masterknoten mit einem Moment beaufschlagen =======================================
D,master,UX,,,,,UY,,ROTX,ROTY  ! Freiheitsgrade des Masterknotens:
                               ! nur Rotation um Z-Achse und Translation in Z-Richtung
F,master,MZ,M                  ! Masterknoten der Flaeche (2) wird nun mit dem oben defi-
                               ! nierten Moment um Z-Achse belastet
ALLSEL                         ! fuer die Simulation wieder alles auswahlen
FINISH

! # ///////////////////////////////////////////////////////////////////////////////////// #
! # ////////////////////////////////// SOLUTION ///////////////////////////////////////// #

/SOLU                          ! Startet das Loesungs-Modul
antype,static
!NLGEOM,ON
!NSUBST,1
SOLVE
FINISH

!===== Flaeche (3) zum Auswerten der Spannungen definieren (--> bei l/2) =================
ALLSEL
NSEL,S,LOC,Z,-l/2              ! selektiere alle Knoten der Flaeche A3
ESLN,S,0,ALL                   ! Alle Elemente anwaehlen, die an den gew. Knoten haengen
/AUTO,1                        ! Gew. Elemente in Ansicht einpassen
/VIEW,1,,,1                    ! Ansicht von "vorne"
/REP,FAST                      ! Grafik neu aufbauen
EPLOT                          ! (selektierte) Elemente anzeigen

! # ///////////////////////////////////////////////////////////////////////////////////// #
! # /////////////////////////////////// POSTPROZESSOR /////////////////////////////////// #

/POST1
PLESOL, S,1, 0,1.0             ! Darstellung der Schubspannungen an den Elementen
                               ! "1st Principal stress"