!--- Kommentare ---

! Erst Geometrie erzeugen
! dann Temperaturen berechen
! danach Struktur berechnen

! Hier wird die Temperatur berechnet


! 27.11.06

!--- Anfang ---

! -- Neustart
FINISH  
/CLEAR,START

! Datei- und Jobnamen definieren
/FILENAME,thermo-V13,1

! Schriftgrösse anpassen
/dev,font,1,Courier*New,400,0,-16,0,0,,,
/dev,font,2,Courier*New,400,0,-16,0,0,,,

! Dateinamen einblenden
/PLOPTS,FILE,1  


! Preprozessor starten
/PREP7


! - Veränderliche Werte angeben

! Anfangsgeschwindigkeit in km/h
va=200

! Endgeschwindigkeit in km/h
ve=10

! - Starttemperatur in Grad Celsius
Ts=200

! Radlast in kg
rl=382

! Anfangskonvektion in W/(m**2*K)
akonv=100

! Endkonvektion in W/(m**2*K)
ekonv=50

! Bremsscheibengesamtfläche in m**2
bf=0.0681

! Bremsabstand in Sekunden
brab=15

! Bremszeit in Sekunden
tb=9.3

! Abkühlzeit in Sekunden
ta=300

! Genauigkeit, Anzahl der berechneten Ergebnisse je Bremsung
! (zwischen 3 bis 9)
s=3


! - Erste Berechnungen

! Durchschnittliche Verzögerung in m/s**2
verzög=(va-ve)/3.6/tb

! Umgesetzte Energie in Kilojoule
eu=0.5*rl*((va/3.6)**2-(ve/3.6)**2)/1000

! Zeit des ersten Loadstep
tel=tb/s

! Anfangs-Wärmestromdichte in Watt/m**2 für ersten Loadstep
awsd=rl*(va/3.6-verzög*(tel/2))*verzög/bf

! End-Wärmestromdichte in Watt/m**2
ewsd=rl*(va/3.6-verzög*(tb-tel/2))*verzög/bf



! Einheiten setzen
/UNITS,SI

! Geometrie laden
CDREAD,COMB,geometrie-G6,cdb,,,

! Zyklische Symmetrie wird hier nicht gebraucht
CYCLIC,OFF

! Elementtyp nach Thermal wechseln
ETCHG,STT

! Materialeigenschaften
MP,EX,1,1.2E11
MP,DENS,1,7100
MP,ALPX,1,11e-6
MP,KXX,1,37
MP,C,1,600



! -- Solutionumgebung starten
/SOLU

! - Transient Analysis festlegen
ANTYPE,4

! - Transient Analysis Optionen festlegen
TRNOPT,FULL,

! - Einheitliche Starttemperatur
TUNIF,273+Ts

! - Laufzeit t beginnt mit 0
t=0



! -- Beginn der Schleife i

! - Schleife i erzeugt die Loadstep-Files für 
!   zwei Bremsungen hintereinander
!   und läuft von 1 bis 2
*do,i,1,2



! -- Loadstep 1 bzw. 4 
!    Anfang des Bremsens und grosse Konvektion

! - Anfangskonvektion aufbringen

! Flächen auswählen
ASEL,S,,,8 ! Topffläche aussen
ASEL,A,,,9
ASEL,A,,,10
ASEL,A,,,105
ASEL,A,,,27
ASEL,A,,,38
ASEL,A,,,55
ASEL,A,,,64
ASEL,A,,,71

ASEL,A,,,6 ! Reibfläche aussen oben
ASEL,A,,,88
ASEL,A,,,75
ASEL,A,,,89
ASEL,A,,,32
ASEL,A,,,95
ASEL,A,,,77
ASEL,A,,,90
ASEL,A,,,52
ASEL,A,,,96
ASEL,A,,,87
ASEL,A,,,91
ASEL,A,,,60
ASEL,A,,,102
ASEL,A,,,97
ASEL,A,,,92
ASEL,A,,,67
ASEL,A,,,104
ASEL,A,,,99
ASEL,A,,,93

