finish
/clear
/title,Platte_gekruemmt_B
/filname,Platte_gekruemmt_B

Modus=1			! 1 = Vollmodell
				! 2 = Halbmodell
				! 3 = Viertelmodell



!====================================
!   Geometrie- und Lastparameter	=
!						=
!   Einheitensystem:			=
!   mm kg ms kN GPa J K			=
!====================================
GesHoehe=24
DeckHoehe=2
Breite=500
GesLaenge=650
EinspLaenge=80
R=2000
Hebelarm=200
Kraft=10


Ri=R-GesHoehe/2+DeckHoehe
Ra=R+GesHoehe/2-DeckHoehe
PI=acos(-1)
Phi1=180*GesLaenge/(2*PI*R)
Phi2=180*(GesLaenge-2*EinspLaenge)/(2*PI*R)


*if,Modus,eq,3,then
	zPosEnd=0
	!Momenteneinleitung durch Kraeftepaar an Innen-
	!und Aussenseite der Platte
	Moment=1/4*Kraft*Hebelarm/(GesHoehe-2*DeckHoehe)
*else
	zPosEnd=Breite/2
	!Momenteneinleitung durch Kraeftepaar an Innen-
	!und Aussenseite der Platte
	Moment=1/2*Kraft*Hebelarm/(GesHoehe-2*DeckHoehe)
*endif




!====================================
!	  Elementtypen und 		=
!	  Materialparameter		=
!====================================
/prep7
et,1,solid185				!3-D Solid mit 8 Knoten
et,2,shell181

keyopt,2,1,2
keyopt,2,8,2

sectype,1,shell
secdata,DeckHoehe,1
secoffset,bot


mp,ex,1,210
mp,prxy,1,0.2

mp,ex,2,1e10
mp,prxy,2,0




!====================================
!		FE-Modell			=
!====================================
cylind,R-GesHoehe/2+DeckHoehe,R+GesHoehe/2-DeckHoehe,-Breite/2,zPosEnd,0,Phi2
*if,Modus,eq,1,then
	cylind,R-GesHoehe/2+DeckHoehe,R+GesHoehe/2-DeckHoehe,-Breite/2,zPosEnd,-Phi2,0
*endif

local,11,1
esys,11
esize,GesHoehe/3
mat,1
type,1
vmesh,all

cylind,R-GesHoehe/2+DeckHoehe,R+GesHoehe/2-DeckHoehe,-Breite/2,zPosEnd,Phi2,Phi1
*if,Modus,eq,1,then
	cylind,R-GesHoehe/2+DeckHoehe,R+GesHoehe/2-DeckHoehe,-Breite/2,zPosEnd,-Phi1,-Phi2
*endif
mat,2
vmesh,all

allsel
csys,1
asel,s,loc,x,R+GesHoehe/2-DeckHoehe,R+GesHoehe/2
nsla,s,1
mat,1
type,2
real,10
esurf

allsel
asel,s,loc,x,R-GesHoehe/2,R-GesHoehe/2+DeckHoehe
nsla,s,1
real,20
esurf

allsel
nummrg,all
numcmp,all
finish


!====================================
!		Randbedingungen		=
!====================================
/solu

allsel
nsel,s,loc,y,Phi1,2*Phi1
nsel,r,loc,x,,R-GesHoehe/2+DeckHoehe
*get,NCOUNT,node,,count
f,all,fy,-Moment/NCOUNT
d,all,ux,,,,,uz

allsel
nsel,s,loc,y,Phi1,2*Phi1
nsel,r,loc,x,R+GesHoehe/2-DeckHoehe,R+GesHoehe/2
*get,NCOUNT,node,,count
f,all,fy,Moment/NCOUNT

allsel
nsel,s,loc,y
d,all,uy

*if,Modus,ne,1,then
	allsel
	nsel,s,loc,y
	dsym,symm,y
	*if,Modus,ne,2,then
		allsel
		nsel,s,loc,z
		dsym,symm,z
		nsel,r,loc,y,Phi1,2*Phi1
		fdele,all
		nsel,r,loc,x,,R-GesHoehe/2+DeckHoehe
		f,all,fy,-Moment/(2*NCOUNT)
		nsel,s,loc,z
		nsel,r,loc,y,Phi1,2*Phi1
		nsel,r,loc,x,R+GesHoehe/2-DeckHoehe,R+GesHoehe/2
		f,all,fy,Moment/(2*NCOUNT)
	*endif
*else
	allsel
	nsel,s,loc,y,-2*Phi1,-Phi1
	nsel,r,loc,x,,R-GesHoehe/2+DeckHoehe
	*get,NCOUNT,node,,count
	f,all,fy,Moment/NCOUNT
	d,all,ux,,,,,uz

	allsel
	nsel,s,loc,y,-2*Phi1,-Phi1
	nsel,r,loc,x,R+GesHoehe/2-DeckHoehe,R+GesHoehe
	*get,NCOUNT,node,,count
	f,all,fy,-Moment/NCOUNT
*endif


!====================================
!	  Analyse-Einstellungen		=
!====================================
antype,static
time,10
nsubst,1
outres,all,all

allsel
save,Platte_gekruemmt_B,db

solve
finish



!====================================
!	  Ergebnis-Auswertung		=
!====================================
/post1
set,last
rsys,11

!Ergebnisbetrachtungen am Vollmodell
*if,Modus,eq,2,then
/expand,2,polar,half
*elseif,Modus,eq,3,then
/expand,2,rect,half,,,1e-10,2,polar,half
*endif
/replot
!anschliessend plnsol,plesol,...

allsel
esel,s,real,,10
DATEINAME='y_Aussen'
*use,Auswertg1
DATEINAME='z_Aussen'
*use,Auswertg2

allsel
esel,r,real,,20
DATEINAME='y_Innen'
*use,Auswertg1
DATEINAME='z_Innen'
*use,Auswertg2