Originalmakro:
-------------------------------------

DEFINE Awm_plot_to_pdf

  PARAMETER Pdf_file_name
  LOCAL Current_plot_device
  LOCAL Current_plot_scale
  LOCAL Plot_scale
  LOCAL File_name

  INQ_ENV 4
  LET Current_plot_device (INQ 301)
  LET Plot_scale (INQ 17)
  PLOTTER_TYPE 'pdf_generic'
  IF (Plot_scale=0)
    LET Current_plot_scale (INQ 2)
    PLOT_SCALE AUTO
  END_IF
  PLOT_DESTINATION DEL_OLD Pdf_file_name
  PLOT SHEETS NORM_VIDEO
  PLOTTER_TYPE Current_plot_device
  IF (Plot_scale=0)
    PLOT_SCALE Current_plot_scale
  END_IF
END_DEFINE

-------------------------------------------

Angepaßt:

-------------------------------------------
DEFINE Awm_plot_to_pdf

  PARAMETER Pdf_file_name
  LOCAL Current_plot_device
  LOCAL Current_plot_destination
  LOCAL Current_plot_scale
  LOCAL Plot_scale
  LOCAL File_name
  LOCAL Akt_Teil
  
  LOCAL I
  LOCAL Pkt_ul
  LOCAL Pkt_or
  LOCAL Masstab
  LOCAL Breite
  LOCAL Hoehe

  {*** Aktuelles Teil merken ***}
  INQ_ENV 7
  LET Akt_Teil (INQ 303)
  EDIT_PART TOP

  {*** Eckpunkte Zeichenfläche ***}
  INQ_ENV 7
  LET Pkt_ul (INQ 101){*** Eckp. Zeichn. Unten links ***}
  LET Pkt_or (INQ 102){*** Eckp. Zeichn. Oben rechts ***}
  
  INQ_ENV 6
  LET Masstab (INQ 4)

  LET Breite ((X_OF (Pkt_or-Pkt_ul))*Masstab)
  LET Hoehe  ((Y_OF (Pkt_or-Pkt_ul))*Masstab)

  
  {*** Plotterparameter abfragen ***}
  INQ_ENV 4
    LET Current_plot_device (INQ 301) {*** Akt. Plottergerätename sichern ***}
    LET Current_plot_destination (INQ 303) {*** Akt. Plotziel (Dateiname) sichern ***}
    LET Plot_scale (INQ 17) {*** Akt. Plotmaßstab: 0=Einpassen 1=Faktor aus INQ 2***}
    
  IF (Plot_scale=0)
    LET Current_plot_scale (INQ 2) 
    PLOT_SCALE AUTO
  END_IF
  
  PLOTTER_TYPE "PDF_GENERIC"
  Set_sys_plot_rot 0
  Set_sys_plot_center ON
  Set_sys_plot_plotscale 1
  Set_sys_plot_source ALL
  Set_sys_plot_as_displayed 0
 
  LET Breite (Breite + 12)
  LET Hoehe (Hoehe + 12)
  IF ((Breite > 1189) OR (Hoehe > 1189))
    IF (Breite > Hoehe)
      LET Breite 1189
      LET Hoehe 841
    ELSE
      LET Breite 841
      LET Hoehe 1189
    END_IF
    Set_sys_plot_plotscale 0
  END_IF

  PLOT_FORMAT Breite Hoehe
  
  {*** Pdf-Erstellung ausführen ***}
    PLOT_DESTINATION DEL_OLD Pdf_file_name 
  PLOT SHEETS NORM_VIDEO
  
  PLOTTER_TYPE Current_plot_device {*** Akt. Plottergerätename wiederherstellen ***}
  PLOT_DESTINATION Current_plot_destination {*** Akt. Plotziel wiederherstellen ***}
  IF (Plot_scale=0)
    PLOT_SCALE Current_plot_scale {*** Akt. Plotmaßstab  wiederherstellen ***}
  END_IF
  {*** Aktuelles Teil wieder aktivieren ***}
  EDIT_PART Akt_Teil
  
END_DEFINE

-------------------------------------------

Kann ebenfalls für Annotation verwendet werden:

-------------------------------------------

;; Einlesen der angepassten ME10 Routinen für Awm_plot_to_pdf_anno 
;; Diese werden auch für Annotation verwendet 

(sd-execute-annotator-command :cmd "input ((GETENV 'CC_PROJECT_PATH') + '/me10/awm/Awm_plot_to_pdf_anno.m') ")