fini
/clear
/FILNAME,HYDAUFWEITEN  
/PREP7

!Geometrie Eingabeparameter[mm]

dia=10					!Außendurchmesser Rohr
ti=1					!Wandstärke Rohr
gap=0.1					!Lücke zwischen Rohrplatte und Rohr

!Aufweitdruck
pi=3600					!Druck in bar

!Geometrie berechnete Radien
 
RAA=40					!Außenradius Rohrscheibe 
RAI=dia/2+gap				!Innenradius Rohrscheibe
RIA=dia/2				!Außenradius Rohr	
RII=dia/2-ti				!Innenradius Rohr

!Meshing
nU=50					!Anzahl der Unterteilungen in Umfangsrichtung
nRP=50					!Anzahl der Unterteilung in radialer Richtung, Platte
nRR=5					!Anzahl der Unterteilung in radialer Richtung, Platte

!Model POINTS Rohrscheibe

K,1,RAI,0,0,
K,2,RAA,0,0,
K,3,0,RAA,0,
K,4,0,RAI,0,

!Model POINTS Rohr

K,5,RII,0,0,
K,6,RIA,0,0,
K,7,0,RIA,0,
K,8,0,RII,0,

K,9,0,0,0,				!Mittelpunkt
				
!LINES

L,1,2
LARC,2,3,9,RAA
L,3,4
LARC,4,1,9,RAI

L,5,6
LARC,6,7,9,RIA
L,7,8
LARC,8,5,9,RII

!AREAS

AL,1,2,3,4
AL,5,6,7,8

!Element Data

et,1,plane183				!definiert Element plane183 als Element type 1
et,2,CONTA175				!definiert Element CONTA171 als Element type 2
et,3,TARGE169				!definiert Element TARGE169 als Element type 3 

!KEYOPT,2,5,1				!Close Gap
!KEYOPT,2,9,1				!Exclude gap

! Material 1

mp,ex,1,212000				!weist Material 1 E=200000 MPa    
mp,nuxy,1,0.3				!weist Material 1 v=0.3
!tb,biso,1
!tbdata,,300,0			

!Material 2

mp,ex,2,200000
mp,nuxy,2,0.3
tb,biso,2				!nicht lineare Materialeigenschaften, bilinear isotopic hardening
tbdata,,268,0				!definiert Fließgrenze und Tangentenmodul

!Real Konst. Target Element
r,10,RAI
    
!Meshing Sizing
lsel,s,,,2
lsel,a,,,4
lsel,a,,,6
lsel,a,,,8
lesiz,all,,,nU
alls

!Platte, radial
lesiz,1,,,nRP,10
lesiz,3,,,nRP,1/10

!Rohr, radial
lesiz,5,,,nRR
lesiz,7,,,nRR
 
!Meshing Area 1 und Materialübergabe

asel,s,area,,1				!selektiert Fläche 1
aatt,1,,1,				!weist der Fläche 1 die Materialeigenschaften 1 zu

CM,_Y,AREA  				!MESHING/MESH/AREAS/MAPPED/3OR4SIDE
ASEL, , , ,1 
CM,_Y1,AREA 
CHKMSH,'AREA'   
CMSEL,S,_Y  
  
MSHKEY,1
AMESH,_Y1   
MSHKEY,0
  
CMDELE,_Y   
CMDELE,_Y1  
CMDELE,_Y2 
  

alls
  

!Meshing Area 2 und Materialübergabe

asel,s,area,,2
aatt,2,,1,

CM,_Y,AREA  				!MESHING/MESH/AREAS/MAPPED/3OR4SIDE
ASEL, , , ,2 
CM,_Y1,AREA 
CHKMSH,'AREA'   
CMSEL,S,_Y  
  
MSHKEY,1
AMESH,_Y1   
MSHKEY,0
  
CMDELE,_Y   
CMDELE,_Y1  
CMDELE,_Y2 
 
alls

!Kontakt

real,10					

lsel,s,,,6				!selektiert Linie 6
nsll,,1
type,2					!CONTA Element
esurf					!erzeugt Elemente auf der Oberfläche
alls

lsel,s,,,4				!selektiert Linie 4
nsll,,1
type,3
esurf
alls


!Boundarys and Forces

DL,1,,UY,0
DL,3,,UX,0
DL,5,,UY,0
DL,7,,UX,0

SFL,8,PRES,pi*0.1             		!Druck

 
/solu

!ANTYPE,4				!transient
NLGEOM,on
NSUBST,500
kbc,0
    
  
TIME,1 
SFL,8,PRES,pi*0.1             		!Pressure  
LSWRITE,1,

Time,2
SFLDELE,8,PRES 
LSWRITE,2,