ASEL,A,,,40 ! Reibfläche innen oben
ASEL,A,,,145
ASEL,A,,,134
ASEL,A,,,59
ASEL,A,,,147
ASEL,A,,,136
ASEL,A,,,72
ASEL,A,,,149
ASEL,A,,,138
ASEL,A,,,109
ASEL,A,,,151
ASEL,A,,,140
ASEL,A,,,127
ASEL,A,,,154
ASEL,A,,,143

ASEL,A,,,133 ! Reibfläche innen unten
ASEL,A,,,144
ASEL,A,,,34
ASEL,A,,,135
ASEL,A,,,146
ASEL,A,,,57
ASEL,A,,,137
ASEL,A,,,148
ASEL,A,,,66
ASEL,A,,,139
ASEL,A,,,150
ASEL,A,,,107
ASEL,A,,,142
ASEL,A,,,153
ASEL,A,,,122

ASEL,A,,,24 ! Topf unten
ASEL,A,,,23
ASEL,A,,,21

ASEL,A,,,36 ! Innenfläche
ASEL,A,,,86
ASEL,A,,,82
ASEL,A,,,84
ASEL,A,,,76
ASEL,A,,,85
ASEL,A,,,83
ASEL,A,,,118
ASEL,A,,,110
ASEL,A,,,120
ASEL,A,,,117
ASEL,A,,,37
ASEL,A,,,119

ASEL,A,,,13 ! Stegfläche
ASEL,A,,,12
ASEL,A,,,44
ASEL,A,,,26
ASEL,A,,,80
ASEL,A,,,4
ASEL,A,,,42
ASEL,A,,,115
ASEL,A,,,81
ASEL,A,,,41
ASEL,A,,,50
ASEL,A,,,116
ASEL,A,,,17
ASEL,A,,,16
ASEL,A,,,45
ASEL,A,,,35
ASEL,A,,,78
ASEL,A,,,46
ASEL,A,,,51
ASEL,A,,,114
ASEL,A,,,79
ASEL,A,,,15
ASEL,A,,,43
ASEL,A,,,113
APLOT

! Knoten dazu auswählen
NSLA,S,1
NPLOT

! Anfangskonvektion auf Knoten bringen
SF,ALL,CONV,akonv,293
 
! -- Alles auswählen
ALLSEL,ALL

! - Anfangs-Wärmestromdichte
! auf Bremsfläche aufbringen

! Flächen auswählen
ASEL,s,,,25 ! Reibfläche aussen
ASEL,A,,,33
ASEL,A,,,54
ASEL,A,,,61
ASEL,A,,,68

ASEL,A,,,31 ! Reibfläche innen
ASEL,A,,,56
ASEL,A,,,65
ASEL,A,,,101
ASEL,A,,,112
APLOT

! Knoten dazu auswählen
NSLA,S,1
NPLOT

! Alte Last entfernen
SFDELE,ALL,ALL

! Anfangs-Wärmestromdichte awsd
! auf die Knoten bringen
SF,ALL,HFLUX,awsd

! -- Alles auswählen
ALLSEL,ALL

! - Zeitschritte festlegen

! Laufzeit t setzen
! Loadstep 1 und 2 haben zusammen die Länge tb
! Loadstep 1 hat davon die Länge tb*(1/s)
t=t+tb*(1/s)

! Zeit t für die Berechnung definieren
TIME,t

! automatic time stepping aus
AUTOTS,OFF

! Keine Substeps
NSUBST,0,

! Specifies stepped loading
KBC,1

! - Output mit allen Daten
OUTRES,ALL,ALL,

! Titel
/TITLE,Bremsen Nr.%i%

! - Loadstep-File mit der Nummer i1 schreiben
! "i1" steht für erster Loadstep in Bremsung Nr.i
LSWRITE,%i%1

! -- Loadstep 1 bzw. 4 Ende





! -- Loadstep 2 bzw. 5 
!    Bremsvorgang mit
!    abfallender Last (ramped loading) in s-1 Schritten 
!    bis auf die End-Wärmestromdichte

! -  Endkonvektion aufbringen

