! FEM fuer Praktiker Band 3: Temperaturfelder
! zwei überlappende Bleche werden mit einer linken (von unten) und rechten (von oben)
! Schweissnaht verschweisst. Die Geometrie der Schweissnaht wird modelliert, die 
! zugehörigen Elemente mit EKILL / EALIVE de-/aktiviert
! Schweissnaht links in von t=0 bis 2 s Schweissen, bis t=10 s Pause, 
! bis t=12 s Schweissnaht rechts, bis t=20 s Pause
! Blech 1 -----------------------\ Schweissnaht rechts
!        Schweissnaht links \---------------------- Blech 2
! Transiente Analyse, Temperaturverteilung berechnen
finish  
/clear
/prep7
immed,1 

et,1,plane55
k,1,0,5.3   
k,2,35,5.3  
k,3,0,.3
k,4,35,.3   
k,5,36,-.3  
k,6,41,-.3  
a,1,2,4,3   
a,2,6,5,4   
local,11,1,30   
agen,2,all,,,,180   
aglue,all   
/pnum,line,1
lplot   

lsel,s,,,2  
lsel,a,,,9  
lsel,a,,,7  
lsel,a,,,14 
lesize,all,,,5  
mshkey,1
mshape,0,2d 
amesh,2,4,2 
mshkey,2
esize,1.6   
amesh,all   

mp,kxx,1,16.5   
mp,c,1,500e6
mp,dens,1,7.85e-9   
asel,s,,,2  
esla
cm,nahtr,elem   
asel,s,,,4  
esla
cm,nahtl,elem   
allsel  
 
/solu
antype,trans
nropt,full  
eqslv,front 
nsel,s,ext  
sf,all,conv,10e-3,20
allsel  

! estif,1e-6 Standardwert, Voreinstellung
estif,1e-60

time,1e-6
nsub,1   
cmsel,s,nahtl   
cmsel,a,nahtr   
ekill,all
esel,s,live 
eplot
allsel  
d,all,temp,20   
solve
   
timint,on   
tintp,,,,1.0
time,2.0
nsub,1  
ddel,all,temp   
cmsel,s,nahtl 
ealive,all  
nsle,s,1
d,all,temp,1200 
!cmsel,a,nahtr !fuer Testzwecke, Kontrolle ob bewusstes Einschalten etwas am
!ealive,all    !ergebnis aendert
allsel  
solve
   
time,10 
nsub,16 
outres,all,all  
ddel,all,temp   
solve
   
time,12 
nsub,1  
cmsel,s,nahtr   
ealive,all  
nsle,s,1
d,all,temp,1200 
allsel  
solve
   
time,20 
nsub,16 
ddel,all,temp   
solve   
FINISH
  
/POST26 
csys
nsol,2,node(24,.3,0),temp,,tl   
nsol,3,node(36,-.3,0),temp,,tr  
nsol,4,node(0,.3,0),temp,,tll   
nsol,5,node(60,-.3,0),temp,,trr 
plvar,2,3,4,5   
FINISH  
/POST1  
set,,,,,10  
plns,temp
cmsel,s,nahtr   
esel,invert 
set,,,,,10  
plnsol,temp 
allsel  
plnsol,temp 
set,,,,,20  
plns,temp  

/quit
!nur fuer testzwecke
/post1
set,,,,,5
plnsol,temp
cmsel,s,nahtr
etable,temp_nr,temp
pretab,temp_nr