FINI
/CLEAR, ALL
/FILNAME, Numerische Modellierung eines adaptronischen Balkensystems

!-------------------
! START Preprocessor
!-------------------

/PREP7
/UNITS, SI !SI Einheitensystem (m, kg, s, K)

!--------------------------------------------------------------
! Eingaben von Variablen für Geometrie, Elementtyp und Material
!--------------------------------------------------------------

Balken_Lange=0.2 !(m)
Balken_Breite=0.04 !(m)
Balken_Hohe=0.003 !(m)

Balken_EANX=100  !Für Vernetzung: the number of element divisions per line
Balken_EANY=3
Balken_EANZ=20

Balken_EModul=7e10 !(N/m^2)
Balken_Poissonzahl=0.34
Balken_Dichte=2700 !(kg/m^3)

Aktor_Lange=0.05 !(m)
Aktor_Breite=0.03 !(m)
Aktor_Hohe=0.001 !(m)

Aktor_EANX=50
Aktor_EANY=3
Aktor_EANZ=9

Sensor_Lange=0.01 !(m)
Sensor_Breite=0.01 !(m)
Sensor_Hohe=0.001 !(m)

Sensor_EANX=10
Sensor_EANY=3
Sensor_EANZ=3

Piezo_Dichte=7800 !(kg/m^3)

! Koordinatensystems für Balken, Aktor und Sensor: X-Achse = Lange, Y-Achse = Hohe und Z-Achse = Breite 

!-----------------------
! Definiere einen Balken
!-----------------------

ET, 1, SOLID186

!--------------------------------------------
! Eingaben für Elementtyp und Material Balken
!--------------------------------------------

MP, EX, 1, Balken_EModul
MP, PRXY, 1, Balken_Poissonzahl
MP, DENS, 1, Balken_Dichte

!------------------------------
! Eingaben für Balken Geometrie 
!------------------------------

BLOCK, 0, Balken_Lange, 0, Balken_Hohe, 0, Balken_Breite
VSEL, S, VOLU, , 1  
CM, Balken, VOLU
VATT, 1, ,1 ,
ASEL, S, AREA, , 4  
CM, Balkenoberseite, AREA
!AATT, 1, , ,
ASEL, S, AREA, , 3  
CM, Balkenunterseite, AREA
!AATT, 1, , , 
VSEL, NONE
ASEL, NONE


!----------------------------------
!Materialeigenschaften Piezo PIC151
!----------------------------------

!#------------------------------------------------------------------------
!#------------Piezo Material-----------------------------------------------------
!#------------------------------------------------------------------------
!#_MATERIAL_2_PZT_
!#__MATERIALDATEN_PIC_151__
    mp,dens,10,7.76e3
    sE11=16.83e-12
    sE12=-5.656e-12
    sE13=-7.107e-12
    sE33=19e-12
    sE44=50.96e-12
    sE66=(sE11-sE12)*2
    !_
    d31=-2.14e-10
    d33=4.23e-10
    d15=6.1e-10
    !
    epsS_1=1110  !bei const. Dehnung wegen dem 
    epsS_3=852   !von Ansys verwendeten Gls.
    !
    emunit,mks
!
!__NACHGIEBIGKEITSMATRIX__
!_Achtung: ANSYS verlangt dass die eingaben sE44 & sE66 vertauscht werden

    tb,anel,10,1,,1
    tbdata,1 ,sE11,sE12,sE13,   0,   0,   0
    tbdata,7      ,sE11,sE13,   0,   0,   0
    tbdata,12          ,sE33,   0,   0,   0
    tbdata,16               ,sE66,   0,   0
    tbdata,19                    ,sE44,   0
    tbdata,21                          ,sE44
    !__MATRIX_DER_PIEZOELEKTRISCHEN_LADUNGSKONSTANTEN__
    tb,piez,10,,,1
    tbdata, 1,0  ,0  ,d31
    tbdata, 4,0  ,0  ,d31
    tbdata, 7,0  ,0  ,d33
    tbdata,10,0  ,0  ,0
    tbdata,13,0  ,d15,0
    tbdata,16,d15,0  ,0
    !__PEMITIVITÄTEN__
    mp,perx,10,epsS_1
    mp,pery,10,epsS_1
    mp,perz,10,epsS_3

