/PREP7
ET,1,PLANE55
ET,2,SURF19,1,,,1,1
KEYOPT,2,9,1
R,2,1.0,5.67e-8
TOFFST,273

!*************Material***********
MPTEMP,,,,,,,,
MPTEMP,1,22
MPTEMP,2,130
MPTEMP,3,200
MPTEMP,4,600
!*Wärmeleitfähigkeit 71ultra
MPDATA,KXX,1,,	0.1954
MPDATA,KXX,1,,	0.2005
MPDATA,KXX,1,,	0.19448
MPDATA,KXX,1,,	0.08099

!*spezifische Wärmekapazität
MPTEMP,,,,,,,,
MPTEMP,1,22
MPTEMP,2,100
MPTEMP,3,130
MPTEMP,4,200
MPTEMP,5,400
MPTEMP,6,600

MPDATA,C,1,,	808.1220
MPDATA,C,1,,	10000
MPDATA,C,1,,	1081.3689
MPDATA,C,1,,	1155.4407
MPDATA,C,1,,	1475.7250
MPDATA,C,1,,	1502.4137

!*Dichte
MPTEMP,,,,,,,,
MPTEMP,1,22
MPTEMP,2,200
MPDATA,DENS,1,,899.92
MPDATA,DENS,2,,884,362


!*Emission
MP,EMIS,1,0.93

MPLIST		
!*********************************STROH***************

MP,KXX,2,0.052	!*Wärmeleitfähigkeit
MP,C,2,1000	!*Spezifische Wärme
MP,DENS,2,110	!*Dichte
MP,EMIS,2,0.9	!*Emission

!***************************************GEOMETRIE*******
RECT,0,0.24,0,0.25
ESIZE,0.001
ESHAPE,.2
TYPE,1
MAT,1
REAL,1
AMESH,ALL

!**********************AUSSENRAND - SURFACE BOUNDS*****
TYPE,2
REAL,2
LSEL,S,,,4
NSLL,S,1
N,2000000,-0.01,0
ESURF,2000000
ALLS

!*********************Ändern der Kennung für Stroh****
NSEL,S,LOC,X,0.06,0.24
ESLN,S,1
ESEL,R,TYPE,,1
EMOD,ALL,TYPE,1
EMOD,ALL,MAT,2
ALLS

/PNUM,TYPE,1
/SHRINK,.2
EPLOT
/PNUM,MAT,1
EPLOT


!*************************SOLUTION
/SOLU
ANTYPE,TRANS
OUTRES,ALL,ALL

!*******************************ETK definieren***********************
*DIM,ETK, table,8,1,1,TIME	!*Tabelle mit 8 Reihen, 1 Spalte, Funktion der Zeit, 
ETK(0,1)=0.0
!
! Times
ETK(1,0)=0
ETK(2,0)=300
ETK(3,0)=600
ETK(4,0)=900
ETK(5,0)=1800
ETK(6,0)=3600
ETK(7,0)=7200
ETK(8,0)=10800

!Enter bulk temperatures at above bulk temperature times
ETK(1,1)=20
ETK(2,1)=576
ETK(3,1)=678
ETK(4,1)=739
ETK(5,1)=842
ETK(6,1)=945
ETK(7,1)=1049
ETK(8,1)=1110

!
*dim,ETKTSRES,array,8 ! numerische Abfolge dimensionieren ,8 Zeilen, 1 Spalte
ETKTSRES(1)=0
ETKTSRES(2)=300
ETKTSRES(3)=600
ETKTSRES(4)=900
ETKTSRES(5)=1800
ETKTSRES(6)=3600
ETKTSRES(7)=7200
ETKTSRES(8)=10800
!
TSRES, %ETKTSRES%

! Starttemperatur festlegen
TUNIF,22

! Convection lines definieren
! Alle Knoten der X-Koordinate bei X=0
NSEL,S,LOC,X,0
CM,AUSSEN,NODE
ALPHA=25

!Wärmeübergangsbedingungen Konvektion festlegen
SF,ALL, CONV, ALPHA,22

!Aufheben Selektion Randknoten
ALLS

!Umgebungstemperatur
D,2000000,TEMP,22


NPLOT
!Abschliessen des "mini"Zeitschritts für T=22 °C
TIMINT,OFF
TIME,1e-06
SOLVE

!********************************************************ETK als Lastschritt 2

SF,AUSSEN,CONV,ALPHA,%ETK%
D,2000000,TEMP,%ETK%
TIMINT,ON
TINTP,,,,1
LNSRCH,on
TIME,10800
DELTIM,60,,,1

KBC,0

/STATUS,SOLU
SOLVE

/POST26
NSOL,2,NODE(0.06,0.125,0),TEMP,,Grenze


/GRID,1
/AXLAB,X, Zeit [s]
/AXLAB,Y, Temperatur [°C]
PLVAR,2