!Einfacher Magnetkopf 2D 
!120716
!Robin Grantz

finish
/clear
/prep7
!___________________________________________________________________Elementtypen
et,1,plane53
et,2,plane53
et,3,plane53
!__________________________________________________________Materialeigenschaften
!_____Stahl
mp,murx,1,5000
!_____Isolation
mp,murx,2,1
!_____Spule
mp,murx,3,1
mp,rsvx,3,1/56e6
!_____________________________________________________________Geometrieparameter                     
!_____Stahlkern (ST: Stahlkern; B: Breite; H: Höhe)
STB_konz = 52.5e-3                          !Stahlkern Breite des Konzentrators
STB_fuss = 200e-3                           !Stahlkern Fussbreite
STB_bein = 100e-3                           !Stahlkern Beinbreite
STB_seite = STB_fuss + STB_bein + STB_konz  !Stahlkern Breite einer Seite
STB_luftspalt = 10e-3                       !Stahlkern Breite des Luftspalts      
STB_gesamt = 2*STB_seite + STB_luftspalt    !Stahlkern Gesamtbreite
STB_mitte = 2*STB_fuss + 2*STB_konz + STB_luftspalt      !Stahlkern Breite zwischen Beinen
STH_fuss = 50e-3                            !Stahlkern Fusshöhe
STH_bein = STH_fuss + 200e-3                !Stahlkern Beinhöhe
STH_kopf = STH_bein + 100e-3                !Stahlkern Kopfhöhe
!_____Spule
Srad = 1e-3                                 !Spulenradius
SAbs_x = 0.5e-3                             !Abstand zwischen Wicklungen
SAbs_x2 = 10e-3                             !Abstand zum Kern
SWind = Nint((STB_mitte - SAbs_x2*2)/(Srad + SAbs_x))     !Anzahl der Windungen
SAbs_y = 10e-3      !Spulenabstand zum Kern
Strom= 1*6e6*Srad*Srad                      !Stromstärke
stromdichte = 6e6                                                    
!_____Isolation
luft = STB_gesamt*1.5                       !Größe der Umgebende Isolation

!____________________________________________________________Geometrieerstellung
!_____Stahlkern
rectng,STB_luftspalt/2,STB_luftspalt/2 + STB_konz + STB_fuss,0,STH_fuss
rectng,STB_gesamt/2,STB_gesamt/2-STB_bein,,STH_bein
rectng,STB_gesamt/2,0,STH_bein,STH_kopf
arsym,x,all
aadd,all
!_____Spule
Wicklung_startx = STB_gesamt/2 - STB_bein - SAbs_x2
Wicklung_starty = STH_kopf + SAbs_y
*do,temp,0,SWind,1
rectng,Wicklung_startx - temp*(Srad + SAbs_x), Wicklung_startx - Srad - temp*(Srad + SAbs_x),Wicklung_starty,Wicklung_starty + Srad
*enddo

Wicklung_starty = STH_bein - SAbs_y - Srad
*do,temp,0,SWind,1
rectng,Wicklung_startx - temp*(Srad + SAbs_x), Wicklung_startx - Srad - temp*(Srad + SAbs_x),Wicklung_starty,Wicklung_starty + Srad
*enddo

!_____Luft
wplane,,,STH_fuss + (STH_bein-STH_fuss)/2
rectng,luft/2,-luft/2,luft/2,-luft/2
allsel            
aovlap,all            
numcmp,all         
wplane,,0,0,0
allsel
!/eof
!_____________________________________________________________________Vernetzung
!_____Wicklungen
type,3
mat,3
esize,0.5e-3
amesh,1,6
amesh,8,663
!/eof
!_____Stahlkern
type,1    
mat,1
esize,10e-3
amesh,7
!/eof
!_____Luftblock
type,2
mat,2
esize,50e-3
amesh,664
!/eof
!_______________________________________________________________________Kopplung
asel,,,,1,6
asel,a,,,8,332
esla
bfe,all,js,1,,,-stromdichte

asel,,,,333,663
esla
bfe,all,js,1,,,stromdichte
allsel
!/eof
lsel,s,ext
dl,all,,az,0
!/eof
!_________________________________________________________________________Lösung
/solu				
solve
/eof

!__________________________________________________________________________________________________________________________________________________________________________________________________