finish
/clear

!Projektdateien   versuch_1.xxx  wegen dem Geometrierückruf

!-------Magnetkreis--1-----
/PREP7  
/Title, Vorbetrachtung Magnetkreis nicht symmetrisch



!----Elementtypen------
 
ET,1,PLANE53              ! Luft 
ET,2,PLANE53              ! Blech 
ET,3,Plane53              ! Spule
ET,4,Plane53              ! Kern (Eisen) 


!----Material-------

MP,MURX,1,1               ! Permeabilität (Luft)

MP,MURX,2,2000            ! Permeability (Blechstreifen)
mp,ex,2,210e9             ! E-modul
mp,nuxy,2,0.3             ! Querkontraktionszahl
mp,dens,2,7860            ! Dichte

MP,MURX,3,1               ! Permeability (Spulen)
MP,MURX,4,1000            ! Permeability (Kern)



!----Gepmetrie-----Einstellungen-----


schleif=5             !Anzahl der gerechneten Schleifen (Rückwirkung)
stromdi=2e5            !Stromdichte



abst=30e-3               !Abstand  der Spulenanordnung zum 0 Punkt
spubr=10e-3              !Spulenbreite
Spuho=40e-3              !Spulenhöhe
kernbr=10e-3             !Kernbreite
kernho=40e-3             !Kernhöhe
luspho=1e-3              !Luftspalthöhe
blechbr=60e-3            !Blechbreite
blechho=0.9e-3           !Blechstärke

/pnum,Area,1                            !Nummerierung der Areas   
  
rectng,abst,abst+spubr,0,spuho
rectng,abst+spubr,abst+spubr+kernbr,0,kernho
rectng,abst+spubr+kernbr,abst+2*spubr+kernbr,0,spuho
rectng,abst+spubr+(kernbr-blechbr)/2,(abst+spubr+(kernbr-blechbr)/2)+blechbr,kernho+luspho,kernho+luspho+blechho
cyl4,abst+spubr+kernbr/2,kernho/2+luspho,30e-3+blechbr/2 

AOVLAP,ALL                              ! Überschneidende Areas neu aufteilen
NUMCMP,AREA                             ! Compress out unused area numbers
APLOT                                   ! neu plotten

!A1: Spule links, A3: Kern, A4:Spule rechts, A2: Blech, A5:Luft

!----mesh-----

type,2 $mat,2            !Blechstreifen
esize,blechho/2
amesh,2

type,3 $mat,3            !Spule
esize,spubr/4
amesh,1
amesh,4

type,4 $mat,4            !Kern
amesh,3

type,1 $mat,1            !restliche Luft
esize,kernbr 
amesh,5

ESEL,S,MAT,,2         ! Selection des Blech  
CM,Blech,ELEM         ! Componente Blech erstellen

FMAGBC,'BLECH'          
ALLSEL,ALL


*dim,yloc,table,(schleif+2) ! Array für die Postionsspeicherung der Durchbiegung


!n1=node(abst+spubr+kernbr/2,kernho+luspho,0)  


*get,yloc_t,node,135,loc,y    !Position des Knoten 135 (Unterseite Blech mittig) aly Scalar yloc_t speichern
yloc(1)=yloc_t                !Scalar yloc_t an Positon 1 in den array schreiben


!-----Lösung-----

/solu


!-----------Stromdichte------------

esel,s,cent,x,abst,abst+spubr     !Selektion der Elemente der linken Spule
esel,u,cent,y,-1,0
esel,u,cent,y,spuho,1

bfe,all,JS,, , ,stromdi,0         !Aufprägen der Stromdichte

allsel

esel,s,cent,x,abst+spubr+kernbr,abst+2*spubr+kernbr   !Selektion der Elmente der rechten Spule
esel,u,cent,y,-1,0
esel,u,cent,y,spuho,1

bfe,all,JS,, , ,-stromdi,0 

!------Flux Parallel an der Aussenseite-------
allsel
lsel,s,ext
nsll,s,1
d,all,az,0

allsel

solve


!----Auswertung-----
/post1
plf2d
/wait,3
plvect,fmag


!=============mechanisch===========
/prep7
ET,1,0              ! Luft 
ET,2,PLANE82,,,1    ! Blech 
ET,3,0              ! Spule
ET,4,0              ! Kern (Eisen) 


!----Randbedingungen-----
esel,s,mat,,2
nsle
nsel,r,loc,x,abst+spubr+(kernbr-blechbr)/2
d,all,ux,0
d,all,uy,0
nsle
nsel,r,loc,x,(abst+spubr+(kernbr-blechbr)/2)+blechbr
d,all,ux,0
d,all,uy,0
nsel,all

!--------------Lösung-------
/solu
esel,s,mat,,2
ldread,forc,,,,,,rmg
solve

!------Auswertung------
!/post1
!pldi,2
!/wait,1
!plns,u,y
!/wait,3


*get,yloc_t,node,135,loc,y    
yloc(2)=yloc_t                




!----Schleife für die Rückwirkung----

*do,count,1,schleif,1


!-------Magnetkreis--2-----
/PREP7  

!----Elementtypen------
 
ET,1,PLANE53              ! Luft 
ET,2,PLANE53              ! Blech 
ET,3,Plane53              ! Spule
ET,4,Plane53              ! Kern (Eisen) 
ET,5,Plane53              ! Gehäuse(Alu)

aclear,5

upgeom,,,,versuch_1,rst          !Einlesen der Blechgeometrie aus Mechanisch 1


type,1 $mat,1            !restliche Luft
esize,kernbr
amesh,5

allsel

FMAGBC,'BLECH'          
ALLSEL,ALL


!-----Lösung-----

/solu


!-----------Stromdichte------------

esel,s,cent,x,abst,abst+spubr     !Selektion der Elemente der linken Spule
esel,u,cent,y,-1,0
esel,u,cent,y,spuho,1

bfe,all,JS,, , ,stromdi,0         !Aufprägen der Stromdichte

allsel

esel,s,cent,x,abst+spubr+kernbr,abst+2*spubr+kernbr   !Selektion der Elmente der rechten Spule
esel,u,cent,y,-1,0
esel,u,cent,y,spuho,1

bfe,all,JS,, , ,-stromdi,0 

!------Flux Parallel an der Aussenseite-------
allsel
lsel,s,ext
nsll,s,1
d,all,az,0

allsel

solve


!----Auswertung-----
!/post1
!plf2d
!/wait,3
!plvect,fmag


!=============mechanisch===========
/prep7
ET,1,0              ! Luft 
ET,2,PLANE82,,,1    ! Blech 
ET,3,0              ! Spule
ET,4,0              ! Kern (Eisen) 

!----Randbedingungen-----
esel,s,mat,,2
nsle
nsel,r,loc,x,abst+spubr+(kernbr-blechbr)/2
d,all,ux,0
d,all,uy,0
nsle
nsel,r,loc,x,(abst+spubr+(kernbr-blechbr)/2)+blechbr
d,all,ux,0
d,all,uy,0
nsel,all

!--------------Lösung-------
/solu
esel,s,mat,,2
ldread,forc,,,,,,rmg     ! Einlesen der Magnetkräfte
ldread,reac,,,,,,rst     ! Einlesen der der Reaktionskräfte aus mechanischem Schritt davor
solve



*get,yloc_t,node,135,loc,y    
yloc(count+2)=yloc_t                


finish

*enddo


!------Auswertung------
/post1
pldi,2
/wait,1
plns,u,y
/wait,2

*stat,yloc   ! Anzeige der Y-Positionen für den den Knoten 135 Blechmitte