DEFINE Infostempel_macro
  LOCAL Teil_aktuell
  LOCAL Text_justierung
  LOCAL Text_zeilenabstand
  LOCAL Text_hoehe_breite
  LOCAL Text_groesse
  LOCAL Text_winkel
  LOCAL Text_schriftart
  LOCAL Text_farbe
  LOCAL Mstb
  LOCAL P_ul
  LOCAL P_or
  LOCAL X_u
  LOCAL X_o
  LOCAL Y_u
  LOCAL Y_o
  LOCAL P_mitte
  LOCAL Druckdatum
  LOCAL Name
  LOCAL Position


  INQ_SELECTED_ELEM ALL
  IF ((INQ 14) < 1)
    DISPLAY_NO_WAIT '*** Keine Geometrie zum erstellen eines Infostempel vorhanden.'
    WAIT 1
    CANCEL
  END_IF

  INQ_PART '.'
  LET Teil_aktuell (INQ 302)

  TRAP_ERROR
  EDIT_PART '1'
    {*** Wenn die geladenen Zeichnung eine Annotation-Zeichnung ist, dann darf der        ***}
    {*** Infostempel NICHT im Top erstellt werden, sondern im Blatt 1 !!!                 ***}
    {*** Wird dieser naemlich im Top erstellt, dann verschwindet dieser beim Neuzeichnen  ***}
  IF (CHECK_ERROR)
    EDIT_PART '/' {*** Kein Blatt 1 vorhanden ***}
  ELSE
    WAIT 0        {*** Blatt 1 vorhanden ***}
  END_IF


  INQ_ENV 12
  LET Text_justierung     (INQ 3)
  LET Text_zeilenabstand  (INQ 4)
  LET Text_hoehe_breite   (INQ 5)
  LET Text_groesse        (INQ 6)
  LET Text_winkel         (INQ 8)
  LET Text_schriftart     (INQ 302)
  LET Text_farbe          (INQ 301)

  INQ_ENV 6
  LET Mstb (INQ 4)

  INQ_ENV 7
  LET P_ul       (INQ 101)
  LET P_or       (INQ 102)
  LET X_u        (X_OF INQ 101)
  LET X_o        (X_OF INQ 102)
  LET Y_u        (Y_OF INQ 101)
  LET Y_o        (Y_OF INQ 102)
  LET Position   (P_ul + PNT_XY (2.5 / Mstb) (2.5 / Mstb))
  LET P_mitte    ((INQ 101) + PNT_XY (0.5 * (X_o - X_u)) (0.5 * (Y_o - Y_u)))
  LET Druckdatum (DATE)

  {*** Abfrage - Betriebssystem ***}
  INQ_ENV 10
  IF (INQ 4 = 2)
    {*** HP-UX ***}
    LET Name (GETENV 'LOGNAME')
  ELSE_IF (INQ 4 >= 6)
    {*** WINDOWS ***}
    LET Name (GETENV 'USERNAME')
  END_IF


  INQ_ELEM Position

  IF (INQ 403 <> TEXT)  { Abfrage, ob Infostempel schon vorhanden }

    MEASURE_DISTANCE P_ul P_or
    LET Text_infogroesse (INQ 3)
    INQ_ENV 6
    LET Text_infogroesse (0.03 * Text_infogroesse * (INQ 4))

    TEXT_ADJUST    5
    TEXT_LINESPACE 2
    TEXT_RATIO     1.5
    TEXT_SIZE      Text_infogroesse
    TEXT_ANGLE     P_ul P_or
    CURRENT_FONT   'hp_block_v'
    TEXT           CYAN
    TEXT_FILL      OFF
    END

    TEXT 'NUR ZUR INFO' P_mitte

    TEXT_ADJUST    4
    TEXT_LINESPACE 2
    TEXT_RATIO     1
    TEXT_SIZE      2
    TEXT_ANGLE     90
    CURRENT_FONT   'hp_d17_v'
    TEXT           RED
    TEXT_FILL      OFF
    END

    TEXT ('Ausdruck vom: ' + (STR Druckdatum) + '/' + (STR Name)) Position

    TEXT_ADJUST    Text_justierung
    TEXT_LINESPACE Text_zeilenabstand
    TEXT_RATIO     Text_hoehe_breite
    TEXT_SIZE      Text_groesse
    TEXT_ANGLE     Text_winkel
    CURRENT_FONT   Text_schriftart
    TEXT           (VAL Text_farbe)
    END
  END_IF

  EDIT_PART Teil_aktuell

END_DEFINE