! Flächen auswählen
ASEL,S,,,8 ! Topffläche aussen
ASEL,A,,,9
ASEL,A,,,10
ASEL,A,,,105
ASEL,A,,,27
ASEL,A,,,38
ASEL,A,,,55
ASEL,A,,,64
ASEL,A,,,71

ASEL,A,,,6 ! Reibfläche aussen oben
ASEL,A,,,88
ASEL,A,,,75
ASEL,A,,,89
ASEL,A,,,32
ASEL,A,,,95
ASEL,A,,,77
ASEL,A,,,90
ASEL,A,,,52
ASEL,A,,,96
ASEL,A,,,87
ASEL,A,,,91
ASEL,A,,,60
ASEL,A,,,102
ASEL,A,,,97
ASEL,A,,,92
ASEL,A,,,67
ASEL,A,,,104
ASEL,A,,,99
ASEL,A,,,93

ASEL,A,,,40 ! Reibfläche innen oben
ASEL,A,,,145
ASEL,A,,,134
ASEL,A,,,59
ASEL,A,,,147
ASEL,A,,,136
ASEL,A,,,72
ASEL,A,,,149
ASEL,A,,,138
ASEL,A,,,109
ASEL,A,,,151
ASEL,A,,,140
ASEL,A,,,127
ASEL,A,,,154
ASEL,A,,,143

ASEL,A,,,133 ! Reibfläche innen unten
ASEL,A,,,144
ASEL,A,,,34
ASEL,A,,,135
ASEL,A,,,146
ASEL,A,,,57
ASEL,A,,,137
ASEL,A,,,148
ASEL,A,,,66
ASEL,A,,,139
ASEL,A,,,150
ASEL,A,,,107
ASEL,A,,,142
ASEL,A,,,153
ASEL,A,,,122

ASEL,A,,,24 ! Topf unten
ASEL,A,,,23
ASEL,A,,,21

ASEL,A,,,36 ! Innenfläche
ASEL,A,,,86
ASEL,A,,,82
ASEL,A,,,84
ASEL,A,,,76
ASEL,A,,,85
ASEL,A,,,83
ASEL,A,,,118
ASEL,A,,,110
ASEL,A,,,120
ASEL,A,,,117
ASEL,A,,,37
ASEL,A,,,119

ASEL,A,,,13 ! Stegfläche
ASEL,A,,,12
ASEL,A,,,44
ASEL,A,,,26
ASEL,A,,,80
ASEL,A,,,4
ASEL,A,,,42
ASEL,A,,,115
ASEL,A,,,81
ASEL,A,,,41
ASEL,A,,,50
ASEL,A,,,116
ASEL,A,,,17
ASEL,A,,,16
ASEL,A,,,45
ASEL,A,,,35
ASEL,A,,,78
ASEL,A,,,46
ASEL,A,,,51
ASEL,A,,,114
ASEL,A,,,79
ASEL,A,,,15
ASEL,A,,,43
ASEL,A,,,113
APLOT

! Knoten dazu auswählen
NSLA,S,1
NPLOT

! Endkonvektion ekonv auf Knoten bringen
SF,ALL,CONV,ekonv,293
 
! -- Alles auswählen
ALLSEL,ALL

! - End-Wärmestromdichte auf Bremsfläche aufbringen

! Flächen auswählen
ASEL,s,,,25 ! Reibfläche aussen
ASEL,A,,,33
ASEL,A,,,54
ASEL,A,,,61
ASEL,A,,,68

ASEL,A,,,31 ! Reibfläche innen
ASEL,A,,,56
ASEL,A,,,65
ASEL,A,,,101
ASEL,A,,,112
APLOT

! Knoten dazu auswählen
NSLA,S,1
NPLOT

! Alten Last entfernen
SFDELE,ALL,ALL

! End-Wärmestromdichte ewsd auf Knoten bringen
SF,ALL,HFLUX,ewsd

! -- Alles auswählen
ALLSEL,ALL

! - Zeitschritte festlegen

