fini
/clear
/batch

!----------------------------Makros

!----------------------------Ausgabemakroinit
*create,Ausgabeinit,mac
/com,
/out,sine,txt
/com,-------- einfache Ergebnisausgabe -------
/com,
/com,L[m]	H[m]	T[°C]	sigma[Pa]	Verkippwinkel[deg]	Max_Displ[m]	Min_Displ[m]
/com, -------------------------------------------
/out
*end

!----------------------------Ausgabemakro
*create,Ausgabe,mac
/COM
/OUT,sine,txt,,append
*MWRITE,erg
(' ',F11.9,'   ',F11.9,'   ',F6.2,'   ',F11.9,'   ',F10.7,'   ',F11.9,'   ',F11.9)
/OUT
*end


/prep7
*afun,deg
pi = 4*atan(1)
D=600e-9
L=1e-3
H=1e-6
dH=1		!Teilung der Höhe
B=100*D
!B=1e-5
alpha=54.74
s=0e+6
T=300
dT=30		!Teilung der Temperatur

E=300e+9	!E-Modul
nu=0.287	!Querkontraktionszahl
ausdehn=3.75e-6

et,1,188
sectype,1,beam,rect,
secdata,D,B,4,4
keyopt,1,1,1
keyopt,1,2,0

mp,ex,1,E
mp,nuxy,1,nu
mp,alpx,1,ausdehn

fini		!Prep7 verlassen

*dim,erg,array,1,7
ausgabeinit

*do,iH,1,dH,1
	/prep7
	lclear,all
	ldele,all
	kclear,all
	Hakt=H/dH*iH
	csys,0
	k,1,0,0,0
	k,2,L/2-Hakt/tan(alpha)/2,0,0
	k,3,L/2+Hakt/tan(alpha)/2,Hakt,0
	k,4,L,Hakt,0
	L,1,2
	L,2,3
	L,3,4

	lesize,1,10*D,,
	lesize,2,,,2
	lesize,3,10*D,,

	lmesh,all
	fini

	!------------------------Solution---------------------
	/solu
	!------------------------1. Lastfall------------------
	antype,0
	nlgeom,on
	nsubst,1000,100000,10,on
	pstr,off
	sstif,on

	d,1,all,0
	*get,nmax,node,,num,max
	d,nmax,all,0
	nsel,s,loc,y,Hakt/2
	d,all,ux,0,,,,uy,uz
	alls

	inistate,define,,,,,s,s,s,s,s,s
	tref, 0
	kbc,0
	solve
	fini
	
	*do,iT,1,dT,1
		/prep7
		upgeom,,,,file,rst
		fini

		Takt=T/dT*iT
		/solu
		antype,0
		nlgeom,on
		nsubst,10,100000,10,on
		pstr,off
		sstiff,on
		tref,0
		tunif,Takt
		kbc,0
		solve
		fini
		
		/post26
		numvar,200
		erg(1,1)=L
		erg(1,2)=Hakt
		erg(1,3)=Takt
		erg(1,4)=s
		nsol,2,nmax/2,rot,z
		vget,erg(1,5),2
		fini
		/post1
		/dscale,,0
		plnsol,uy
		*get,erg(1,6),plnsol,0,max
		*get,erg(1,7),plnsol,0,min
		ausgabe
		fini
		cdwrite,db,Geometrie,rst
	*enddo
*enddo
/post1
pldisp,2
/dscale,,auto

plnsol,uy	!Verschiebung in y-Richtung darstellen
/dscale,,0	!Verschiebung in realer Verformung
prnsol,uy	!Verschiebung anzeigen

plnsol,rot,z
prnsol,rot,z