finish
/clear,start
/filname,Modell_ohne_bohrung,1
/uis,msgpop,3
/prep7
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!1!!!Eingangsgroeßen!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!Bauteilbezogene Größen(auch Material)

B_Laenge=50              !Bauteillänge(z)
B_Breite=56              !Bauteilbreite(x)
B_Hoehe=5                !Bauteilhöhe(y)
Grund=0

!Bohrungsgeometrie und Werkzeugdaten

Loch=8.5                  !Lochdurchmesser
Fraeser=5                 !Fräserdurchmesser
FH=Fraeser/2
Bohrung_Z=B_Breite/2      !X-Koord_Bohrung
Bohrung_X=B_Laenge/2      !Y-Koord_Bohrung
DRM=Loch/2
FRB_X=Bohrung_X+FH        !Mittelpunkt Fräserkontakt in der Bohrung
SNE_X=Bohrung_X+Loch/2
Segmente=24               !Die Anzahl der Segmente steurt auch die Anzahl der Masterknoten
alpha=360/Segmente
SPD=alpha*1/120           !Vorschub
YOT=(Loch-Fraeser)/2
GKR=0.1                  !Glättungskreisradius um spitze Winkel zu vermeiden
WLK=0.75                 !Über diesen Radius wird der Kreis zum Antragen der Wärme erzeugt

Scheiben=B_Hoehe/SPD
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!Start Programm!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!Alublock erstellen
block,Grund,B_Laenge,Grund,B_Hoehe,Grund,B_Breite

!Keypoints für 1.Verstärkung
numstr,kp,20
k,20,0,2.15,11
k,21,0,2.15,15
k,22,0,2.85,15
k,23,0,2.85,11

!Keypoints verbinden
numstr,line,30
l,20,21
l,21,22
l,22,23
l,23,20

!Linen durhc das Blech ziehen
numstr,area,20
adrag,30,31,32,33,,,4,

!Verstärkung kopieren
agen,3,20,23,1,0,0,15,,1,0

!Volumen erstellen
asel,s,area,,20,31
vsba,1,all,,,
allsel

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!Vernetzung des Modells!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! 
et,1,solid187
et,2,solid187

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!Materialeigenschaften in thermischer Hinsicht!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
EModul=73394.6           !E-Modul_Alu [MPa]
Quer=0.34              !Querkontraktionszahl Alu
EModul_S=196000          !E-Modul_Stahl [MPa]
Quer_S=0.30              !Querkontraktionszahl Stahl
mp,prxy,1,Quer
mp,reft,1,480
mp,ex,1,Emodul

mp,ex,2,EModul_S
mp,prxy,2,Quer_S
mp,alpx,2,15e-6            !Wärmeausdehungkoeffizient
mp,reft,2,480
mpamod,2,20

!Wärmeabhängigkeiten Alu
!!MPTEMP,1,20,100,200,300,480
 MPDATA,ALPX,1,1,22.4e-6,23.4e-6,24.4e-6,25.4e-6,26.4e-6
 MPDATA,Ex,1,1,69000,64844,52075,40076,15467
 TB,MKIN,1,5
 TBTEMP,,STRAIN                            ! Next TBDATA values are strains
 TBDATA,1,0.001,0.002,0.25                       ! Strains for all temps
 TBTEMP,20                                 ! Temperature = 20
 TBDATA,1,69,95,227                        ! Stresses at temperature = 20
 TBTEMP,100                                ! Temperature = 100
 TBDATA,1,64.8,72,158                          ! Stresses at temperature =100
 TBTEMP,200                                ! Temperature = 200
 TBDATA,1,52.075,66,138                          ! Stresses at temperature = 200
 TBTEMP,300                                ! Temperature = 300
 TBDATA,1,40.076,46,88                         ! Stresses at temperature =300
 TBTEMP,480                                       ! Temperature = 480
 TBDATA,1,15.467,16,17                            ! Stresses at temperature = 480


 !Wärmeabhängigkeiten STAHL
 MPTEMP,1,20,100,200,300,480
 MPDATA,ALPX,2,1,1.61e-5,1.72e-5,1.81e-5,1.88e-5,1.95e-5
 MPDATA,Ex,2,1,196000,190000,182000,174000,166000

vsel,s,volu,,2,4
type,2
mat,2
mshkey,0
MSHAPE,0,3D
esize,1
vmesh,all
allsel
vsel,s,volu,,5
type,1
mat,1
mshkey,0
MSHAPE,1,3D
esize,2
vmesh,all
allsel
!Lagerung
asel,s,area,,38,39
nsla,s,1
d,all,all,0
allsel
finish

/solu
antype,0
eqslv,pcg
nlgeom,on
TOFFST,273                         !Temperatur in Celsius
TREF,20                            !Referenztemperatur
solc,on
nropt,full
autots,on
deltim,0.5,0.1,0.5
tunif,480
bf,all,temp,200
kbc,0
ALLSEL
solve
bf,all,temp,20
kbc,0
ALLSEL
solve