! Spule Eigenbau
! /input,'D:\Dokumente\Studium\ss_11\Master Thesis\Ansys test\Eigenbau-Spule-kern.txt'
!------------------------------------------------
finish
/clear
/CWD,'D:\Dokumente\Studium\ss_11\Master Thesis\Ansys test\'
*abbr,startP,/input,Eigenbau-Spule-kern.txt
!------Parameter-----------------------
! Konstanten
pi = atan(1)*4		! PI
! Spule
phi0 	= 0			! Startwinkel Wicklung
phi1 	= 8*pi		! Endwinkel Wicklung
R0		= 5e-3		! Startradius
dR		= 0.5e-3	! Änderungsrate Radius pro phi
Z0		= -0.5e-3	! Starthöhe
dZ		= 0*0.5e-3		! Änderungsrate Höhe pro phi
stepspp = 30			! Steps per pi


phi0 	= 0				! Startwinkel Wicklung
phi1 	= 16*pi			! Endwinkel Wicklung
R0		= 10e-3			! Startradius
dR		= 0e-3			! Änderungsrate Radius pro phi
Z0		= -0.5e-3		! Starthöhe
dZ		= 1*0.5e-3		! Änderungsrate Höhe pro phi
stepspp = 80			! Steps per pi

leiterR	= 0.5e-3		! Radius Querschnitt Leiter

! Luftvolumen
radau=3*(R0+(phi1-phi0)*dR)			! Radius Luftkugel
! Strom durch Spule
strom=200				! [A]
freq=1e-3
wikappa=56e6			!spez. el. Leitfähigkeit der Wicklungen
! Anker
ankh	= 5e-2			! [m]
ankb	= 3e-2			! [m]
kerndy	= 1e-2			! [m]
kerndz	= 1e-2			! [m]
luftsph	= 5e-3			! [m]

mukern	= 2000			! Permeabilität


!------Elementtypen------------------------------
/prep7
et,1,solid97,0		! ET 1: Luft
et,2,solid97,1		! ET 2: Spule
et,3,solid97,0		! ET 3: Kern
!------Materialeigenschaften------------------------
mp,murx,1,1			! Luft
mp,murx,2,1			! Wicklung
mp,rsvx,2,1/wikappa	!spez. el. Leitfähigkeit (Wicklung)
mp,murx,3,mukern	! Kern
!------Geometrie------------------
!------Wicklung---------------
csys,1
nkppath=0

*DO,m,phi0,phi1,(phi1-phi0)/stepspp
	nkppath=nkppath+1
	K,nkppath,R0+dR*m,m/pi*180,Z0+dZ*m
*ENDDO

! Spline durch die KPs legen. Ein Querschnitt wird später entlang dieser Linie extrudiert
FLST,3,nkppath,3 
*DO,m,1,nkppath
	FITEM,3,m
*ENDDO
BSPLIN, ,P51X

! WP an den Anfang der Helix verschieben
WPAVE,R0,phi0,Z0
WPROTA,90-phi0
WPROTA,,90
WPROTA,,,90
csys,wp

! Querschnitt erzeugen
CYL4,0,0,leiterR
VDRAG,1,,,,,,1  

allsel
CM,spulev,volum
vsel,none
!------Kern---------------
wpcsys,,0
wpave,,,(Z0+dZ*(phi1-phi0))/2
wprota,,90
wpave,,,-kerndz/2
blc4,-kerndy/2,-ankh/2,kerndy,ankh,kerndz
blc4,kerndy/2,ankh/2-kerndy,ankb-2*kerndy,kerndy,kerndz
blc4,kerndy/2,-ankh/2,ankb-2*kerndy,kerndy,kerndz
! Luftspalt
blc4,kerndy/2+ankb-2*kerndy,luftsph/2,kerndy,ankh/2-luftsph/2,kerndz
blc4,kerndy/2+ankb-2*kerndy,-ankh/2,kerndy,ankh/2-luftsph/2,kerndz
!cm,kernv,VOLU	!bringt nichts, wird ohnehin gelöscht
!------Luft--------
wpcsys,,0
csys,0
wpave,-radau,-radau,-radau+(Z0+(phi1-phi0)*dZ)/2
BLC4,,,2*radau,2*radau,2*radau 
wpcsys,,0
csys,0

ALLSEL
vovlap,all             
numcmp,volu

VSEL,S,,,7 
CM,luftv,volum

ALLSEL
CMSEL,U,spulev
CMSEL,U,luftv
CM,kernv,volum


!-------Mesh Windung-------------
CMSEL,S,spulev
esize,0.0015,  		! Meshfeinheit
type,2				
mat,2	  	
vmesh,all

!-------Mesh Kern-------------
CMSEL,S,kernv
esize,0.0045,  		! Meshfeinheit
mshkey,0		
mshape,1,3D	
type,3				
mat,3	  	
vmesh,all

!------Mesh Luft-------------
allsel
cmsel,s,luftv
esize,0.004
mshkey,0		
mshape,1,3D		
type,1
mat,1	
vmesh,all
!/EOF
!------Rand----------------------
nsel,s,ext
d,all,az,0
d,all,ax,0
d,all,ay,0

!------Lasten-----
! Anfang der Spule auswählen
csys,1
cmsel,s,spulev
aslv,s
asel,R,loc,x,R0-leiterR, R0+leiterR
!asel,R,loc,y,phi0/pi*180
asel,R,loc,z,Z0-leiterR, Z0+leiterR

nsla,s,1
cp,1,volt,all
*get,n_ein,node,0,num,max
f,n_ein,amps,strom
!---------------------
! Ende der Spule auswählen
csys,1
cmsel,s,spulev
aslv,s
asel,R,loc,x,R0+(phi1-phi0)*dR-leiterR, R0+(phi1-phi0)*dR+leiterR
asel,R,loc,z,Z0+(phi1-phi0)*dZ-leiterR, Z0+(phi1-phi0)*dZ+leiterR
nsla,s,1
d,all,volt,0

!------LÖSUNG----------------------------------

/solu			
allsel			
antype,harm	
harfre,freq
solve

/POST1
CMSEL,S,spulev
eslv,u
PLVECT,B, , , ,VECT,ELEM,ON,0   
/VSCALE,1,1,0