! Testprogramm Kontakt-Modell

!_________________________________________________________________________________
!_________________________________________________________________________________

fini
/clear
!_________________________________________________________________________________

! Konstanten
bl=12
bl2=15
dko=3
dku=4
dl=1
dm=5
dr=0.5
du=1
hi=6
hm=10
ho=4
hu=5
ro=1
rr=1
ru=1
r2=50
tk=2
!_________________________________________________________________________________
!_________________________________________________________________________________

! Preprocessing
/prep7
!_________________________________________________________________________________

! lokale Koordinatensysteme
local,11,1,r2-dku-ru,du+ru,0
local,12,1,r2-tk-dko-ro,hu+hm-dl-ro,0
local,13,1,r2-dku-ru-1,du+ru,0
local,14,1,r2-tk-dko-ro-1,hu+hm-dl-ro,0
!_________________________________________________________________________________

! Elementtypen
et,1,plane182,,,1		! Axialsymmetrie festgelegt
et,2,conta171,,0,,1		! Kontaktelement
et,3,targe169			! Targetelement
!_________________________________________________________________________________

! Realkonstanten für Zuordnung der Kontaktpartner
r,1
!_________________________________________________________________________________

! Materialeigenschaften
mp,ex,1,5
mp,nuxy,1,0.4
!_________________________________________________________________________________

! Geometrie

! K1
csys,0
k,,0,0,0
k,,0,du,0
k,,r2-dku-ru,du,0
k,,r2-dku,du+ru,0
k,,r2-dku-ru*(1-cos(1/4*3.14159)),du+ru+ru*sin(1/4*3.14159),0
k,,r2-tk-dm,hu,0
k,,r2-tk-dm,hu+hi,0
k,,r2-tk-dko-ro*(1-cos(3/8*3.14159)),hu+hm-dl-ro-ro*sin(3/8*3.14159),0
k,,r2-tk-dko,hu+hm-dl-ro,0
k,,r2-tk-dko-ro,hu+hm-dl,0
k,,r2-tk-dm-bl2-rr,hu+hm-dl,0
k,,r2-tk-dm-bl2-rr,hu+hm+rr,0
k,,r2-tk-dm-bl2,hu+hm,0
k,,r2-tk-dm,hu+hm,0
k,,r2-tk,hu+hm+ho-dl,0
k,,r2-tk-bl-rr,hu+hm+ho-dl,0
k,,r2-tk-bl-rr,hu+hm+ho+rr,0
k,,r2-tk-bl,hu+hm+ho,0
k,,r2-dr,hu+hm+ho,0
k,,r2-dr,hu+hm,0
k,,r2-tk,hu+hm,0
k,,r2-tk,hu,0
k,,r2,hu,0
k,,r2,0,0
l,1,2
l,2,3
csys,11
l,3,4
l,4,5
csys,0
l,5,6
l,6,7
l,7,8
csys,12
l,8,9
l,9,10
csys,0
l,10,11
l,11,12
l,12,13
l,13,14
l,14,15
l,15,16
l,16,17
l,17,18
l,18,19
l,19,20
l,20,21
l,21,22
l,22,23
l,23,24
l,24,1
al,all

! K2

! Keypoints ohne Abstand zu K1
!k,,r2-dku-5,du+ru,0
!k,,r2-dku,du+ru,0
!k,,r2-dku-ru*(1-cos(1/4*3.14159)),du+ru+ru*sin(1/4*3.14159),0
!k,,r2-tk-dm,hu,0
!k,,r2-tk-dm,hu+hi,0
!k,,r2-tk-dko-ro*(1-cos(3/8*3.14159)),hu+hm-dl-ro-ro*sin(3/8*3.14159),0
!k,,r2-tk-dko,hu+hm-dl-ro,0
!k,,r2-tk-dko-ro,hu+hm-dl,0
!k,,r2-tk-dko-ro-3,hu+hm-dl,0

! keypoints mit Abstand 1 zu K1
k,,r2-dku-5-1,du+ru,0
k,,r2-dku-1,du+ru,0
k,,r2-dku-ru*(1-cos(1/4*3.14159))-1,du+ru+ru*sin(1/4*3.14159),0
k,,r2-tk-dm-1,hu,0
k,,r2-tk-dm-1,hu+hi,0
k,,r2-tk-dko-ro*(1-cos(3/8*3.14159))-1,hu+hm-dl-ro-ro*sin(3/8*3.14159),0
k,,r2-tk-dko-1,hu+hm-dl-ro,0
k,,r2-tk-dko-ro-1,hu+hm-dl,0
k,,r2-tk-dko-ro-3-1,hu+hm-dl,0
l,25,26
!csys,11
csys,13
l,26,27
csys,0
l,27,28
l,28,29
l,29,30
!csys,12
csys,14
l,30,31
l,31,32
csys,0
l,32,33
l,33,25
lsel,s,line,,25,33
al,all
allsel
!_________________________________________________________________________________

! Vernetzung K1
type,1
mat,1
esize,0.5
amesh,1

! Kontakt
type,2				! Kontaktelement (K1)
real,1
lmesh,3,10
type,3				! Targetelement (K2)
real,1
lmesh,26,32
!_________________________________________________________________________________

! Kontrolle Elementkoordinatensysteme

! Anzeigen der Normalenrichtungen der Kontaktelemente
!/psymb,esys,1
!esel,s,type,,2
!eplot
!allsel

! Anzeigen der Normalenrichtungen der Targetelemente
!/psymb,esys,1
!esel,s,type,,3
!eplot
!allsel

! Elemente drehen
lsel,s,line,,3,10
esll,s
esurf,,reverse
allsel

fini
!_________________________________________________________________________________
!_________________________________________________________________________________

! Lösen
/solu
!_________________________________________________________________________________

! Randbedingungen

! Lager K1
lsel,s,line,,11,16,5
dl,all,,ux,0
dl,all,,uy,0
allsel
dl,24,,uy,0

! Verschiebung von K2
lsel,s,line,,25,33
dl,all,,ux,4
allsel
!_________________________________________________________________________________

! Lösen
solve
fini
!_________________________________________________________________________________
!_________________________________________________________________________________

! Postprocessing
/post1
!_________________________________________________________________________________

! Darstellung der Verformung
/dscale,,1			! 1:1
pldisp,2

fini
!_________________________________________________________________________________
!_________________________________________________________________________________

! Wenn sich zu Beginn der Rechnung kein Spalt zwischen K1 und K2 befindet,
! wird der Kontakt erkannt. Besteht ein Abstand wird Kontakt ignoriert.
! Wieso?