!--- Kommentare ---


! Erst Geometrie erzeugen
! dann Temperaturen berechen
! danach Struktur berechnen

! Hier wird die Struktur berechnet


! 27.11.06


!--- Anfang ---

! -- Neustart
FINISH  
/CLEAR,START

! Datei- und Jobnamen definieren
/FILENAME,struc-V13,1

! Schriftgrösse anpassen
/dev,font,1,Courier*New,400,0,-16,0,0,,,
/dev,font,2,Courier*New,400,0,-16,0,0,,,

! Dateinamen einblenden
/PLOPTS,FILE,1  


! Preprozessor starten
/PREP7

! - Veränderliche Werte angeben (müssen mit thermo-file übereinstimmen!)

! Bremsabstand in Sekunden
brab=15

! Bremszeit in Sekunden
tb=9.3

! Abkühlzeit in Sekunden
ta=300

! Genauigkeit, Anzahl der berechneten Ergebnisse je Bremsung
! (zwischen 3 bis 9)
s=3


! Einheiten setzen
/UNITS,SI


! Geometrie laden
CDREAD,COMB,geometrie-G6,cdb,,,

! Hier kann die zyklische Symmetrie testweise abgeschaltet werden
! Dann aber auch unten im Postprocessor /CYCEXPAND abschalten
!CYCLIC,OFF


! -- Solutionumgebung starten
/SOLU

! - Static Analysis festlegen
ANTYPE,STATIC

! Referenztemperatur
TREF,293

! Zylindrisches Koordinatensystem
CSYS,1


! -- Konstante Randbedingungen definieren

! - Fixieren am Anschraubbereich

! Flächen auswählen
ASEL,S,,,18
APLOT

! Knoten dazu auswählen
NSLA,S,1
NPLOT

! Sektor-Knoten abwählen
lsel,s,,,10
lsel,a,,,74
nsll,u,1

! DoFs (UX,UY,UZ) begrenzen
D,ALL,ALL,0,
 
! -- Alles auswählen
ALLSEL,ALL
EPLOT


! - Laufzeit beginnt mit 0
t=0



! -- Beginn der Schleife i

! - Thermoloadstepzähler beginnt mit 0
ThLstZ=0

! - Schleife i erzeugt die Loadstep-Files für 
!   zwei Bremsungen hintereinander
!   und läuft von 1 bis 2
*do,i,1,2


! -- Loadstep 1 bzw. 4 
!    Anfang des Bremsens

! - Thermoloadstepzähler um 1 erhöhen
ThLstZ=ThLstZ+1

! - Temperaturergebnisse entsprechend
!   Thermoloadstepzähler ThLstZ laden
LDREAD,TEMP,ThLstZ,,,,thermo-V13,RTH

! - Zeitschritte festlegen

! Laufzeit t setzen
! Loadstep 1 hat die Länge tb*(1/s)
t=t+tb*(1/s)

! Zeit t für die Berechnung definieren
TIME,t

! automatic time stepping aus
AUTOTS,OFF

! Keine Substeps
NSUBST,0,

! Specifies stepped loading
KBC,1

! - Output mit allen Daten
OUTRES,ALL,ALL,

! Titel
/TITLE,Bremsen Nr.%i%

! - Loadstep-File mit der Nummer i11 schreiben
! "i11" steht für Bremsung Nr.i, erster Loadstep, erster Substep
LSWRITE,%i%11


! -- Loadstep 1 bzw. 4 Ende



! -- Loadstep 2 bzw. 5
!    (restlicher Bremsvorgang)

! - Thermoloadstepzähler um 1 erhöhen
ThLstZ=ThLstZ+1

! - Schleife j liest den 2. Thermostep mit
!   seinen s-1 Substeps aus
!   Schleife j wird von 1 bis s-1 durchlaufen
*do,j,1,s-1

! - Temperaturergebnisse vom 
! Loadstep ThLstZ und Substep j laden
LDREAD,TEMP,ThLstZ,j,,,thermo-V13,RTH

! -- Zeitschritte festlegen

! - Laufzeit t berechnen
!   Laufzeit wird um die Länge eines Substeps erhöht
t=t+tb*(1/s)

! Zeit t für die Berechnung definieren
TIME,t

! time stepping deaktiviert
AUTOTS,OFF

! Keine Substeps
NSUBST,1

! Specifies stepped loading
KBC,1

! - Output mit allen Daten und allen Substeps
OUTRES,ALL,ALL,

! Titel
/TITLE,Bremsen Nr.%i%

! - Loadstep-File mit der Nummer i2j schreiben
! "i2j" steht für Bremsung Nr.i, zweiter Loadstep, Substep j
LSWRITE,%i%2%j%

! -- Ende der Schleife j
*ENDDO


! -- Loadstep 2 bzw. 5 Ende




! -- Loadstep 3 bzw. 6
!    (Abkühlschritt)

! - Thermoloadstepzähler um 1 erhöhen
ThLstZ=ThLstZ+1

! - Schleife k wird von 1 bis Zahl der
!   Substeps s durchlaufen
*do,k,1,s

! - Temperaturergebnisse vom
!   Loadstep ThLstZ und Substep k laden
LDREAD,TEMP,ThLstZ,k,,,thermo-V13,RTH

! - Zeitschritte festlegen

! - Laufzeit t berechnen

! Wenn i=1
*if,i,eq,1,then

! dann Laufzeit t um Bremsabstand brab/s erhöhen
t=t+brab/s

! sonst
*else

! Laufzeit t um die Abkühlzeit ta/s erhöhen
t=t+ta/s

! Schluss mit if
*endif

! Zeit t für die Berechnung definieren
TIME,t

! time stepping deaktiviert
AUTOTS,OFF

! Keine Substeps
NSUBST,1

! Specifies stepped loading
KBC,1

! - Output mit allen Daten und allen Substeps
OUTRES,ALL,ALL,

! Titel
/TITLE,Abkuehlen Nr.%i%

! - Loadstep-File mit der Nummer i3k schreiben
! "i3k" steht für Bremsung Nr.i, dritter Loadstep, Substep k
LSWRITE,%i%3%k%

! -- Ende der Schleife k
*ENDDO

! -- Loadstep 3 bzw. 6 Ende



! -- Ende der Loadstep-Schleife i
*ENDDO



! -- Jetzt können die Loadstep-Files überprüft werden




! -- Berechnung aller Loadsteps

! - Schleife i berechnet zwei Bremsungen hintereinander
!   auf der Basis der Loadstep-Files
!   und läuft von 1 bis 2
*do,i,1,2


! -- Loadstep 1 bzw. 4 berechnen

! - Loadstep lösen
LSSOLVE,%i%11

! -- Loadstep 2 bzw. 5 berechnen

! - Substeps lösen
LSSOLVE,%i%21,%i%2%s-1%

! -- Loadstep 3 bzw. 6 berechnen

! - Substeps lösen
LSSOLVE,%i%31,%i%3%s%

! -- Ende der Schleife i
*ENDDO

! --- Berechnung Ende




! -- Postprocessor
/POST1

! Graphically expands displacements, stresses and strains of a cyclically symmetric model
/CYCEXPAND,1,ON

! Zylindrisches Koordinatensystem
RSYS,1

! Letzen Set einlesen
SET,LAST

! Mieses plotten
PLNSOL,S,EQV,0,1.0

! -- Alles speichern
SAVE,