finish
/clear,read

/filname, Hausarbeit_Aufgabe_1_a        ! Dateiname
/title, Hausarbeit_Aufgabe_1_a          ! Beschriftung für das Grafikfenster

!----------------------------------------------------------------------------------------
! Aufruf des Preprocessors PREP 7
!----------------------------------------------------------------------------------------

/PREP7

!----------------------------------------------------------
! Parameter definieren
!----------------------------------------------------------

l = 7500			! Systemlänge [mm]

h = 500				! IPE 500 [mm]
b = 200
s = 10.2
t = 16.0

n = 100				! element size			

x = 7500			! Länge des Systems

h1 = (h-t)/2
b1 = b/2


!----------------------------------------------------------
! Elementtyp, Material und Querschnitt definieren
!----------------------------------------------------------

et,1,181			!Elementtyp 
mp,ex,1,210000			!E-Modul
mp,nuxy,1,0.3			!Querkontraktionszahl

r,1,t				!Real-Konstanten mit Nummer und Dicke (als Variable s oder t)
r,2,s

!----------------------------------------------------------
! Keypoints
!----------------------------------------------------------

k,1,-b1,-h1,0			!k,"Nr","x","y","z"
k,2,  0,-h1,0
k,3, b1,-h1,0
k,4,  0,  0,0
k,5,-b1, h1,0
k,6,  0, h1,0
k,7, b1, h1,0

kgen,2,1,7,,,,-l,,0		!Generates keypoints from a pattern of keypoints
				!kgen,itime,np1,np2,ninc,dx,dy,dz

!----------------------------------------------------------
! Flächen
!----------------------------------------------------------

a,1,2,9,8			!Fläche durch Verbindung der Punkte
a,2,3,10,9			!vier Flanschflächen, zwei Stegflächen
a,2,9,11,4
a,13,6,4,11
a,5,6,13,12
a,6,7,14,13


!----------------------------------------------------------
! Vernetzung
!----------------------------------------------------------

esize,n				!Netzgröße

asel,s,area,,3			!Stegflächen werden ausgewählt
asel,a,area,,4

type,1				!Festlegung von Elementtypnummer, 
real,2				!Real-Konstantennummer und Material- 
mat,1				!nummer für die folgenden Vernetzungen

amesh,all			!Die Stegfläche wird vernetzt


asel,s,area,,1			!Flanschflächen werden ausgewählt
asel,a,area,,2
asel,a,area,,5
asel,a,area,,6

type,1				!s.o.
real,1
mat,1

amesh,all			!s.o.


!----------------------------------------------------------------------------------------
! Solution
!----------------------------------------------------------------------------------------

/solu

!----------------------------------------------------------
! Auflager
!----------------------------------------------------------

allsel 				!Gesamte Datenbasis wird ausgewählt

nsel,s,loc,z,0			!Selektion einer Gruppe von Knoten aus den aktivierten Daten
nsel,r,loc,x,0			!z,(0): Auswahl aller Knoten mit z=0			
	 			!r:Selektion der Teilmenge x=0

d,all,ux			!Festlegung von Knotenverschiebungen
d,all,uz			!all=Alle selektierten Knoten
				!ux, uz Verschiebung in x-/z-Richtung

nsel,r,loc,y,0			!r:Selektion der Teilmenge y=0

d,all,uy			!Festlegung von Knotenverschiebungen/-verdrehungen			
d,all,roty			!all=Alle selektierten Knoten
				!uy Verschiebung in y-Richtung
				!roty Verdrehung um y-Achse


!----------------------------------------------------------
! Last
!----------------------------------------------------------

allsel				!Gesamte Datenbasis wird ausgewählt

nsel,s,loc,x,0			!Selektion eine Gruppe von Knoten aus den aktivierten Daten
nsel,r,loc,y,h1			!x,(0): Auswahl aller Knoten mit x=0
				!r:Selektion der Teilmenge y=h1

*get,anzahl,node,,count		!create parameter 'anzahl'

nsel,r,loc,z,-0.1,-l+0.1	!

f,all,fy,-x/(anzahl-1)



				!Danach die beiden äußeren Knoten selektieren
				!und die halbe Last aufbringen.
				
allsel				

nsel,s,loc,z,0
nsel,r,loc,y,h1
nsel,r,loc,x,0
f,all,fy,0.5*(-x/(anzahl-1))	!Halbe Kraft am Anfang


allsel

nsel,s,loc,x,0
nsel,r,loc,y,h1
nsel,r,loc,z,-l
f,all,fy,0.5*(-x/(anzahl-1))	!Halbe Kraft am Ende

!----------------------------------------------------------
! Statische Lösung
!----------------------------------------------------------

/solu				!Enter the solution mode

allsel
antype,static			!antype steht für Type of analysis, static analysis (not buckling)
pstres,on			!Analysis Options: pstres,...

solve
save
finish


!----------------------------------------------------------
! Eigenwertproblem
!----------------------------------------------------------

/solu
antype,1
bucopt,subsp,2,0,0
solve

!----------------------------------------------------------------------------------------
! Postprozessor
!----------------------------------------------------------------------------------------
/post1
set,first
pldisp,0

fini				!Ende der Arbeiten im Lösungsprozessor

/eof				!Beendet und löscht alle vorherigen Befehle