ET, 10, SOLID226, 1001

!-----------------------------
! Eingaben für Aktor Geometrie 
!-----------------------------

BLOCK, 0.01, 0.01+Aktor_Lange, Balken_Hohe, Balken_Hohe+Aktor_Hohe, 0.005, 0.005+Aktor_Breite
VSEL, S, VOLU, , 2 
CM, Aktor, VOLU
VATT, 10, , 10,
ASEL, S, AREA, , 10 
NSLA
CM, Aktoroberseite, NODE
!AATT, 2, , ,
ASEL, S, AREA, , 9 
NSLA
CM, Aktorunterseite, NODE
!AATT, 2, , , 
VSEL, NONE
ASEL, NONE

!------------------------------
! Eingaben für Sensor Geometrie 
!------------------------------

BLOCK, 0.03, 0.03+Sensor_Lange, 0, -Sensor_Hohe, 0.015, 0.015+Sensor_Breite
VSEL, S, VOLU, , 3 
CM, Sensor, VOLU
VATT, 10, , 10,
ASEL, S, AREA, , 16 
NSLA
CM, Sensoroberseite, NODE
!AATT, 2, , ,
ASEL, S, AREA, , 15 
NSLA
CM, Sensorunterseite, NODE
!AATT, 2, , , 
VSEL, ALL
ASEL, ALL
VPLOT, ALL

!----------------------------------------
! Eingaben für manuelle Vernetzung Balken
!----------------------------------------

LSEL, S, LOC, Z, 0
LSEL, A, LOC, Z, Balken_Breite
LSEL, U, LOC, X, 0
LSEL, U, LOC, X, Balken_Lange
LESIZE, ALL, , , Balken_EANX
LSEL, ALL

LSEL, S, LOC, Z, 0
LSEL, A, LOC, Z, Balken_Breite
LSEL, U, LOC, Y, 0
LSEL, U, LOC, Y, Balken_Hohe
LESIZE, ALL, , , Balken_EANY
LSEL, ALL

LSEL, S, LOC, X, 0
LSEL, A, LOC, X, Balken_Lange
LSEL, U, LOC, Z, 0
LSEL, U, LOC, Z, Balken_Breite
LESIZE, ALL, , , Balken_EANZ
LSEL, ALL

!---------------------------------------
! Eingaben für manuelle Vernetzung Aktor
!---------------------------------------

LSEL, S, LOC, Z, 0.005
LSEL, A, LOC, Z, 0.005+Aktor_Breite
LSEL, U, LOC, X, 0.01
LSEL, U, LOC, X, 0.01+Aktor_Lange
LESIZE, ALL, , , Piezo_EANX
LSEL, ALL

LSEL, S, LOC, Z, 0.005
LSEL, A, LOC, Z, 0.005+Aktor_Breite
LSEL, U, LOC, Y, Balken_Hohe
LSEL, U, LOC, Y, Balken_Hohe+Aktor_Hohe
LESIZE, ALL, , , Piezo_EANY
LSEL, ALL

LSEL, S, LOC, X, 0.01
LSEL, A, LOC, X, 0.01+Aktor_Lange
LSEL, U, LOC, Z, 0.005
LSEL, U, LOC, Z, 0.005+Aktor_Breite
LESIZE, ALL, , , Aktor_EANZ
LSEL, ALL

!----------------------------------------
! Eingaben für manuelle Vernetzung Sensor
!----------------------------------------

LSEL, S, LOC, Z, 0.015
LSEL, A, LOC, Z, 0.015+Sensor_Breite
LSEL, U, LOC, X, 0.03
LSEL, U, LOC, X, 0.03+Sensor_Lange
LESIZE, ALL, , , Sensor_EANX
LSEL, ALL

