fini
/clear
/CWD,'C:\Users\Marco\Desktop\Ansy\Berechnungen

/fil,Spannbandbrücke mit Vorspannung aus Vordehnung, Beam3


!------------------------------------------------------------
! Spannbandbrücke mit Streckenlast, Vorspannung an den Enden.
!------------------------------------------------------------

 !
 ! Eingabeteil
 !

! Materialeigenschaften
 EModul = 1.7*10**11 ![N/m^2]
 Querk = 0.3 ![-]

 ! Profileigenschaften
 Flae = 2.8236*10**(-4) ![m^2]
 FM2G = 6.638*10**(-9) ![m^4]
 Hoe = 0.0168 ![m]
 

!Vorspannkraft
Vkraft=311000 ![N]
ISTRN=Vkraft/(Emodul*Flae)
 
 ! Elementgröße
Anzahl=261
 *set,elegr,13.05/Anzahl ![m]

 ! Streckenlast
 *set,Last,3320 ![N/m]

!Stablänge
 *set,Laenge,13.05 ![m]

!Gewichtskraft
 *set,Gewicht,(Last*Laenge/10) ![kg]

 DICHTE = (Gewicht)/(Flae*Laenge) ![kg/m^3]


 /prep7
 ! Elementtyp
 et,1,Beam3

 ! Erdbeschleunigung
! acel,,10 ! [m/s^2]


 ! Materialeigenschaften
 mp,ex,1,EModul
 mp,prxy,1,Querk
 mp,dens,1,DICHTE

 ! Profileigenschaften
 r,1,Flae,FM2G,Hoe,,ISTRN

 ! Keypoints
 k,1,0,0
 k,2,Laenge,0

 ! Linien
 l,1,2,Anzahl


 ! Elementgröße
 !esize,elegr
 lmesh,all

 ! Auflager ’links’
DK,1,ux,0
DK,1,uy,0

 ! Auflager ’rechts’
DK,2,ux,0
DK,2,uy,0

 ! Belastung, Hier auf Knoten aufgebracht
 NSLL,S,0
 f,all,fy,-(Last*elegr)
 ALLSEL


 finish


/SOLU
ANTYPE,STATIC 		! Static analysis
!PSTRES,ON 		! Flag to calculate the prestress matrix
NLGEOM,on 		! Large deflection analysis
NSUBST,10,10
ARCLEN,ON

SOLVE
FINISH

! Starten Postprocessor
 /post1

 ! Schreiben Elementergebnisse in Tabelle
 etable,ni,smisc,1
 etable,nj,smisc,7
 etable,vi,smisc,2
 etable,vj,smisc,8
 etable,moi,smisc,6
 etable,moj,smisc,12


 ! Definieren Fenster für Ergebnisausgabe
 /wind,all,off
 /wind,1,ltop
 /wind,2,rtop
 /wind,3,lbot
 /wind,4,rbot

 ! Allgemeine plot-Optionen
 gplot

 ! Ausgabe der Verformung, N,Q und M-Linien
 /gcmd,1,pldisp,1
 /gcmd,3,plls,ni,nj
 /gcmd,2,plls,vi,vj
 /gcmd,4,plls,moi,moj
 /replot