!Zylinderspule
finish
/clear
/prep7
!___________________________________________________________________Elementtypen
et,1,solid70          !Luft  
et,2,solid70          !Spule
!__________________________________________________________Materialeigenschaften
mp,kxx,1,0.2          ! Luft
mp,kxx,2,400          ! Spule

!_____________________________________________________________Geometrieparameter
pi = 3.14159265
!_____Zylinder
r_in = 0.09e-3             !Innenradius 
r_au = 0.1e-3              !Auáenradius
h = 0.3e-3                 !Zylinderhöhe
schicht = (r_au-r_in)/20
!/eof
!_____Luft
Breite = 0.4e-3             !Luftblock-Breite
Tiefe = Breite
Hoehe = Breite
!____________________________________________________________Geometrieerstellung
!_____Zylinder
*do,temp,0,19,1
cylind,r_in+temp*schicht,r_in+temp*schicht+schicht,h/2,-h/2,-90,0
cylind,r_in+temp*schicht,r_in+temp*schicht+schicht,h/2,-h/2,0,90
cylind,r_in+temp*schicht,r_in+temp*schicht+schicht,h/2,-h/2,90,180
cylind,r_in+temp*schicht,r_in+temp*schicht+schicht,h/2,-h/2,180,270
*enddo
vglue,all
numcmp,all         
!_____________________________________________________________________Vernetzung
!_____Zylinderspule
esize,5e-6
mshape,0,3D
mshkey,1
type,2
mat,2
vmesh,1,80
!_________________________________________________________________________Lasten
allsel
!LDREAD, Lab, LSTEP, SBSTEP, TIME, KIMG, Fname, Ext, --
ldread,hgen ,      ,       ,     ,     ,RESULT,RST !Name der Result-Datei
allsel

nsel,s,ext
sf,all,conv,8,20
allsel
!________________________________________________________________________Loesung
allsel
/solu
solve
/eof