/CLEAR,NOSTART
/title, Static Analysis of a Piezoelectric Mulimorph Beam
/nopr
/com
/UNITS,SI
/UIS,MSGPOP,3
/UIS,ABORT,0

!--------------- Definition of variables

vtop = -500	! Top Voltage
vbot = 0	! Bottom Voltage 0 V

!--------------- Transient Analysis data calc

pi = 3.1416
f = 100

minSteps = 20

!   - Geometry Bimorph Material
!
L_mat=100e-3                    ! Length, m
H_mat=0.5e-3                   ! One-layer thickness, m
W_mat=10e-3			! Width, m
!

support_l = 5e-3		! Define Support width for piezo
support_h = 2e-3		! Support height for Piezo

!   - Geometry PZT
!
L_pzt=L_mat-(support_l*2)      ! Length, m
H_pzt=0.5e-3                   ! One-layer thickness, m
W_pzt=10e-3			! Width, m
!


!-------------- Preprocessing
/PREP7
!
!Bimorph 1
!

block,0,L_pzt		,support_h+H_mat ,support_h+H_mat+H_pzt	,((W_mat-W_Pzt)/2) ,((W_mat-W_Pzt)/2)+W_Pzt	! PZT Layer Top
block,0,L_mat		,support_h ,support_h+H_mat		,0,W_mat					! Epoxy Layer
block,0,L_pzt		,support_h-H_pzt ,support_h		,((W_mat-W_Pzt)/2) ,((W_mat-W_Pzt)/2)+W_Pzt	! PZT Layer Bottom

allsel
cm,bimorphA,Volume

allsel


cmsel,s,bimorphA
vglue,all
cm,bimorphA,Volume

/com
/com	Pz21	Y-polarized
/com

/com	Stiffness
TB,	ANEL,	1	,	1	,	0
TBDATA,	1,	1.1419E+11	,	7.2357E+10	,	7.5740E+10
TBDATA,	7,	1.1077E+11	,	7.2357E+10
TBDATA,	12,	1.1419E+11
TBDATA,	16,	2.6291E+10
TBDATA,	19,	2.6291E+10
TBDATA,	21,	1.9227E+10

/com	Piezo matrix
TB,	PIEZ,	1
TBDATA,	2,	-2.9179
TBDATA,	5,	33.3852
TBDATA,	8,	-2.9179
TBDATA,	10,	16.1936
TBDATA,	15,	16.1936

/com	Permittivity
EMUNIT,	EPZRO,	8.85E-12
MP,	PERX,	1	,	2118
MP,	PERY,	1	,	1401
MP,	PERZ,	1	,	2118

/com	Density
MP,	DENS,	1	,	7780


/com
/com  -- Material properties for chosen middle Material (Glass Epoxy Composite)
/com
mp,ex,2,25e9				!Young modulus
mp,prxy,2,0.136				!Poisson coefficient
mp,dens,2,1900				!Density



et,1,solid227,1001  	! Hexaedral Coupled-Field Solid

et,2,solid186   	! 3-D 20-Node Structural


/com
/com  -- Mesh middle Material
/com

cmsel,s,bimorphA
vsel,r,loc,y,support_h ,support_h+H_mat
type,2
mat,2
! esize,0.5e-3
mshape,1,3d				!Volume mesh using tetrahedral shape
mshkey,0				!Mapped meshing off
vmesh,all
allsel



/com
/com  -- Mesh PZT
/com

cmsel,s,bimorphA
vsel,u,loc,y,support_h ,support_h+H_mat
type,1
mat,1
! esize,0.5e-3
mshape,1,3d				!Volume mesh using tetrahedral shape
mshkey,0				!Mapped meshing off
vmesh,all
allsel

!!! Select top PZT top electrode on Bimorph A
cmsel,s,bimorphA
eslv,r
esel,r,mat,,1
allsel,below,elem
nsel,r,loc,y,support_h+H_mat+H_pzt
cm,top_V_bimorphA,nodes
cp,1,volt,all

*get,n_A_t_V,node,,num,min


allsel,all


!!! Select top PZT bottom electrode on Bimorph A

cmsel,s,bimorphA
eslv,r
esel,r,mat,,1
allsel,below,elem
nsel,r,loc,y,support_h+H_mat
cm,top_0_bimorphA,nodes
cp,2,volt,all

*get,n_A_t_0,node,,num,min

allsel,all



!!! Select bottom PZT top electrode on Bimorph A
cmsel,s,bimorphA
eslv,r
esel,r,mat,,1
allsel,below,elem
nsel,r,loc,y,support_h
cm,bottom_0_bimorphA,nodes
cp,3,volt,all


*get,n_A_b_0,node,,num,min

allsel,all

!!! Select bottom PZT bottom electrode on Bimorph A

cmsel,s,bimorphA
eslv,r
esel,r,mat,,1
allsel,below,elem
nsel,r,loc,y,support_h-H_pzt
cm,bottom_V_bimorphA,nodes
cp,4,volt,all


*get,n_A_b_V,node,,num,min

allsel,all

!-----------------Clamp left and right end of bimorph-------------
nsel,s,loc,x,L_mat
d,all,ux,0
d,all,uy,0
d,all,uz,0

allsel,all

nsel,s,loc,x,0
nsel,r,loc,y,H_mat+H_pzt+H_pzt
*get,topNode,node,,num,max
allsel,all

!---------------Solution-------------------------------------------
START = 1e-12
END = 1/f
STEPS = 1*minSteps


/solu
anty,trans
trnopt,full                            
outres,all,all
kbc,1

*DO,i,0,STEPS 
	TIME,i*END/STEPS+START
	*if,i,eq,0,THEN
		U=0
	*else
		U=sin(2*pi*i/STEPS)
		*if,U,gt,0,THEN
			U = vtop
		*else
			U = 0
		*endif
	*endif
	
	/com
	/com  -- Voltage Constraints
	/com
	
	d,n_A_t_V,volt,U
	d,n_A_t_0,volt,vbot
	d,n_A_b_V,volt,U
	d,n_A_b_0,volt,vbot
	
	allsel,all
	solve
*enddo

!/post1
!*DO,T,1,dim*5,1
!set,next
!pldisp,2
!/IMAGE,Save,DeformedShape-%T%,jpg
!plnsol,u,y,2
!/IMAGE,Save,Deformation-Y-%T%,jpg
!plnsol,s,eqv,2
!/IMAGE,Save,EquivalentStress-%T%,jpg
!plnsol,volt,,2
!/IMAGE,Save,Voltage-%T%,jpg
!*enddo

/post26
nsol,2,topNode,volt,,,
nsol,3,topNode,u,y,,
*dim,res,array,STEPS,3
*GET,cTime,ACTIVE,0,TIME,WALL 
mTime=MOD(cTime,1) 
hTime=cTime-mTime
mTime=mTime*60
vget,res(1,1),1
vget,res(1,2),2
vget,res(1,3),3
*cfopen,bimorph-%htime%-%mtime%,dat
*vwrite,SEQU,res(1,1),res(1,2),res(1,3)
(F3.0,'  ',F12.8,'  ',F9.4,'  ',F12.8)
*cfclose

*MSG,UI,'DONE'

/EOF