qclear

/FILNAME,prob
/prep7
/units,mpa

DA_=20			! Außendurchmesser CFK
DI_=14			! Innendurchmesser CFK
Chrom=0.05		! Schichtdicke Chrom
wink_st=180		! Ausschnittswinkel
E_wink=20		! Elemente entlang des Umfangs
ANZ_LAY=9		! Lagenanzahl
TK_LAM=DA_/2-DI_/2	! Dicke des Rohrs
TK_LAY=TK_LAM/ANZ_LAY	! Lagendicke

E_Rad=ANZ_LAY
LAE_=40			! Länge
Delta_T=140		! Temperaturdifferenz

mp,ex,2,146000
mp,ey,2,6000
mp,ez,2,6000
mp,prxy,2,0.26
mp,prxz,2,0.26
mp,pryz,2,0.36
mp,gxy,2,3200
mp,gxz,2,3200
mp,gyz,2,2200
mp,alpx,2,1e-6
mp,alpy,2,25e-6
mp,alpz,2,25e-6

mp,ex,1,210000
mp,nuxy,1,0.3
mp,alpx,1,12e-6

et,1,181
et,2,185
keyopt,2,3,1		! Elementtypen
keyopt,2,8,1

C**** Modellierung/Meshing des Rohres

mat,2
real,2
local,11,1
csys,0
cyl4,0,0,Di_/2,0,DA_/2,Wink_st
lesize,1,,,E_wink
lesize,2,,,E_Rad,
lesize,4,,,E_Rad,
amap,1,1,2,3,4
eplot
type,2
esize,,20
voffst,1,LAE_,10
aclear,all
cm,E_CFK,elem
csys,11

C**** Definition des Lagenaufbaus

*do,i,1,7
sect,i+100,shell,,Laminat%I%   
secdata, TK_LAY/2,2,90+30,3			! +/- 60° Lagen
secdata, TK_LAY/2,2,90-30,3
*enddo
i=8+100
sect,i,shell,,Laminat%I%   
secdata, TK_LAY/2,2,90+37.5,3			! +/- 52,5° Lagen
secdata, TK_LAY/2,2,90-37.5,3			
i=9+100
sect,i,shell,,Laminat%I%   
secdata, TK_LAY/2,2,90+45,3			! +/- 45° Lagen
secdata, TK_LAY/2,2,90-45,3

alls
emodif,all,esys,11

eorient,185,posx				! Ausrichtung der Elemente


alls
*do,i,1,ANZ_LAY
nsel,s,loc,x,(DI_/2+(i-1)*TK_LAY)*0.99,(DI_/2+(i)*TK_LAY)*1.01
esln,s,all
cm,Elem_C%i%,elem
emodif,all,sec,i+100
*enddo
alls

C**** Chromschicht

type,1
r,1,Chrom			! Dicke der Chromschicht
real,1
mat,1
secn,1
sect,1,shell,,Chromschicht  
secdata,Chrom,1,0,3
secoffset,BOT 
A_old=3
asel,s,,,A_old
amesh,all
agen,2,all
*GET,AMAX,AREA,,NUM,MAX
A_NEW=amax
aclear,A_Old
esel,s,type,,1
emodif,all,mat,1

/eshape,1
eplot

MAT,1   
R,3 
REAL,3  
ET,3,TARGE170
ET,4,CONTA173
R,3,,,1.0,0.1,0,
RMORE,,,1.0E20,0.0,1.0, 
RMORE,0.0,0,1.0,,1.0,0.5
RMORE,0,1.0,1.0,0.0,,1.0
KEYOPT,4,4,0			! location of contac detection point...gauss point
KEYOPT,4,5,0			! No automated adjustment for CNOF/ICONT
KEYOPT,4,7,0			! No Element level time incrementation control
KEYOPT,4,8,0			! No Asymmetric contact selection
KEYOPT,4,9,0			! Include both initial geometrical penetration or gap and offset
KEYOPT,4,10,2			! contact stiffnes update: Each iteration based on current mean stress of underlying elements   
KEYOPT,4,11,0			! exclude shell stiffnes effect
KEYOPT,4,12,3   		! bonded contact behavior
KEYOPT,4,2,0			! augmented lagrange
KEYOPT,3,5,0			! Automatic constraint type detection 
! Generate the target surface   
ASEL,S,,,A_NEW 
TYPE,3  
NSLA,S,1
ESLN,S,0
ESLL,U  
ESEL,U,ENAME,,188,189   
ESURF,,bottom
! ESURF,,reverse
! Generate the contact surface  
ASEL,S,,,A_Old
TYPE,4  
NSLA,S,1
ESLN,S,0
ESURF
! ESURF,,REVERSE
ALLSEL  

csys,11
nrot,all

/solu
nsel,s,loc,z,0
d,all,uy
nsel,r,loc,x,DI_/2
d,all,uz
nsel,s,loc,y,0
nsel,a,loc,y,180
d,all,uy
alls
bfunif,temp,Delta_T
! solve