Makros führen Befehlsfolgen selbständig aus. Über Makros werden häufig verwendete Befehlsreihen
durch einen Aufruf durchgeführt. Der Vorteil dieser systemeigenen Programmiersprache liegt damit in der
rationalisierten Erstellung von Zeichnungen. Unter dem Menüpunkt [MAKROS] findet man solche Befehlsreihen.
[Die Version der LKT-Rechner der Saarbrücker Universität enthält viele Makros, bei denen durch wenige
Eingaben viele geometrische Komponenten schnell und einfach erstellt werden, zum Beispiel Paßfedern.]
Für jeden Befehl unter ME10 gibt es ein englisches Gegenstück, dessen Wortlaut und Bedeutung man
meist über Anwählen von [HILFE] und Anklicken des gewünschten Befehls finden kann. Die
Makroprogrammiersprache setzt sich aus diesen englischen Befehlen und verschiedenen Funktionen zusammen, die aus
der Basic-Programmiersprache bekannt sind.
Als Beispiel zur Makroprogrammierung folgt die Erstellung einer Welle mit Paßfedernut (Abbildung 11.1).
Das zugehörige Makroprogramm kann wie folgt aussehen28:
DEFINE wellenausschnitt {Makrobeginn}
{Definition der lokalen Variablen}
LOCAL D {Durchmesser der Welle}
LOCAL P0 {Positionierungspunkt}
LOCAL P1 { Es folgen Konstruktionspunkte}
LOCAL P2
LOCAL P3
LOCAL P4
LOCAL P5
LOCAL P6
LOCAL P7
LOCAL P8
LOCAL W {Winkel zur positiven x-Achse}
LOCAL T {Nuttiefe}
LOCAL B {Nutbreite}
{Koordinatensystem zurücksetzen}
CS_REF_PT 0,0
CS_AXIS ABSOLUTE 0 1 90 1
{Eingabebefehle}
READ PNT 'Positionierungspunkt!(Mausklick)' P0
READ NUMBER 'Durchmesser eingeben:' D
READ NUMBER 'Ausrichtung der Nut zur positiven x-Achse (Winkel):' W
READ NUMBER 'Nuttiefe eingeben:' T
READ NUMBER 'Nutbreite eingeben:' B
CS_REF_PT P0 {Koordinatensystem in P0 setzen}
CS_ROTATE W {Koordinatensystem um Winkel W drehen}
{Punktzuweisungen}
LET P1 (PNT_XY ((-D/2)-(D/8)) 0)
LET P8 (PNT_XY 0 ((D/2)+(D/8)))
LET P7 (PNT_XY 0 ((-D/2)-(D/8)))
LET P6 (PNT_XY ((D/2)+(D/8)) 0)
LET P3 (PNT_XY (-B/2) ((D/2)-T))
LET P4 (PNT_XY (B/2) ((D/2)-T))
LET P2 (PNT_XY (-B/2) (SQRT(SQR(D/2)-SQR(B/2))))
LET P5 (PNT_XY (B/2) (SQRT(SQR(D/2)-SQR(B/2))))
LET P0 (0,0)
LINETYPE SOLID {Linienart auf Vollinie}
COLOR YELLOW {Linienfarbe auf Gelb}
LINE POLYGON P2 P3 P4 P5 END {Polygon über die Punkte erzeugen}
ARC CEN_BEG_END P0 P2 P5 {Kreisbogen über die angegebenen Punkte}
ARC CEN_BEG_END P0 P5 P2
LINETYPE DOT_CENTER {Linienart auf Strichpunktiert}
COLOR GREEN {Linienfarbe auf Grün}
{Linie zwischen den angegebenen Punkten}
LINE P1 P6
LINE P7 P8 END
CS_ROTATE ABSOLUTE 0 {Kooordinatensystem zurückdrehen}
HATCH_ANGLE 45 {Schraffurwinkel auf 45° gesetzt}
HATCH_DIST 5 {Schraffurabstand auf 5mm gesetzt}
{Schraffurmuster festlegen}
CURRENT_HATCH_PATTERN 0 1 0 RED SOLID CONFIRM
{Automische Schraffurerstellung über Punkt innerhalb der Kontur}
HATCH AUTO (PNT_XY (D/1000) (D/1000)) END
{Koordinatensystem zurücksetzen}
CS_REF_PT 0,0
CS_AXIS ABSOLUTE 0 1 90 1
END_DEFINE {Makroende}
Die Vorgehensweise zur Makroprogrammierung:
Eingabe des Makroprogrammes in einem ASCII-Texteditor unter dem jeweiligen Betriebssystem.
Abspeichern des Makroprogrammes unter dem Texteditor.
Anklicken von [DATEI] EINGABE und Eingeben des Namens durch Anwählen in der Dateiliste oder über
die Tastatur.
Der Aufruf des Makroprogrammes erfolgt über die Eingabe des Makonamens (steht hinter dem Befehl DEFINE)
in die Eingabezeile.
Weitere Bearbeitungsmöglichkeiten bestehen über die Befehle: LOAD_MACRO, EDIT_MACRO und
SAVE_MACRO.