fini
/CLEAR,START

!-----------------------------------------------------------------------
q2=1
q1=2
aa=200         !Radius
TBL=5
KRAEFTE=1      !1=Knotenkräfte 0=Drücke
ALTE_FORMEL=1  !1=alteformel 0=neue Formel
!-----------------------------------------------------------------------
/PREP7
!*
ET,1,SHELL93
!*
R,1,TBL, , , , , ,
!*
!*
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,210000
MPDATA,PRXY,1,,.3
PCIRC,AA,0,0,90,
PCIRC,AA,0,90,180,
PCIRC,AA,0,180,270,
PCIRC,AA,0,270,360
Nummrg,kp
numcmp,kp
numcmp,line

SMRT,1
ESIZE,10,0,
MSHAPE,0,2D
MSHKEY,0
!*
ASEL,all
CHKMSH,'AREA'
AMESH,ALL
!*

lsel,s,radius,,aa
nsll,s,1
d,all,uz
nsel,s,loc,y,0
nsel,r,loc,x,0
d,all,ux
d,all,uy


*IF,KRAEFTE,EQ,1,THEN
   nsle,s,corner           !bei Elementen mit zwknoten nur eckknoten auswählen
                           !ansonsten werden die zwischenknoten falsch belastet
   *get,minn,node,0,num,min
   *get,mxnn,node,0,num,max
   *do,ni,minn,mxnn
   *if,nsel(ni),eq,1,then
       *if,ny(ni),eq,0,and,nx(ni),eq,aa,then
             F,ni,FZ,-q2
       *elseif,ny(ni),eq,0,and,nx(ni),eq,-aa,then
             F,ni,FZ,-q1
       *else
           *IF,ALTE_FORMEL,EQ,1,THEN
             F,ni,FZ, -q2-q1*cos(asin((-ny(ni))/aa))    !alte Version
           *else
             F,ni,FZ,(-q1-(q2-q1)*((NX(ni)+AA)/(2*AA)))*cos(asin((-ny(ni))/aa))
           *endif
       *endif
   *endif
   *enddo
  nsle,s
/PBC,F,,1
/PBC,U, ,1
EPLO
*ENDIF

*IF,KRAEFTE,EQ,0,THEN
*GET,N_ELEM,ELEM,,count    !ANZ_ELEM
*GET,MIN_E,ELEM,,num,min   !kleinste ElementNummer

*DIM,NN,,4
*DIM,PII,,4

*DO,I,1,N_ELEM            !Schleife über die ELEMENTE
   NN(1)=NELEM(MIN_E,1)
   NN(2)=NELEM(MIN_E,2)
   NN(3)=Nelem(MIN_E,3)
   NN(4)=Nelem(MIN_E,4)

  *IF,ALTE_FORMEL,EQ,1,THEN
    *DO,J,1,4
       n1=NN(J)
       *if,ny(n1),eq,0,and,nx(n1),eq,aa,then
          PII(J)=-q2
       *elseif,ny(n1),eq,0,and,nx(n1),eq,-aa,then
          PII(J)=-q1
       *ELSE
          PII(J)=-q2-q1*cos(asin((-ny(n1))/aa))
       *ENDIF
    *ENDDO
  *ELSE
!*Neue Formel-----------------------------------------------------------
     *DO,J,1,4
        n1=NN(J)
        PII(J)=(-q1-(q2-q1)*((NX(n1)+AA)/(2*AA)))*cos(asin((-ny(n1))/aa))
     *ENDDO
*ENDIF

    !SFE, ELEM, LKEY, Lab, KVAL, VAL1, VAL2, VAL3, VAL4
     SFE,MIN_E,    2,PRES   ,0,    PII(1),PII(2),PII(3),PII(4)
     MIN_E=ELNEXT(MIN_E)
 *ENDDO

/PSF,PRES,NORM,3,0,1
/PBC,U,,1
EPLO
*ENDIF !**KRAEFTE=0

allsel
fini

/solu
solve