! Laufzeit t setzen
! Loadstep 1 und 2 haben zusammen die Länge tb
! Loadstep 2 hat davon die Länge tb*(1-1/s)
t=t+tb*(1-1/s)

! Zeit t für die Berechnung definieren
TIME,t

! automatic time stepping aus
AUTOTS,OFF

! Anzahl der Substeps definieren
! Loadstep 1 und 2 unterteilen den Bremsvorgang
! in s Teilschritte, damit bleiben für Loadstep 2
! nur noch s-1 Teilschritte übrig
NSUBST,s-1,

! Specifies ramped loading
KBC,0

! - Output mit allen Daten und allen Substeps
OUTRES,ALL,ALL,

! Titel
/TITLE,Bremsen Nr.%i%

! - Loadstep-File mit der Nummer i2 schreiben
! "i2" steht für zweiter Loadstep in Bremsung Nr.i
LSWRITE,%i%2

! -- Loadstep 2 bzw. 5 Ende





! -- Loadstep 3 bzw. 6 (keine Last)
!    mit Bremsabstand oder Abkühlzeit

! - Endkonvektion auf Bremsfläche aufbringen

! Flächen auswählen
ASEL,s,,,25 ! Reibfläche aussen
ASEL,A,,,33
ASEL,A,,,54
ASEL,A,,,61
ASEL,A,,,68

ASEL,A,,,31 ! Reibfläche innen
ASEL,A,,,56
ASEL,A,,,65
ASEL,A,,,101
ASEL,A,,,112
APLOT

! Knoten dazu auswählen
NSLA,S,1
NPLOT

! Alten Wärmestrom entfernen
SFDELE,ALL,ALL

! Endkonvektion ekonv auf Knoten bringen
SF,ALL,CONV,ekonv,293

! -- Alles auswählen
ALLSEL,ALL

! - Zeitschritte festlegen

! Wenn i=1
*if,i,eq,1,then

! dann Laufzeit t um Bremsabstand brab erhöhen
t=t+brab

! sonst
*else

! Laufzeit t um die Abkühlzeit ta erhöhen
t=t+ta

! Schluss mit if
*endif

! Zeit t für die Berechnung definieren
TIME,t

! automatic time stepping aus
AUTOTS,OFF

! Anzahl s der Substeps
NSUBST,s,

! Specifies stepped loading
KBC,1

! - Output mit allen Daten und allen Substeps
OUTRES,ALL,ALL,

! Titel
/TITLE,Abkuehlen Nr.%i%

! - Loadstep-File mit der Nummer i3 schreiben
! "i3" steht für dritter Loadstep in Bremsung Nr.i (Abkühlvorgang Nr.i)
LSWRITE,%i%3

! -- Loadstep 3 bzw. 6 Ende



! -- Ende der Loadstep-Schleife i
*ENDDO



! -- Jetzt können die Loadstep-Files überprüft werden




! --- Berechnung beginnen

! - Schleife i berechnet zwei Bremsungen hintereinander
!   auf der Basis der Loadstep-Files
!   und läuft von 1 bis 2
*do,i,1,2

! -- Loadstep 1 bzw. 4 berechnen

! - Alten Loads entfernen
SFDELE,ALL,ALL

! - Erstes Loadstep-File i1 einlesen
LSREAD,%i%1
NPLOT

! - Step Lösen
SOLVE

! -- Loadstep 2 bzw. 5 berechnen

! - Zweites Loadstep-File i2 einlesen
LSREAD,%i%2
NPLOT

! - Step Lösen
SOLVE

! -- Loadstep 3  bzw. 6 berechnen

! - Alten Loads entfernen
SFDELE,ALL,ALL

! - Drittes Loadstep-File i3 einlesen
LSREAD,%i%3
NPLOT

! - Step Lösen
SOLVE

! -- Ende der Berechnungs-Schleife i
*ENDDO

! --- Berechnung Ende




! -- Postprocessor
/POST1

! Zylindrisches Koordinatensystem
RSYS,1

! Letzen Set einlesen
SET,LAST

! Knotentemperaturen plotten
PLNSOL,TEMP,,0

! -- Alles speichern
SAVE,