!Zylinderspule
finish
/clear
/prep7
!___________________________________________________________________Elementtypen
et,1,solid87          !Luft  
et,2,solid87          !Spule
!__________________________________________________________Materialeigenschaften
mp,kxx,1,0.2          ! Luft
mp,kxx,2,400          ! Spule
!_____________________________________________________________Geometrieparameter
pi = 3.14159265
!_____Zylinder
r_in = 0.09             !Innenradius 
r_au = 0.1              !Auáenradius
h = 0.3                 !Zylinderhöhe
!_____Luft
Breite = 0.4             !Luftblock-Breite
Tiefe = Breite
Hoehe = Breite
!____________________________________________________________Geometrieerstellung
!_____Zylinder
cylind,r_in,r_au,h/2,-h/2,-90,90
cylind,r_in,r_au,h/2,-h/2,90,270
vadd,all

!_____Luftblock
block,Breite/2,-Breite/2,Hoehe/2,-Hoehe/2,Tiefe/2,-Tiefe/2        
vovlap,all            
numcmp,all
!/eof         
!_____________________________________________________________________Vernetzung
!_____Zylinderspule
esize,0.01
mshape,1,3D
mshkey,0
type,2
mat,2
vmesh,2
!_____Luftblock
type,1
mat,1
mshkey,0
mshape,1,3d
esize,0.05
vmesh,1
!/eof
!_________________________________________________________________________Lasten
esel,s,type,,2
bfe,all,hgen,,1e+6 !Testwert, bei richtiger Simulation aus vorhergehender Simulation bestimmt.

asel,s,ext
da,all,temp,18
!________________________________________________________________________Loesung
allsel
/solu
solve
/eof