LSEL, S, LOC, Z, 0.015
LSEL, A, LOC, Z, 0.015+Sensor_Breite
LSEL, U, LOC, Y, 0
LSEL, U, LOC, Y, -Sensor_Hohe
LESIZE, ALL, , , Sensor_EANY
LSEL, ALL

LSEL, S, LOC, X, 0.03
LSEL, A, LOC, X, 0.03+Sensor_Lange
LSEL, U, LOC, Z, 0.015
LSEL, U, LOC, Z, 0.015+Sensor_Breite
LESIZE, ALL, , , Sensor_EANZ
LSEL, ALL

!----------
! Vernetzen
!----------

ASEL, ALL
VSEL, ALL
CMSEL, ALL
VMESH, ALL


ASEL, ALL
VSEL, ALL
CMSEL, ALL

!------------------------------------------------------------
!Verbinden der Balken mit Aktorunterseite und Sensoroberseite
!------------------------------------------------------------

ET, 3, TARGE170
ET, 4, CONTA175
KEYOPT, 4, 1, 3
KEYOPT, 4, 12, 5

ASEL, S, AREA, , 4
NSLA, S, 1
ESLA, A
NSEL, R, LOC, X, 0.01, 0.01+Aktor_Lange  
NSEL, R, LOC, Z, 0.005, 0.005+Aktor_Breite
TYPE, 3
MAT, 1
ESURF  

ASEL, S, AREA, , 9
NSLA, S, 1
ESLA, A
TYPE, 4
MAT, 2
ESURF

ASEL, NONE

ASEL, S, AREA, , 3
NSLA, S, 1
ESLA, A
NSEL, R, LOC, X, 0.03, 0.03+Sensor_Lange  
NSEL, R, LOC, Z, 0.015, 0.015+Sensor_Breite
TYPE, 3
MAT, 1
ESURF  

ASEL, S, AREA, , 16
NSLA, S, 1
ESLA, A
TYPE, 4
MAT, 2
ESURF

ALLSEL, ALL

!-----------------------------------------
! Randbedingungen bei eingespanntem Balken
!-----------------------------------------

NSEL, S, LOC, X, 0
D, ALL, ALL, 0

LOCAL,12, , 0, 0, 0, 90, 0,90

esel,s,mat,,10
emodif,all,esys,12


!-----------------------------------------
! DoF Piezo
!-----------------------------------------

!Aktoroberseite
ASEL, S, AREA, , 10 
NSLA
cp,1,volt,all
*get,N_A_Mi,node,,num,min                 !N_A_Mi: node an der Oberseite von Piezoaktor mit miminaler Nummer
*get,N_A_Ma,node,,num,max                 !N_A_Ma: node an der oberseite von piezoaktor mit maximaler Nummer
nsel,s,node,,N_A_Mi,N_A_Ma                !select nodes mit der Nummer ab minimal bis maximal
d,all,volt,10
nsel,none


!Sensorunterseite
ASEL, S, AREA, , 15 
NSLA
cp,2,volt,all
*get,N_S_M,node,,num,min
nsel,s,node,,N_S_M
nsel,none


!Aktorunterseite
ASEL, S, AREA, , 9 
NSLA
cp,3,volt,all
d,all,volt,0

!Sensoroberseite
ASEL, S, AREA, , 16 
NSLA
cp,4,volt,all
d,all,volt,0

cmsel,s,sensorunterseite,node

*get,Ns,node,,num,min

va=volt(Ns)

cmsel,none

!---------------
! START Solution
!---------------

/solu

ANTYPE,TRANS !Transiente Analyse

TRNOPT,FULL  !Full method

nropt,full

cmsel,s,aktoroberseite,node

d,all,volt,1000

time,5

kbc,1

nsubst,100

lswrite,1

allsel,all

lssolve,1

fini