!Zylinderspule
finish
/clear
/prep7
!___________________________________________________________________Elementtypen
et,1,solid87          !Luft  
et,2,solid69          !Spule
!__________________________________________________________Materialeigenschaften
mp,kxx,1,0.2          ! Luft
mp,kxx,2,400          ! Spule
mp,rsvx,2,1/56e6

!_____________________________________________________________Geometrieparameter
pi = 3.14159265
!_____Zylinder
r_in = 0.09             !Innenradius 
r_au = 0.1              !Außenradius
h = 0.3                 !Zylinderhöhe
!_____Spulenwerte
draht = (r_in+r_au/2)*2*pi   !Drahtlänge   (D*PI)
area = h*(r_au-r_in)         !Querschnittsfläche  
spez = 1.78e-8               !Spezifischer Widerstand Kupfer
Wied = spez*draht/area       !Spulenwiderstand
strom = 10e8*((r_au-r_in)*h) !Spulenstrom  
Span = Wied*strom            !Spannung
!_____Luft
Breite = 0.4             !Luftblock-Breite
Tiefe = Breite
Hoehe = Breite
!____________________________________________________________Geometrieerstellung
!_____Zylinder
cylind,r_in,r_au,h/2,-h/2,-90,90
cylind,r_in,r_au,h/2,-h/2,90,270
vadd,all

block,0,r_au*2,1e-3,-1e-3,h/2,-h/2
vovlap,all
numcmp,all
vsel,u,,,4
vdele,all
allsel
aslv
asel,inve
adele,all
allsel
numcmp,all              !Lücke herausschneiden und Überflüssiges entfernen
!_____Luftblock
block,Breite/2,-Breite/2,Hoehe/2,-Hoehe/2,Tiefe/2,-Tiefe/2        
vovlap,all            
numcmp,all
!/eof         
!_____________________________________________________________________Vernetzung
!_____Zylinderspule
esize,0.01
mshape,1,3D
mshkey,0
type,2
mat,2
vmesh,1
!_____Luftblock
type,1    
mat,1
mshkey,0
mshape,1,3d
esize,0.05
vmesh,2
!/eof
!_________________________________________________________________________Lasten
da,5,volt,0
da,6,volt,Span             !Anlegen von Spannung an Schnittflächen
!________________________________________________________________________Loesung
allsel
/solu
solve
/eof